Cleanup swapoff.c and swapon.c
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / setjmp.S
1 /* setjmp for i386.
2    Copyright (C) 1995,1996,1997,2000,2001,2005,2006
3         Free Software Foundation, Inc.
4    This file is part of the GNU C Library.
5
6    The GNU C Library is free software; you can redistribute it and/or
7    modify it under the terms of the GNU Lesser General Public
8    License as published by the Free Software Foundation; either
9    version 2.1 of the License, or (at your option) any later version.
10
11    The GNU C Library is distributed in the hope that it will be useful,
12    but WITHOUT ANY WARRANTY; without even the implied warranty of
13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14    Lesser General Public License for more details.
15
16    You should have received a copy of the GNU Lesser General Public
17    License along with the GNU C Library; if not, write to the Free
18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
19    02111-1307 USA.  */
20
21 #include <sysdep.h>
22 #include <jmpbuf-offsets.h>
23 #include <asm-syntax.h>
24 #include "bp-sym.h"
25 #include "bp-asm.h"
26
27 #define PARMS   LINKAGE         /* no space for saved regs */
28 #define JMPBUF  PARMS
29 #define SIGMSK  JMPBUF+PTR_SIZE
30
31 ENTRY (BP_SYM (__sigsetjmp))
32         ENTER
33
34         movl JMPBUF(%esp), %eax
35         CHECK_BOUNDS_BOTH_WIDE (%eax, JMPBUF(%esp), $JB_SIZE)
36
37         /* Save registers.  */
38         movl %ebx, (JB_BX*4)(%eax)
39         movl %esi, (JB_SI*4)(%eax)
40         movl %edi, (JB_DI*4)(%eax)
41         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
42 #ifdef PTR_MANGLE
43         PTR_MANGLE (%ecx)
44 #endif
45         movl %ecx, (JB_SP*4)(%eax)
46         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
47 #ifdef PTR_MANGLE
48         PTR_MANGLE (%ecx)
49 #endif
50         movl %ecx, (JB_PC*4)(%eax)
51         LEAVE /* pop frame pointer to prepare for tail-call.  */
52         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
53
54 #if defined NOT_IN_libc && defined IS_IN_rtld
55         /* In ld.so we never save the signal mask.  */
56         xorl %eax, %eax
57         ret
58 #else
59         /* Make a tail call to __sigjmp_save; it takes the same args.  */
60         jmp __sigjmp_save
61 #endif
62 END (BP_SYM (__sigsetjmp))