Fixed incorrect use of mvcle introduced by 2001-07-12 change.
[kopensolaris-gnu/glibc.git] / sysdeps / i386 / submul_1.S
1 /* i80386 __mpn_submul_1 -- Multiply a limb vector with a limb and subtract
2    the result from a second limb vector.
3    Copyright (C) 1992, 1994, 1997, 1998, 2000 Free Software Foundation, Inc.
4    This file is part of the GNU MP Library.
5
6    The GNU MP Library is free software; you can redistribute it and/or modify
7    it under the terms of the GNU Lesser General Public License as published by
8    the Free Software Foundation; either version 2.1 of the License, or (at your
9    option) any later version.
10
11    The GNU MP Library is distributed in the hope that it will be useful, but
12    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
13    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
14    License for more details.
15
16    You should have received a copy of the GNU Lesser General Public License
17    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
18    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
19    MA 02111-1307, USA. */
20
21 #include "sysdep.h"
22 #include "asm-syntax.h"
23 #include "bp-sym.h"
24 #include "bp-asm.h"
25
26 #define PARMS   LINKAGE+16      /* space for 4 saved regs */
27 #define RES     PARMS
28 #define S1      RES+PTR_SIZE
29 #define SIZE    S1+PTR_SIZE
30 #define S2LIMB  SIZE+4
31
32 #define res_ptr edi
33 #define s1_ptr esi
34 #define sizeP ecx
35 #define s2_limb ebx
36
37         .text
38 ENTRY (BP_SYM (__mpn_submul_1))
39         ENTER
40
41         pushl   %edi
42         pushl   %esi
43         pushl   %ebp
44         pushl   %ebx
45
46         movl    RES(%esp), %res_ptr
47         movl    S1(%esp), %s1_ptr
48         movl    SIZE(%esp), %sizeP
49         movl    S2LIMB(%esp), %s2_limb
50 #if __BOUNDED_POINTERS__
51         shll    $2, %sizeP      /* convert limbs to bytes */
52         CHECK_BOUNDS_BOTH_WIDE (%res_ptr, RES(%esp), %sizeP)
53         CHECK_BOUNDS_BOTH_WIDE (%s1_ptr, S1(%esp), %sizeP)
54         shrl    $2, %sizeP
55 #endif
56         leal    (%res_ptr,%sizeP,4), %res_ptr
57         leal    (%s1_ptr,%sizeP,4), %s1_ptr
58         negl    %sizeP
59         xorl    %ebp, %ebp
60         ALIGN (3)
61 L(oop):
62         movl    (%s1_ptr,%sizeP,4), %eax
63         mull    %s2_limb
64         addl    %ebp, %eax
65         adcl    $0, %edx
66         subl    %eax, (%res_ptr,%sizeP,4)
67         adcl    $0, %edx
68         movl    %edx, %ebp
69
70         incl    %sizeP
71         jnz     L(oop)
72         movl    %ebp, %eax
73
74         popl    %ebx
75         popl    %ebp
76         popl    %esi
77         popl    %edi
78
79         LEAVE
80         ret
81 END (BP_SYM (__mpn_submul_1))