(_start): Use ".save rp, r0" idiom to terminate call-chain right from the
[kopensolaris-gnu/glibc.git] / sysdeps / ia64 / elf / start.S
1 /* Copyright (C) 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Written by Jes Sorensen, <Jes.Sorensen@cern.ch>, April 1999.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21
22 #include <asm/unistd.h>
23 #include <asm/fpu.h>
24
25 /*
26  * Arguments for __libc_start_main:
27  *      out0:   main
28  *      out1:   argc
29  *      out2:   argv
30  *      out3:   init
31  *      out4:   fini
32  *      out5:   rtld_fini
33  *      out6:   stack_end
34  */
35
36         .align 32
37         .global _start
38
39         .proc _start
40         .type _start,@function
41 _start:
42         .prologue
43         .save rp, r0
44         .body
45         .prologue
46         { .mlx
47           alloc r2 = ar.pfs,0,0,7,0
48           movl r3 = FPSR_DEFAULT
49         }
50         { .mlx
51           adds out2 = 16, sp    /* get address of argc value */
52           movl gp = @gprel(0f)
53           ;;
54         }
55 0:      { .mmi
56           ld8 out1 = [out2], 8  /* load argc and move out2 to become argv */
57           mov.m r10 = ar.bsp    /* fetch rbs base address */
58           mov r9 = ip
59           ;;
60         }
61         { .mii
62           mov ar.fpsr = r3
63           sub gp = r9, gp       /* back-compute gp value */
64           adds out6 = 16, sp    /* highest non-environment stack address */
65           ;;
66         }
67         {
68           addl r11 = @ltoff(__libc_ia64_register_backing_store_base), gp
69           addl out0 = @ltoff(@fptr(main)), gp
70           addl out3 = @ltoff(@fptr(__libc_csu_init)), gp
71           ;;
72         }
73         { .mmi
74           ld8 r3 = [r11]        /* pointer to __libc_ia64_register_backing_store_base */
75           ld8 out0 = [out0]     /* pointer to `main' function descriptor */
76           addl out4 = @ltoff(@fptr(__libc_csu_fini)), gp
77           ;;
78         }
79         { .mmi
80           ld8 out3 = [out3]     /* pointer to `init' function descriptor */
81           ld8 out4 = [out4]     /* pointer to `fini' function descriptor */
82           nop 0
83         }
84         .body
85         { .mib
86           st8 [r3] = r10
87           mov out5 = ret0       /* dynamic linker destructor */
88           br.call.sptk.few rp = __libc_start_main
89         }
90         { .mib
91           break 0       /* break miserably if we ever return */
92         }
93         .endp _start
94
95 /* Define a symbol for the first piece of initialized data.  */
96         .data
97         .globl __data_start
98 __data_start:
99         .long 0
100         .weak data_start
101         data_start = __data_start
102
103         .common __libc_ia64_register_backing_store_base, 8, 8