1c41a6517d8b7b5349a36ce59c4c53581215e7e5
[kopensolaris-gnu/glibc.git] / sysdeps / ia64 / elf / start.S
1 /* Copyright (C) 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Written by Jes Sorensen, <Jes.Sorensen@cern.ch>, April 1999.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    In addition to the permissions in the GNU Lesser General Public
11    License, the Free Software Foundation gives you unlimited
12    permission to link the compiled version of this file with other
13    programs, and to distribute those programs without any restriction
14    coming from the use of this file. (The GNU Lesser General Public
15    License restrictions do apply in other respects; for example, they
16    cover modification of the file, and distribution when not linked
17    into another program.)
18
19    Note that people who make modified versions of this file are not
20    obligated to grant this special exception for their modified
21    versions; it is their choice whether to do so. The GNU Lesser
22    General Public License gives permission to release a modified
23    version without this exception; this exception also makes it
24    possible to release a modified version which carries forward this
25    exception.
26
27    The GNU C Library is distributed in the hope that it will be useful,
28    but WITHOUT ANY WARRANTY; without even the implied warranty of
29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
30    Lesser General Public License for more details.
31
32    You should have received a copy of the GNU Lesser General Public
33    License along with the GNU C Library; if not, write to the Free
34    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
35    02111-1307 USA.  */
36
37 #include <sysdep.h>
38
39 #include <asm/unistd.h>
40 #include <asm/fpu.h>
41
42 /*
43  * Arguments for __libc_start_main:
44  *      out0:   main
45  *      out1:   argc
46  *      out2:   argv
47  *      out3:   init
48  *      out4:   fini
49  *      out5:   rtld_fini
50  *      out6:   stack_end
51  */
52
53         .align 32
54         .global _start
55
56         .proc _start
57         .type _start,@function
58 _start:
59         .prologue
60         .save rp, r0
61         .body
62         .prologue
63         { .mlx
64           alloc r2 = ar.pfs,0,0,7,0
65           movl r3 = FPSR_DEFAULT
66         }
67         { .mlx
68           adds out2 = 16, sp    /* get address of argc value */
69           movl gp = @gprel(0f)
70           ;;
71         }
72 0:      { .mmi
73           ld8 out1 = [out2], 8  /* load argc and move out2 to become argv */
74           mov.m r10 = ar.bsp    /* fetch rbs base address */
75           mov r9 = ip
76           ;;
77         }
78         { .mii
79           mov ar.fpsr = r3
80           sub gp = r9, gp       /* back-compute gp value */
81           adds out6 = 16, sp    /* highest non-environment stack address */
82           ;;
83         }
84         {
85           addl r11 = @ltoff(__libc_ia64_register_backing_store_base), gp
86           addl out0 = @ltoff(@fptr(main)), gp
87           addl out3 = @ltoff(@fptr(__libc_csu_init)), gp
88           ;;
89         }
90         { .mmi
91           ld8 r3 = [r11]        /* pointer to __libc_ia64_register_backing_store_base */
92           ld8 out0 = [out0]     /* pointer to `main' function descriptor */
93           addl out4 = @ltoff(@fptr(__libc_csu_fini)), gp
94           ;;
95         }
96         { .mmi
97           ld8 out3 = [out3]     /* pointer to `init' function descriptor */
98           ld8 out4 = [out4]     /* pointer to `fini' function descriptor */
99           nop 0
100         }
101         .body
102         { .mib
103           st8 [r3] = r10
104           mov out5 = ret0       /* dynamic linker destructor */
105           br.call.sptk.few rp = __libc_start_main
106         }
107         { .mib
108           break 0       /* break miserably if we ever return */
109         }
110         .endp _start
111
112 /* Define a symbol for the first piece of initialized data.  */
113         .data
114         .globl __data_start
115 __data_start:
116         .long 0
117         .weak data_start
118         data_start = __data_start
119
120         .common __libc_ia64_register_backing_store_base, 8, 8