Cleanup swapoff.c and swapon.c
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / __longjmp.S
1 /* longjmp for i386.
2    Copyright (C) 1995-1998,2000,2002,2005, 2006 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21 #include <jmpbuf-offsets.h>
22 #include <asm-syntax.h>
23 #include <bp-sym.h>
24 #include <bp-asm.h>
25
26 #define PARMS   LINKAGE         /* no space for saved regs */
27 #define JBUF    PARMS
28 #define VAL     JBUF+PTR_SIZE
29
30 ENTRY (BP_SYM (__longjmp))
31         ENTER
32
33 #ifdef PTR_DEMANGLE
34         movl JBUF(%esp), %eax   /* User's jmp_buf in %eax.  */
35         CHECK_BOUNDS_BOTH_WIDE (%eax, JBUF(%esp), $JB_SIZE)
36
37         /* Save the return address now.  */
38         movl (JB_PC*4)(%eax), %edx
39         /* Get the stack pointer.  */
40         movl (JB_SP*4)(%eax), %ecx
41         PTR_DEMANGLE (%edx)
42         PTR_DEMANGLE (%ecx)
43         cfi_def_cfa(%eax, 0)
44         cfi_register(%eip, %edx)
45         cfi_register(%esp, %ecx)
46         cfi_offset(%ebx, JB_BX*4)
47         cfi_offset(%esi, JB_SI*4)
48         cfi_offset(%edi, JB_DI*4)
49         cfi_offset(%ebp, JB_BP*4)
50         /* Restore registers.  */
51         movl (JB_BX*4)(%eax), %ebx
52         movl (JB_SI*4)(%eax), %esi
53         movl (JB_DI*4)(%eax), %edi
54         movl (JB_BP*4)(%eax), %ebp
55         cfi_restore(%ebx)
56         cfi_restore(%esi)
57         cfi_restore(%edi)
58         cfi_restore(%ebp)
59
60         movl VAL(%esp), %eax    /* Second argument is return value.  */
61         movl %ecx, %esp
62 #else
63         movl JBUF(%esp), %ecx   /* User's jmp_buf in %ecx.  */
64         CHECK_BOUNDS_BOTH_WIDE (%ecx, JBUF(%esp), $JB_SIZE)
65
66         movl VAL(%esp), %eax    /* Second argument is return value.  */
67         /* Save the return address now.  */
68         movl (JB_PC*4)(%ecx), %edx
69         /* Restore registers.  */
70         movl (JB_BX*4)(%ecx), %ebx
71         movl (JB_SI*4)(%ecx), %esi
72         movl (JB_DI*4)(%ecx), %edi
73         movl (JB_BP*4)(%ecx), %ebp
74         movl (JB_SP*4)(%ecx), %esp
75 #endif
76         /* Jump to saved PC.  */
77         jmp *%edx
78 END (BP_SYM (__longjmp))