(__strncat_g): Improve last patch.
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / rshift.S
1 /* i80386 __mpn_rshift --
2    Copyright (C) 1992, 1994, 1997, 1998, 1999, 2000 Free Software Foundation, Inc.
3    This file is part of the GNU MP Library.
4
5    The GNU MP Library is free software; you can redistribute it and/or modify
6    it under the terms of the GNU Lesser General Public License as published by
7    the Free Software Foundation; either version 2.1 of the License, or (at your
8    option) any later version.
9
10    The GNU MP Library is distributed in the hope that it will be useful, but
11    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
13    License for more details.
14
15    You should have received a copy of the GNU Lesser General Public License
16    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
17    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
18    MA 02111-1307, USA. */
19
20 #include "sysdep.h"
21 #include "asm-syntax.h"
22 #include "bp-sym.h"
23 #include "bp-asm.h"
24
25 #define PARMS   LINKAGE+12              /* space for 3 saved regs */
26 #define RES     PARMS
27 #define S       RES+PTR_SIZE
28 #define SIZE    S+PTR_SIZE
29 #define CNT     SIZE+4
30
31         .text
32 ENTRY (BP_SYM (__mpn_rshift))
33         ENTER
34
35         pushl   %edi
36         pushl   %esi
37         pushl   %ebx
38
39         movl    RES(%esp),%edi
40         movl    S(%esp),%esi
41         movl    SIZE(%esp),%edx
42         movl    CNT(%esp),%ecx
43 #if __BOUNDED_POINTERS__
44         shll    $2, %edx                /* convert limbs to bytes */
45         CHECK_BOUNDS_BOTH_WIDE (%edi, RES(%esp), %edx)
46         CHECK_BOUNDS_BOTH_WIDE (%esi, S(%esp), %edx)
47         shrl    $2, %edx
48 #endif
49         leal    -4(%edi,%edx,4),%edi
50         leal    (%esi,%edx,4),%esi
51         negl    %edx
52
53         movl    (%esi,%edx,4),%ebx      /* read least significant limb */
54         xorl    %eax,%eax
55         shrdl   %cl,%ebx,%eax           /* compute carry limb */
56         incl    %edx
57         jz      L(end)
58         pushl   %eax                    /* push carry limb onto stack */
59         testb   $1,%dl
60         jnz     L(1)                    /* enter loop in the middle */
61         movl    %ebx,%eax
62
63         ALIGN (3)
64 L(oop): movl    (%esi,%edx,4),%ebx      /* load next higher limb */
65         shrdl   %cl,%ebx,%eax           /* compute result limb */
66         movl    %eax,(%edi,%edx,4)      /* store it */
67         incl    %edx
68 L(1):   movl    (%esi,%edx,4),%eax
69         shrdl   %cl,%eax,%ebx
70         movl    %ebx,(%edi,%edx,4)
71         incl    %edx
72         jnz     L(oop)
73
74         shrl    %cl,%eax                /* compute most significant limb */
75         movl    %eax,(%edi)             /* store it */
76
77         popl    %eax                    /* pop carry limb */
78
79         popl    %ebx
80         popl    %esi
81         popl    %edi
82
83         LEAVE
84         ret
85
86 L(end): shrl    %cl,%ebx                /* compute most significant limb */
87         movl    %ebx,(%edi)             /* store it */
88
89         popl    %ebx
90         popl    %esi
91         popl    %edi
92
93         LEAVE
94         ret
95 END (BP_SYM (__mpn_rshift))