Initialize fpsr from _FPU_STATUS.
[kopensolaris-gnu/glibc.git] / sysdeps / ia64 / elf / start.S
1 /* Copyright (C) 1999, 2000, 2001 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Written by Jes Sorensen, <Jes.Sorensen@cern.ch>, April 1999.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21
22 #include <asm/unistd.h>
23
24 /* Arguments for __libc_start_main:
25         out0:   main
26         out1:   argc
27         out2:   argv
28         out3:   init
29         out4:   fini
30         out5:   rtld_fini
31         out6:   stack_end  */
32
33 /* XXX: Remove this once a version of the linker scripts (binutils) is
34    widespread enough that provides the default _FPU_STATUS value.  It
35    is safe to remove the OLD_BINUTILS code at any time since, in the
36    worst case, it will lead to an unresolved external reference to
37    _FPU_STATUS; that is, there won't be any silent errors. */
38 #define OLD_BINUTILS
39
40         .align 32
41         .global _start
42
43         .proc _start
44 _start:
45         .prologue
46         { .mlx
47           alloc r2 = ar.pfs,0,0,7,0
48           movl r3 = _FPU_STATUS
49         }
50         { .mlx
51           adds out2 = 16, sp    /* get address of argc value */
52           movl gp = @gprel(0f)
53           ;;
54         }
55 0:      { .mmi
56           ld8 out1 = [out2], 8  /* load argc and move out2 to become argv */
57           mov.m r10 = ar.bsp    /* fetch rbs base address */
58           mov r9 = ip
59           ;;
60         }
61 #ifdef OLD_BINUTILS
62         .weak _FPU_STATUS
63         cmp.eq p6, p0 = r0, r3
64         ;;
65 (p6)    movl r3 = 0x9804c0270033f
66         ;;
67 #endif
68         { .mii
69           mov ar.fpsr = r3
70           sub gp = r9, gp       /* back-compute gp value */
71           adds out6 = 16, sp    /* highest non-environment stack address */
72           ;;
73         }
74         {
75           addl r11 = @ltoff(__libc_ia64_register_backing_store_base), gp
76           addl out0 = @ltoff(@fptr(main)), gp
77           addl out3 = @ltoff(@fptr(_init)), gp
78           ;;
79         }
80         { .mmi
81           ld8 r3 = [r11]        /* pointer to __libc_ia64_register_backing_store_base */
82           ld8 out0 = [out0]     /* pointer to `main' function descriptor */
83           addl out4 = @ltoff(@fptr(_fini)), gp
84           ;;
85         }
86         { .mmi
87           ld8 out3 = [out3]     /* pointer to `init' function descriptor */
88           ld8 out4 = [out4]     /* pointer to `fini' function descriptor */
89           .save rp, r4
90           mov r4 = r0           /* terminate unwind chain with a NULL return-pointer */
91         }
92         .body
93         { .mib
94           st8 [r3] = r10
95           mov out5 = ret0       /* dynamic linker destructor */
96           br.call.sptk.few rp = __libc_start_main
97         }
98         { .mib
99           break 0       /* break miserably if we ever return */
100         }
101         .endp _start
102
103 /* Define a symbol for the first piece of initialized data.  */
104         .data
105         .globl __data_start
106 __data_start:
107         .long 0
108         .weak data_start
109         data_start = __data_start
110
111         .common __libc_ia64_register_backing_store_base, 8, 8