* sysdeps/i386/asm-syntax.h (R, MEM, MEM_DISP, MEM_INDEX,
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / i586 / addmul_1.S
1 /* Pentium __mpn_addmul_1 -- Multiply a limb vector with a limb and add
2    the result to a second limb vector.
3    Copyright (C) 1992, 94, 96, 97, 98, 00 Free Software Foundation, Inc.
4    This file is part of the GNU MP Library.
5
6    The GNU MP Library is free software; you can redistribute it and/or modify
7    it under the terms of the GNU Library General Public License as published by
8    the Free Software Foundation; either version 2 of the License, or (at your
9    option) any later version.
10
11    The GNU MP Library is distributed in the hope that it will be useful, but
12    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
13    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
14    License for more details.
15
16    You should have received a copy of the GNU Library General Public License
17    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
18    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
19    MA 02111-1307, USA. */
20
21 #include "sysdep.h"
22 #include "asm-syntax.h"
23 #include "bp-asm.h"
24
25 #define PARMS   LINKAGE+16      /* space for 4 saved regs */
26 #define RES     PARMS
27 #define S1      RES+PTR_SIZE
28 #define SIZE    S1+PTR_SIZE
29 #define S2LIMB  SIZE+4
30
31 #define res_ptr edi
32 #define s1_ptr esi
33 #define size ecx
34 #define s2_limb ebp
35
36         .text
37 ENTRY(__mpn_addmul_1)
38         ENTER
39
40         pushl   %edi
41         pushl   %esi
42         pushl   %ebx
43         pushl   %ebp
44
45         movl    RES(%esp), %res_ptr
46         movl    S1(%esp), %s1_ptr
47         movl    SIZE(%esp), %size
48         movl    S2LIMB(%esp), %s2_limb
49
50         leal    (%res_ptr,%size,4), %res_ptr
51         leal    (%s1_ptr,%size,4), %s1_ptr
52         negl    %size
53         xorl    %ebx, %ebx
54         ALIGN (3)
55
56 L(oop): adcl    $0, %ebx
57         movl    (%s1_ptr,%size,4), %eax
58
59         mull    %s2_limb
60
61         addl    %ebx, %eax
62         movl    (%res_ptr,%size,4), %ebx
63
64         adcl    $0, %edx
65         addl    %eax, %ebx
66
67         movl    %ebx, (%res_ptr,%size,4)
68         incl    %size
69
70         movl    %edx, %ebx
71         jnz     L(oop)
72
73         adcl    $0, %ebx
74         movl    %ebx, %eax
75         popl    %ebp
76         popl    %ebx
77         popl    %esi
78         popl    %edi
79
80         LEAVE
81         ret
82 #undef size
83 END(__mpn_addmul_1)