Include float.h.
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / submul_1.S
1 /* i80386 __mpn_submul_1 -- Multiply a limb vector with a limb and subtract
2    the result from a second limb vector.
3    Copyright (C) 1992,1994,1997,1998,2000,2005 Free Software Foundation, Inc.
4    This file is part of the GNU MP Library.
5
6    The GNU MP Library is free software; you can redistribute it and/or modify
7    it under the terms of the GNU Lesser General Public License as published by
8    the Free Software Foundation; either version 2.1 of the License, or (at your
9    option) any later version.
10
11    The GNU MP Library is distributed in the hope that it will be useful, but
12    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
13    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
14    License for more details.
15
16    You should have received a copy of the GNU Lesser General Public License
17    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
18    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
19    MA 02111-1307, USA. */
20
21 #include "sysdep.h"
22 #include "asm-syntax.h"
23 #include "bp-sym.h"
24 #include "bp-asm.h"
25
26 #define PARMS   LINKAGE+16      /* space for 4 saved regs */
27 #define RES     PARMS
28 #define S1      RES+PTR_SIZE
29 #define SIZE    S1+PTR_SIZE
30 #define S2LIMB  SIZE+4
31
32 #define res_ptr edi
33 #define s1_ptr esi
34 #define sizeP ecx
35 #define s2_limb ebx
36
37         .text
38 ENTRY (BP_SYM (__mpn_submul_1))
39         ENTER
40
41         pushl   %edi
42         cfi_adjust_cfa_offset (4)
43         pushl   %esi
44         cfi_adjust_cfa_offset (4)
45         pushl   %ebp
46         cfi_adjust_cfa_offset (4)
47         pushl   %ebx
48         cfi_adjust_cfa_offset (4)
49         cfi_rel_offset (edi, 12)
50         cfi_rel_offset (esi, 8)
51         cfi_rel_offset (ebp, 4)
52         cfi_rel_offset (ebx, 0)
53
54         movl    RES(%esp), %res_ptr
55         movl    S1(%esp), %s1_ptr
56         movl    SIZE(%esp), %sizeP
57         movl    S2LIMB(%esp), %s2_limb
58 #if __BOUNDED_POINTERS__
59         shll    $2, %sizeP      /* convert limbs to bytes */
60         CHECK_BOUNDS_BOTH_WIDE (%res_ptr, RES(%esp), %sizeP)
61         CHECK_BOUNDS_BOTH_WIDE (%s1_ptr, S1(%esp), %sizeP)
62         shrl    $2, %sizeP
63 #endif
64         leal    (%res_ptr,%sizeP,4), %res_ptr
65         leal    (%s1_ptr,%sizeP,4), %s1_ptr
66         negl    %sizeP
67         xorl    %ebp, %ebp
68         ALIGN (3)
69 L(oop):
70         movl    (%s1_ptr,%sizeP,4), %eax
71         mull    %s2_limb
72         addl    %ebp, %eax
73         adcl    $0, %edx
74         subl    %eax, (%res_ptr,%sizeP,4)
75         adcl    $0, %edx
76         movl    %edx, %ebp
77
78         incl    %sizeP
79         jnz     L(oop)
80         movl    %ebp, %eax
81
82         popl    %ebx
83         cfi_adjust_cfa_offset (-4)
84         cfi_restore (ebx)
85         popl    %ebp
86         cfi_adjust_cfa_offset (-4)
87         cfi_restore (ebp)
88         popl    %esi
89         cfi_adjust_cfa_offset (-4)
90         cfi_restore (esi)
91         popl    %edi
92         cfi_adjust_cfa_offset (-4)
93         cfi_restore (edi)
94
95         LEAVE
96         ret
97 END (BP_SYM (__mpn_submul_1))