Cleanup swapoff.c and swapon.c
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / configure.in
1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
2 # Local configure fragment for sysdeps/i386.
3
4 AC_CACHE_CHECK(if -g produces usable source locations for assembler-with-cpp,
5                libc_cv_cpp_asm_debuginfo, [dnl
6 cat > conftest.S <<EOF
7 #include "confdefs.h"
8
9 /* comment on
10    two lines */
11         ${libc_cv_dot_text}
12         ${libc_cv_asm_global_directive} foo
13 foo:
14         /* Unfortunately this test only works for a real instruction,
15            not for any of the machine-independent pseudo-ops.
16            So we just have to assume everybody has a "nop".  */
17         nop
18         /* comment */
19         nop
20         /* comment */
21         nop
22 EOF
23 if AC_TRY_COMMAND([${CC-cc} $CPPFLAGS $ASFLAGS -g -c conftest.S 1>&AS_MESSAGE_LOG_FD]) && {
24    ac_pattern='conftest\.S'
25    AC_TRY_COMMAND([readelf --debug-dump=line conftest.o |
26                    grep $ac_pattern 1>&AS_MESSAGE_LOG_FD])
27   }; then
28   libc_cv_cpp_asm_debuginfo=yes
29 else
30   libc_cv_cpp_asm_debuginfo=no
31 fi
32 rm -f conftest*])AC_SUBST(libc_cv_cpp_asm_debuginfo)
33 if test $libc_cv_cpp_asm_debuginfo = yes; then
34   AC_DEFINE(HAVE_CPP_ASM_DEBUGINFO)
35 fi