Call __libc_start_main with extra argument.
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / elf / start.S
1 /* Startup code compliant to the ELF i386 ABI.
2    Copyright (C) 1995, 1996, 1997, 1998 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 /* This is the canonical entry point, usually the first thing in the text
21    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
22    point runs, most registers' values are unspecified, except for:
23
24    %edx         Contains a function pointer to be registered with `atexit'.
25                 This is how the dynamic linker arranges to have DT_FINI
26                 functions called for shared libraries that have been loaded
27                 before this code runs.
28
29    %esp         The stack contains the arguments and environment:
30                 0(%esp)                 argc
31                 4(%esp)                 argv[0]
32                 ...
33                 (4*argc)(%esp)          NULL
34                 (4*(argc+1))(%esp)      envp[0]
35                 ...
36                                         NULL
37 */
38
39         .text
40         .globl _start
41 _start:
42         /* Clear the frame pointer.  The ABI suggests this be done, to mark
43            the outermost frame obviously.  */
44         xorl %ebp, %ebp
45
46         /* Extract the arguments as encoded on the stack and set up
47            the arguments for `main': argc, argv.  envp will be determined
48            later in __libc_start_main.  */
49         popl %esi               /* Pop the argument count.  */
50         movl %esp, %ecx         /* argv starts just at the current stack top.*/
51
52         /* Before pushing the arguments align the stack to a double word
53            boundary to avoid penalties from misaligned accesses.  Thanks
54            to Edward Seidl <seidl@janed.com> for pointing this out.  */
55         andl $0xfffffff8, %esp
56
57         /* Provide the highest stack address to the user code (for stacks
58            which grow downwards).  */
59         pushl %esp
60
61         pushl %edx              /* Push address of the shared library
62                                    termination function.  */
63
64         /* Push address of our own entry points to .fini and .init.  */
65         pushl $_fini
66         pushl $_init
67
68         pushl %ecx              /* Push second argument: argv.  */
69         pushl %esi              /* Push first argument: argc.  */
70
71         pushl $main
72
73         /* Call the user's main function, and exit with its value.
74            But let the libc call main.    */
75         call __libc_start_main
76
77         hlt                     /* Crash if somehow `exit' does return.  */
78
79 /* To fulfill the System V/i386 ABI we need this symbol.  Yuck, it's so
80    meaningless since we don't support machines < 80386.  */
81         .section .rodata
82         .globl _fp_hw
83         .long 3
84         .size _fp_hw, 4
85
86 /* Define a symbol for the first piece of initialized data.  */
87         .data
88         .globl __data_start
89 __data_start:
90         .long 0
91         .weak data_start
92         data_start = __data_start