Real implementation calling __sigjmp_save.
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / elf / bsd-setjmp.S
1 /* BSD `setjmp' entry point to `sigsetjmp (..., 1)'.  i386 version.
2    Copyright (C) 1995, 1996, 1997, 2000, 2001 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21 #define _ASM
22 #define _SETJMP_H
23 #include <bits/setjmp.h>
24 #include "bp-sym.h"
25 #include "bp-asm.h"
26
27 #define PARMS   LINKAGE         /* no space for saved regs */
28 #define JMPBUF  PARMS
29 #define SIGMSK  JMPBUF+PTR_SIZE
30
31 ENTRY (BP_SYM (setjmp))
32         /* Note that we have to use a non-exported symbol in the next
33            jump since otherwise gas will emit it as a jump through the
34            PLT which is what we cannot use here.  */
35         ENTER
36
37         movl JMPBUF(%esp), %eax
38         CHECK_BOUNDS_BOTH_WIDE (%eax, JMPBUF(%esp), $JB_SIZE)
39
40         /* Save registers.  */
41         movl %ebx, (JB_BX*4)(%eax)
42         movl %esi, (JB_SI*4)(%eax)
43         movl %edi, (JB_DI*4)(%eax)
44         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
45         movl %ecx, (JB_SP*4)(%eax)
46         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
47         movl %ecx, (JB_PC*4)(%eax)
48         LEAVE /* pop frame pointer to prepare for tail-call.  */
49         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
50
51         /* Call __sigjmp_save.  */
52         pushl $1
53         pushl 8(%esp)
54 #ifdef  PIC
55         /* We cannot use the PLT, because it requires that %ebx be set, but
56            we can't save and restore our caller's value.  Instead, we do an
57            indirect jump through the GOT, using for the temporary register
58            %ecx, which is call-clobbered.  */
59         call here2
60 here2:  popl %ecx
61         addl $_GLOBAL_OFFSET_TABLE_+[.-here2], %ecx
62         movl C_SYMBOL_NAME (BP_SYM (__sigjmp_save)@GOT)(%ecx), %ecx
63         call *%ecx
64 #else
65         call BP_SYM (__sigjmp_save)
66 #endif
67         popl %ecx
68         popl %edx
69         ret
70 END (BP_SYM (setjmp))