IA-64 _mcount wrapper code.
[kopensolaris-gnu/glibc.git] / sysdeps / ia64 / _mcount.S
1 /* Machine-specific calling sequence for `mcount' profiling function.  ia64
2    Copyright (C) 2000 Free Software Foundation, Inc.
3      Contributed by David Mosberger <davidm@hpl.hp.com>
4    This file is part of the GNU C Library.
5
6    The GNU C Library is free software; you can redistribute it and/or
7    modify it under the terms of the GNU Library General Public License as
8    published by the Free Software Foundation; either version 2 of the
9    License, or (at your option) any later version.
10
11    The GNU C Library is distributed in the hope that it will be useful,
12    but WITHOUT ANY WARRANTY; without even the implied warranty of
13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14    Library General Public License for more details.
15
16    You should have received a copy of the GNU Library General Public
17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
19    Boston, MA 02111-1307, USA.  */
20
21 /* Assembly stub to invoke _mcount().  Compiler generated code calls
22    this stub before executing a function's prologue and without saving
23    any registers.  It is therefore necessary to preserve the input
24    registers as they may contain function arguments.  To work
25    correctly with frame-less functions, it is also necessary to
26    preserve the return pointer (b0 aka rp).
27
28    State upon entering _mcount:
29
30     r8  address of return value structure (used only when called
31         function returns a large structure)
32     r15 static link (used only for nested functions)
33     in0 ar.pfs to restore before returning to the function that
34         called _mcount
35     in1 gp value to restore before returning to the function that
36         called _mcount
37     in2 return address in the function that invoked the caller
38         of _mcount (frompc)
39     in3 address of the global-offset table entry that holds the
40         profile count dword allocated by the compiler; to get
41         the address of this dword, use "ld8 in2=[in2]; this
42         dword can be used in any way by _mcount (including
43         not at all, as is the case with the current implementation)
44     b0  address to return to after _mcount is done
45 */
46
47 #include <sysdep.h>
48
49 #undef ret
50
51         .psr    abi64
52         .psr    lsb
53         .lsb
54
55 LEAF(_mcount)
56         alloc loc0 = ar.pfs, 4, 4, 3, 0
57         mov loc1 = rp
58         mov loc2 = r8   // gcc uses r8 to pass pointer to return structure
59         ;;
60         mov loc3 = r15  // gcc uses r15 to pass the static link to nested functions
61         mov out0 = in2
62         mov out1 = rp
63         br.call.sptk.few rp = __mcount_internal
64         ;;
65 .here:
66 {
67         .mii
68         mov gp = in1
69         mov r2 = ip
70         mov ar.pfs = loc0
71 }
72         ;;
73         adds r2 = 1f - .here, r2
74         mov b7 = loc1
75         mov rp = in2
76         ;;
77         mov r8 = loc2
78         mov r15 = loc3
79         mov b6 = r2
80         br.ret.sptk.few b6
81
82 1:      alloc r2 = ar.pfs, 0, 0, 9, 0
83         mov ar.pfs = r40
84         br b7
85 END(_mcount)
86
87 weak_alias (_mcount, mcount)