Move _dl_hp_timing_overhead and procinfo-related variables in
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / i686 / add_n.S
1 /* Add two limb vectors of the same length > 0 and store sum in a third
2    limb vector.
3    Copyright (C) 1992, 94, 95, 97, 98, 2000 Free Software Foundation, Inc.
4    This file is part of the GNU MP Library.
5
6    The GNU MP Library is free software; you can redistribute it and/or modify
7    it under the terms of the GNU Lesser General Public License as published by
8    the Free Software Foundation; either version 2.1 of the License, or (at your
9    option) any later version.
10
11    The GNU MP Library is distributed in the hope that it will be useful, but
12    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
13    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
14    License for more details.
15
16    You should have received a copy of the GNU Lesser General Public License
17    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
18    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
19    MA 02111-1307, USA. */
20
21 #include "sysdep.h"
22 #include "asm-syntax.h"
23 #include "bp-sym.h"
24 #include "bp-asm.h"
25
26 #define PARMS   LINKAGE+8               /* space for 2 saved regs */
27 #define RES     PARMS
28 #define S1      RES+PTR_SIZE
29 #define S2      S1+PTR_SIZE
30 #define SIZE    S2+PTR_SIZE
31
32         .text
33 #ifdef PIC
34 L(1):   addl    (%esp), %eax
35         ret
36 #endif
37 ENTRY (BP_SYM (__mpn_add_n))
38         ENTER
39
40         pushl %edi
41         pushl %esi
42
43         movl    RES(%esp),%edi
44         movl    S1(%esp),%esi
45         movl    S2(%esp),%edx
46         movl    SIZE(%esp),%ecx
47 #if __BOUNDED_POINTERS__
48         shll    $2, %ecx        /* convert limbs to bytes */
49         CHECK_BOUNDS_BOTH_WIDE (%edi, RES(%esp), %ecx)
50         CHECK_BOUNDS_BOTH_WIDE (%esi, S1(%esp), %ecx)
51         CHECK_BOUNDS_BOTH_WIDE (%edx, S2(%esp), %ecx)
52         shrl    $2, %ecx
53 #endif
54         movl    %ecx,%eax
55         shrl    $3,%ecx                 /* compute count for unrolled loop */
56         negl    %eax
57         andl    $7,%eax                 /* get index where to start loop */
58         jz      L(oop)                  /* necessary special case for 0 */
59         incl    %ecx                    /* adjust loop count */
60         shll    $2,%eax                 /* adjustment for pointers... */
61         subl    %eax,%edi               /* ... since they are offset ... */
62         subl    %eax,%esi               /* ... by a constant when we ... */
63         subl    %eax,%edx               /* ... enter the loop */
64         shrl    $2,%eax                 /* restore previous value */
65 #ifdef PIC
66 /* Calculate start address in loop for PIC.  */
67         leal    (L(oop)-L(0)-3)(%eax,%eax,8),%eax
68         call    L(1)
69 L(0):
70 #else
71 /* Calculate start address in loop for non-PIC.  */
72         leal    (L(oop) - 3)(%eax,%eax,8),%eax
73 #endif
74         jmp     *%eax                   /* jump into loop */
75         ALIGN (3)
76 L(oop): movl    (%esi),%eax
77         adcl    (%edx),%eax
78         movl    %eax,(%edi)
79         movl    4(%esi),%eax
80         adcl    4(%edx),%eax
81         movl    %eax,4(%edi)
82         movl    8(%esi),%eax
83         adcl    8(%edx),%eax
84         movl    %eax,8(%edi)
85         movl    12(%esi),%eax
86         adcl    12(%edx),%eax
87         movl    %eax,12(%edi)
88         movl    16(%esi),%eax
89         adcl    16(%edx),%eax
90         movl    %eax,16(%edi)
91         movl    20(%esi),%eax
92         adcl    20(%edx),%eax
93         movl    %eax,20(%edi)
94         movl    24(%esi),%eax
95         adcl    24(%edx),%eax
96         movl    %eax,24(%edi)
97         movl    28(%esi),%eax
98         adcl    28(%edx),%eax
99         movl    %eax,28(%edi)
100         leal    32(%edi),%edi
101         leal    32(%esi),%esi
102         leal    32(%edx),%edx
103         decl    %ecx
104         jnz     L(oop)
105
106         sbbl    %eax,%eax
107         negl    %eax
108
109         popl %esi
110         popl %edi
111
112         LEAVE
113         ret
114 END (BP_SYM (__mpn_add_n))