Cleanup swapoff.c and swapon.c
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / rshift.S
1 /* i80386 __mpn_rshift --
2    Copyright (C) 1992,1994,1997-2000,2005 Free Software Foundation, Inc.
3    This file is part of the GNU MP Library.
4
5    The GNU MP Library is free software; you can redistribute it and/or modify
6    it under the terms of the GNU Lesser General Public License as published by
7    the Free Software Foundation; either version 2.1 of the License, or (at your
8    option) any later version.
9
10    The GNU MP Library is distributed in the hope that it will be useful, but
11    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
13    License for more details.
14
15    You should have received a copy of the GNU Lesser General Public License
16    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
17    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
18    MA 02111-1307, USA. */
19
20 #include "sysdep.h"
21 #include "asm-syntax.h"
22 #include "bp-sym.h"
23 #include "bp-asm.h"
24
25 #define PARMS   LINKAGE+12              /* space for 3 saved regs */
26 #define RES     PARMS
27 #define S       RES+PTR_SIZE
28 #define SIZE    S+PTR_SIZE
29 #define CNT     SIZE+4
30
31         .text
32 ENTRY (BP_SYM (__mpn_rshift))
33         ENTER
34
35         pushl   %edi
36         cfi_adjust_cfa_offset (4)
37         pushl   %esi
38         cfi_adjust_cfa_offset (4)
39         pushl   %ebx
40         cfi_adjust_cfa_offset (4)
41
42         movl    RES(%esp),%edi
43         cfi_rel_offset (edi, 8)
44         movl    S(%esp),%esi
45         cfi_rel_offset (esi, 4)
46         movl    SIZE(%esp),%edx
47         movl    CNT(%esp),%ecx
48 #if __BOUNDED_POINTERS__
49         shll    $2, %edx                /* convert limbs to bytes */
50         CHECK_BOUNDS_BOTH_WIDE (%edi, RES(%esp), %edx)
51         CHECK_BOUNDS_BOTH_WIDE (%esi, S(%esp), %edx)
52         shrl    $2, %edx
53 #endif
54         leal    -4(%edi,%edx,4),%edi
55         leal    (%esi,%edx,4),%esi
56         negl    %edx
57
58         movl    (%esi,%edx,4),%ebx      /* read least significant limb */
59         cfi_rel_offset (ebx, 0)
60         xorl    %eax,%eax
61         shrdl   %cl,%ebx,%eax           /* compute carry limb */
62         incl    %edx
63         jz      L(end)
64         pushl   %eax                    /* push carry limb onto stack */
65         cfi_adjust_cfa_offset (4)
66         testb   $1,%dl
67         jnz     L(1)                    /* enter loop in the middle */
68         movl    %ebx,%eax
69
70         ALIGN (3)
71 L(oop): movl    (%esi,%edx,4),%ebx      /* load next higher limb */
72         shrdl   %cl,%ebx,%eax           /* compute result limb */
73         movl    %eax,(%edi,%edx,4)      /* store it */
74         incl    %edx
75 L(1):   movl    (%esi,%edx,4),%eax
76         shrdl   %cl,%eax,%ebx
77         movl    %ebx,(%edi,%edx,4)
78         incl    %edx
79         jnz     L(oop)
80
81         shrl    %cl,%eax                /* compute most significant limb */
82         movl    %eax,(%edi)             /* store it */
83
84         popl    %eax                    /* pop carry limb */
85         cfi_adjust_cfa_offset (-4)
86
87         popl    %ebx
88         cfi_adjust_cfa_offset (-4)
89         cfi_restore (ebx)
90         popl    %esi
91         cfi_adjust_cfa_offset (-4)
92         cfi_restore (esi)
93         popl    %edi
94         cfi_adjust_cfa_offset (-4)
95         cfi_restore (edi)
96
97         LEAVE
98         ret
99
100         cfi_adjust_cfa_offset (12)
101         cfi_rel_offset (edi, 8)
102         cfi_rel_offset (esi, 4)
103         cfi_rel_offset (ebx, 0)
104 L(end): shrl    %cl,%ebx                /* compute most significant limb */
105         movl    %ebx,(%edi)             /* store it */
106
107         popl    %ebx
108         cfi_adjust_cfa_offset (-4)
109         cfi_restore (ebx)
110         popl    %esi
111         cfi_adjust_cfa_offset (-4)
112         cfi_restore (esi)
113         popl    %edi
114         cfi_adjust_cfa_offset (-4)
115         cfi_restore (edi)
116
117         LEAVE
118         ret
119 END (BP_SYM (__mpn_rshift))