IA-64 implementation of tanf.
[kopensolaris-gnu/glibc.git] / sysdeps / ia64 / fpu / s_tanf.S
1 .file "tanf.s"
2
3 // Copyright (c) 2000, 2001, Intel Corporation
4 // All rights reserved.
5 // 
6 // Contributed 2/2/2000 by John Harrison, Ted Kubaska, Bob Norin, Shane Story,
7 // and Ping Tak Peter Tang of the Computational Software Lab, Intel Corporation.
8 // 
9 // WARRANTY DISCLAIMER
10 // 
11 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
12 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
13 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
14 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS 
15 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
16 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
17 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR 
18 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY 
19 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
20 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS 
21 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
22 // 
23 // Intel Corporation is the author of this code, and requests that all
24 // problem reports or change requests be submitted to it directly at 
25 // http://developer.intel.com/opensource.
26 //
27 // History
28 //==============================================================
29 // 2/02/00: Initial version
30 // 4/04/00  Unwind support added
31 // 12/27/00 Improved speed
32 //
33 // API
34 //==============================================================
35 // float tan( float x);
36 //
37 // Overview of operation
38 //==============================================================
39 // If the input value in radians is |x| >= 1.xxxxx 2^10 call the
40 // older slower version.
41 //
42 // The new algorithm is used when |x| <= 1.xxxxx 2^9.
43 //
44 // Represent the input X as Nfloat * pi/2 + r
45 //    where r can be negative and |r| <= pi/4
46 //
47 //     tan_W  = x * 2/pi
48 //     Nfloat = round_int(tan_W)
49 //
50 //     tan_r  = x - Nfloat * (pi/2)_hi
51 //     tan_r  = tan_r - Nfloat * (pi/2)_lo
52 //
53 // We have two paths: p8, when Nfloat is even and p9. when Nfloat is odd.
54 // p8: tan(X) =  tan(r)
55 // p9: tan(X) = -cot(r)
56 //
57 // Each is evaluated as a series. The p9 path requires 1/r.
58 //
59 // The coefficients used in the series are stored in a table as
60 // are the pi constants.
61 //
62 // Registers used
63 //==============================================================
64 //
65 // predicate registers used:  
66 // p6-10
67 //
68 // floating-point registers used:  
69 // f10-15, f32-105
70 // f8, input
71 //
72 // general registers used
73 // r14-18, r32-43
74 //
75
76 #include "libm_support.h"
77
78 // Assembly macros
79 //==============================================================
80 TAN_INV_PI_BY_2_2TO64        = f10
81 TAN_RSHF_2TO64               = f11
82 TAN_2TOM64                   = f12
83 TAN_RSHF                     = f13
84 TAN_W_2TO64_RSH              = f14
85 TAN_NFLOAT                   = f15
86
87 tan_Inv_Pi_by_2              = f32
88 tan_Pi_by_2_hi               = f33
89 tan_Pi_by_2_lo               = f34
90
91
92 tan_P0                       = f35
93 tan_P1                       = f36
94 tan_P2                       = f37
95 tan_P3                       = f38 
96 tan_P4                       = f39 
97 tan_P5                       = f40 
98 tan_P6                       = f41
99 tan_P7                       = f42
100 tan_P8                       = f43 
101 tan_P9                       = f44 
102 tan_P10                      = f45 
103 tan_P11                      = f46
104 tan_P12                      = f47 
105 tan_P13                      = f48
106 tan_P14                      = f49
107 tan_P15                      = f50
108
109 tan_Q0                       = f51 
110 tan_Q1                       = f52 
111 tan_Q2                       = f53 
112 tan_Q3                       = f54 
113 tan_Q4                       = f55 
114 tan_Q5                       = f56 
115 tan_Q6                       = f57 
116 tan_Q7                       = f58 
117 tan_Q8                       = f59
118 tan_Q9                       = f60
119 tan_Q10                      = f61
120
121 tan_r                        = f62
122 tan_rsq                      = f63
123 tan_rcube                    = f64
124
125 tan_v18                      = f65
126 tan_v16                      = f66
127 tan_v17                      = f67
128 tan_v12                      = f68
129 tan_v13                      = f69
130 tan_v7                       = f70
131 tan_v8                       = f71
132 tan_v4                       = f72
133 tan_v5                       = f73
134 tan_v15                      = f74
135 tan_v11                      = f75
136 tan_v14                      = f76
137 tan_v3                       = f77
138 tan_v6                       = f78
139 tan_v10                      = f79
140 tan_v2                       = f80
141 tan_v9                       = f81
142 tan_v1                       = f82
143 tan_int_Nfloat               = f83 
144 tan_Nfloat                   = f84 
145
146 tan_NORM_f8                  = f85 
147 tan_W                        = f86
148
149 tan_y0                       = f87
150 tan_d                        = f88 
151 tan_y1                       = f89 
152 tan_dsq                      = f90 
153 tan_y2                       = f91 
154 tan_d4                       = f92 
155 tan_inv_r                    = f93 
156
157 tan_z1                       = f94
158 tan_z2                       = f95
159 tan_z3                       = f96
160 tan_z4                       = f97
161 tan_z5                       = f98
162 tan_z6                       = f99
163 tan_z7                       = f100
164 tan_z8                       = f101
165 tan_z9                       = f102
166 tan_z10                      = f103
167 tan_z11                      = f104
168 tan_z12                      = f105
169
170
171 /////////////////////////////////////////////////////////////
172
173 tan_GR_sig_inv_pi_by_2       = r14
174 tan_GR_rshf_2to64            = r15
175 tan_GR_exp_2tom64            = r16
176 tan_GR_n                     = r17
177 tan_GR_rshf                  = r18
178
179 tan_AD                       = r33
180 tan_GR_10009                 = r34 
181 tan_GR_17_ones               = r35 
182 tan_GR_N_odd_even            = r36 
183 tan_GR_N                     = r37 
184 tan_signexp                  = r38
185 tan_exp                      = r39
186 tan_ADQ                      = r40
187
188 GR_SAVE_PFS                  = r41 
189 GR_SAVE_B0                   = r42       
190 GR_SAVE_GP                   = r43      
191
192
193 #ifdef _LIBC
194 .rodata
195 #else
196 .data
197 #endif
198
199 .align 16
200
201 double_tan_constants:
202 ASM_TYPE_DIRECTIVE(double_tan_constants,@object)
203 //   data8 0xA2F9836E4E44152A, 0x00003FFE // 2/pi
204    data8 0xC90FDAA22168C234, 0x00003FFF // pi/2 hi
205
206    data8 0xBEEA54580DDEA0E1 // P14 
207    data8 0x3ED3021ACE749A59 // P15
208    data8 0xBEF312BD91DC8DA1 // P12 
209    data8 0x3EFAE9AFC14C5119 // P13
210    data8 0x3F2F342BF411E769 // P8
211    data8 0x3F1A60FC9F3B0227 // P9
212    data8 0x3EFF246E78E5E45B // P10
213    data8 0x3F01D9D2E782875C // P11
214    data8 0x3F8226E34C4499B6 // P4
215    data8 0x3F6D6D3F12C236AC // P5
216    data8 0x3F57DA1146DCFD8B // P6
217    data8 0x3F43576410FE3D75 // P7
218    data8 0x3FD5555555555555 // P0
219    data8 0x3FC11111111111C2 // P1
220    data8 0x3FABA1BA1BA0E850 // P2
221    data8 0x3F9664F4886725A7 // P3
222 ASM_SIZE_DIRECTIVE(double_tan_constants)
223
224 double_Q_tan_constants:
225 ASM_TYPE_DIRECTIVE(double_Q_tan_constants,@object)
226    data8 0xC4C6628B80DC1CD1, 0x00003FBF // pi/2 lo
227    data8 0x3E223A73BA576E48 // Q8
228    data8 0x3DF54AD8D1F2CA43 // Q9
229    data8 0x3EF66A8EE529A6AA // Q4
230    data8 0x3EC2281050410EE6 // Q5
231    data8 0x3E8D6BB992CC3CF5 // Q6
232    data8 0x3E57F88DE34832E4 // Q7
233    data8 0x3FD5555555555555 // Q0
234    data8 0x3F96C16C16C16DB8 // Q1
235    data8 0x3F61566ABBFFB489 // Q2
236    data8 0x3F2BBD77945C1733 // Q3
237    data8 0x3D927FB33E2B0E04 // Q10
238 ASM_SIZE_DIRECTIVE(double_Q_tan_constants)
239
240
241    
242 .align 32
243 .global tanf#
244 #ifdef _LIBC
245 .global __tanf#
246 #endif
247
248 ////////////////////////////////////////////////////////
249
250
251
252 .section .text
253 .proc  tanf#
254 #ifdef _LIBC
255 .proc  __tanf#
256 #endif
257 .align 32
258 tanf:
259 #ifdef _LIBC
260 __tanf:
261 #endif
262 // The initial fnorm will take any unmasked faults and
263 // normalize any single/double unorms
264
265 { .mlx
266       alloc          r32=ar.pfs,1,11,0,0               
267       movl tan_GR_sig_inv_pi_by_2 = 0xA2F9836E4E44152A // significand of 2/pi
268 }
269 { .mlx
270       addl           tan_AD   = @ltoff(double_tan_constants), gp
271       movl tan_GR_rshf_2to64 = 0x47e8000000000000 // 1.1000 2^(63+63+1)
272 }
273 ;;
274
275 { .mfi
276       ld8 tan_AD = [tan_AD]
277       fnorm     tan_NORM_f8  = f8                      
278       mov tan_GR_exp_2tom64 = 0xffff-64 // exponent of scaling factor 2^-64
279 }
280 { .mlx
281       nop.m 999
282       movl tan_GR_rshf = 0x43e8000000000000 // 1.1000 2^63 for right shift
283 }
284 ;;
285
286
287 // Form two constants we need
288 //   2/pi * 2^1 * 2^63, scaled by 2^64 since we just loaded the significand
289 //   1.1000...000 * 2^(63+63+1) to right shift int(W) into the significand
290 { .mmi
291       setf.sig TAN_INV_PI_BY_2_2TO64 = tan_GR_sig_inv_pi_by_2
292       setf.d TAN_RSHF_2TO64 = tan_GR_rshf_2to64
293       mov       tan_GR_17_ones     = 0x1ffff             ;;
294 }
295
296
297 // Form another constant
298 //   2^-64 for scaling Nfloat
299 //   1.1000...000 * 2^63, the right shift constant
300 { .mmf
301       setf.exp TAN_2TOM64 = tan_GR_exp_2tom64
302       adds tan_ADQ = double_Q_tan_constants - double_tan_constants, tan_AD
303       fclass.m.unc  p6,p0 = f8, 0x07  // Test for x=0
304 }
305 ;;
306
307
308 // Form another constant
309 //   2^-64 for scaling Nfloat
310 //   1.1000...000 * 2^63, the right shift constant
311 { .mmf
312       setf.d TAN_RSHF = tan_GR_rshf
313       ldfe      tan_Pi_by_2_hi = [tan_AD],16 
314       fclass.m.unc  p7,p0 = f8, 0x23  // Test for x=inf
315 }
316 ;;
317
318 { .mfb
319       ldfe      tan_Pi_by_2_lo = [tan_ADQ],16           
320       fclass.m.unc  p8,p0 = f8, 0xc3  // Test for x=nan
321 (p6)  br.ret.spnt    b0    ;;         // Exit for x=0
322 }
323
324 { .mfi
325       ldfpd     tan_P14,tan_P15 = [tan_AD],16                         
326 (p7)  frcpa.s0  f8,p9=f0,f0           // Set qnan indef if x=inf
327       mov       tan_GR_10009 = 0x10009
328 }
329 { .mib
330       ldfpd      tan_Q8,tan_Q9  = [tan_ADQ],16                        
331       nop.i 999
332 (p7)  br.ret.spnt    b0    ;;         // Exit for x=inf
333 }
334
335 { .mfi
336       ldfpd      tan_P12,tan_P13 = [tan_AD],16                         
337 (p8)  fma.s f8=f8,f1,f8               // Set qnan if x=nan
338       nop.i 999
339 }
340 { .mib
341       ldfpd      tan_Q4,tan_Q5  = [tan_ADQ],16                        
342       nop.i 999
343 (p8)  br.ret.spnt    b0    ;;         // Exit for x=nan
344 }
345
346 { .mmi
347       getf.exp  tan_signexp    = tan_NORM_f8                 
348       ldfpd      tan_P8,tan_P9  = [tan_AD],16                         
349       nop.i 999 ;;
350 }
351
352 // Multiply x by scaled 2/pi and add large const to shift integer part of W to 
353 //   rightmost bits of significand
354 { .mfi
355       ldfpd      tan_Q6,tan_Q7  = [tan_ADQ],16
356       fma.s1 TAN_W_2TO64_RSH = tan_NORM_f8,TAN_INV_PI_BY_2_2TO64,TAN_RSHF_2TO64
357       nop.i 999 ;;
358 }
359
360 { .mmi
361       ldfpd      tan_P10,tan_P11 = [tan_AD],16                         
362       nop.m 999
363       and       tan_exp = tan_GR_17_ones, tan_signexp         ;;
364 }
365
366
367 // p7 is true if we must call DBX TAN
368 // p7 is true if f8 exp is > 0x10009 (which includes all ones
369 //    NAN or inf)
370 { .mmi
371       ldfpd      tan_Q0,tan_Q1  = [tan_ADQ],16                         
372       cmp.ge.unc  p7,p0 = tan_exp,tan_GR_10009               
373       nop.i 999 ;;
374 }
375
376
377 { .mmb
378       ldfpd      tan_P4,tan_P5  = [tan_AD],16                         
379       nop.m 999
380 (p7)  br.cond.spnt   L(TAN_DBX) ;;                                  
381 }
382
383
384 { .mmi
385       ldfpd      tan_Q2,tan_Q3  = [tan_ADQ],16                         
386       nop.m 999
387       nop.i 999 ;;
388 }
389
390
391
392 // TAN_NFLOAT = Round_Int_Nearest(tan_W)
393 { .mfi
394       ldfpd      tan_P6,tan_P7  = [tan_AD],16                         
395       fms.s1 TAN_NFLOAT = TAN_W_2TO64_RSH,TAN_2TOM64,TAN_RSHF      
396       nop.i 999 ;;
397 }
398
399
400 { .mfi
401       ldfd      tan_Q10 = [tan_ADQ]
402       nop.f 999
403       nop.i 999 ;;
404 }
405
406
407 { .mfi
408       ldfpd      tan_P0,tan_P1  = [tan_AD],16                         
409       nop.f 999
410       nop.i 999 ;;
411 }
412
413
414 { .mfi
415       getf.sig    tan_GR_n = TAN_W_2TO64_RSH
416       nop.f 999
417       nop.i 999 ;;
418 }
419
420 // tan_r          = -tan_Nfloat * tan_Pi_by_2_hi + x
421 { .mfi
422       ldfpd      tan_P2,tan_P3  = [tan_AD]
423       fnma.s1  tan_r      = TAN_NFLOAT, tan_Pi_by_2_hi,  tan_NORM_f8         
424       nop.i 999 ;;
425 }
426
427
428 // p8 ==> even
429 // p9 ==> odd
430 { .mmi
431       and         tan_GR_N_odd_even = 0x1, tan_GR_n ;;          
432       nop.m 999
433       cmp.eq.unc  p8,p9          = tan_GR_N_odd_even, r0      ;;
434 }
435
436
437 // tan_r          = tan_r -tan_Nfloat * tan_Pi_by_2_lo 
438 { .mfi
439       nop.m 999
440       fnma.s1  tan_r      = TAN_NFLOAT, tan_Pi_by_2_lo,  tan_r      
441       nop.i 999 ;;
442 }
443
444
445 { .mfi
446       nop.m 999
447       fma.s1   tan_rsq    = tan_r, tan_r,   f0                      
448       nop.i 999 ;;
449 }
450
451
452 { .mfi
453       nop.m 999
454 (p9)  frcpa.s1   tan_y0, p10 = f1,tan_r                  
455       nop.i 999  ;;
456 }
457
458
459 { .mfi
460       nop.m 999
461 (p8)  fma.s1  tan_v18 = tan_rsq, tan_P15, tan_P14        
462       nop.i 999
463 }
464 { .mfi
465       nop.m 999
466 (p8)  fma.s1  tan_v4  = tan_rsq, tan_P1, tan_P0          
467       nop.i 999  ;;
468 }
469
470
471
472 { .mfi
473       nop.m 999
474 (p8)  fma.s1  tan_v16 = tan_rsq, tan_P13, tan_P12        
475       nop.i 999 
476 }
477 { .mfi
478       nop.m 999
479 (p8)  fma.s1  tan_v17 = tan_rsq, tan_rsq, f0             
480       nop.i 999 ;;
481 }
482
483
484
485 { .mfi
486       nop.m 999
487 (p8)  fma.s1  tan_v12 = tan_rsq, tan_P9, tan_P8          
488       nop.i 999 
489 }
490 { .mfi
491       nop.m 999
492 (p8)  fma.s1  tan_v13 = tan_rsq, tan_P11, tan_P10        
493       nop.i 999 ;;
494 }
495
496
497
498 { .mfi
499       nop.m 999
500 (p8)  fma.s1  tan_v7  = tan_rsq, tan_P5, tan_P4          
501       nop.i 999 
502 }
503 { .mfi
504       nop.m 999
505 (p8)  fma.s1  tan_v8  = tan_rsq, tan_P7, tan_P6          
506       nop.i 999 ;;
507 }
508
509
510
511 { .mfi
512       nop.m 999
513 (p9)  fnma.s1    tan_d   = tan_r, tan_y0, f1   
514       nop.i 999 
515 }
516 { .mfi
517       nop.m 999
518 (p8)  fma.s1  tan_v5  = tan_rsq, tan_P3, tan_P2          
519       nop.i 999 ;;
520 }
521
522
523
524 { .mfi
525       nop.m 999
526 (p9)  fma.s1  tan_z11 = tan_rsq, tan_Q9, tan_Q8         
527       nop.i 999
528 }
529 { .mfi
530       nop.m 999
531 (p9)  fma.s1  tan_z12 = tan_rsq, tan_rsq, f0            
532       nop.i 999 ;;
533 }
534
535
536 { .mfi
537       nop.m 999
538 (p8)  fma.s1  tan_v15 = tan_v17, tan_v18, tan_v16        
539       nop.i 999 
540 }
541 { .mfi
542       nop.m 999
543 (p9)  fma.s1  tan_z7 = tan_rsq, tan_Q5, tan_Q4          
544       nop.i 999 ;;
545 }
546
547
548 { .mfi
549       nop.m 999
550 (p8)  fma.s1  tan_v11 = tan_v17, tan_v13, tan_v12        
551       nop.i 999
552 }
553 { .mfi
554       nop.m 999
555 (p9)  fma.s1  tan_z8 = tan_rsq, tan_Q7, tan_Q6          
556       nop.i 999 ;;
557 }
558
559
560
561 { .mfi
562       nop.m 999
563 (p8)  fma.s1  tan_v14 = tan_v17, tan_v17, f0             
564       nop.i 999 
565 }
566 { .mfi
567       nop.m 999
568 (p9)  fma.s1  tan_z3 = tan_rsq, tan_Q1, tan_Q0          
569       nop.i 999 ;; 
570 }
571
572
573
574
575 { .mfi
576       nop.m 999
577 (p8)  fma.s1  tan_v3 = tan_v17, tan_v5, tan_v4           
578       nop.i 999
579 }
580 { .mfi
581       nop.m 999
582 (p8)  fma.s1  tan_v6 = tan_v17, tan_v8, tan_v7           
583       nop.i 999 ;;
584 }
585
586
587
588 { .mfi
589       nop.m 999
590 (p9)  fma.s1     tan_y1  = tan_y0, tan_d, tan_y0    
591       nop.i 999 
592 }
593 { .mfi
594       nop.m 999
595 (p9)  fma.s1     tan_dsq = tan_d, tan_d, f0        
596       nop.i 999 ;; 
597 }
598
599
600 { .mfi
601       nop.m 999
602 (p9)  fma.s1  tan_z10 = tan_z12, tan_Q10, tan_z11       
603       nop.i 999 
604 }
605 { .mfi
606       nop.m 999
607 (p9)  fma.s1  tan_z9  = tan_z12, tan_z12,f0             
608       nop.i 999 ;;
609 }
610
611
612 { .mfi
613       nop.m 999
614 (p9)  fma.s1  tan_z4 = tan_rsq, tan_Q3, tan_Q2          
615       nop.i 999 
616 }
617 { .mfi
618       nop.m 999
619 (p9)  fma.s1  tan_z6  = tan_z12, tan_z8, tan_z7         
620       nop.i 999 ;; 
621 }
622
623
624
625 { .mfi
626       nop.m 999
627 (p8)  fma.s1  tan_v10 = tan_v14, tan_v15, tan_v11        
628       nop.i 999 ;; 
629 }
630
631
632
633 { .mfi
634       nop.m 999
635 (p9)  fma.s1     tan_y2  = tan_y1, tan_d, tan_y0         
636       nop.i 999 
637 }
638 { .mfi
639       nop.m 999
640 (p9)  fma.s1     tan_d4  = tan_dsq, tan_dsq, tan_d       
641       nop.i 999  ;;
642 }
643
644
645 { .mfi
646       nop.m 999
647 (p8)  fma.s1  tan_v2 = tan_v14, tan_v6, tan_v3           
648       nop.i 999
649 }
650 { .mfi
651       nop.m 999
652 (p8)  fma.s1  tan_v9 = tan_v14, tan_v14, f0              
653       nop.i 999 ;;
654 }
655
656
657 { .mfi
658       nop.m 999
659 (p9)  fma.s1  tan_z2  = tan_z12, tan_z4, tan_z3         
660       nop.i 999 
661 }
662 { .mfi
663       nop.m 999
664 (p9)  fma.s1  tan_z5  = tan_z9, tan_z10, tan_z6         
665       nop.i 999  ;;
666 }
667
668
669 { .mfi
670       nop.m 999
671 (p9)  fma.s1     tan_inv_r = tan_d4, tan_y2, tan_y0      
672       nop.i 999 
673 }
674 { .mfi
675       nop.m 999
676 (p8)  fma.s1   tan_rcube  = tan_rsq, tan_r,   f0
677       nop.i 999  ;;
678 }
679
680
681
682 { .mfi
683       nop.m 999
684 (p8)  fma.s1  tan_v1 = tan_v9, tan_v10, tan_v2           
685       nop.i 999 
686 }
687 { .mfi
688       nop.m 999
689 (p9)  fma.s1  tan_z1  = tan_z9, tan_z5, tan_z2          
690       nop.i 999   ;;
691 }
692
693
694
695 { .mfi
696       nop.m 999
697 (p8)  fma.s.s0  f8  = tan_v1, tan_rcube, tan_r             
698       nop.i 999  
699 }
700 { .mfb
701       nop.m 999
702 (p9)  fms.s.s0  f8  = tan_r, tan_z1, tan_inv_r        
703       br.ret.sptk    b0 ;;    
704 }
705 .endp tanf#
706 ASM_SIZE_DIRECTIVE(tanf#)
707
708
709 .proc __libm_callout
710 __libm_callout:
711 L(TAN_DBX): 
712 .prologue
713
714 { .mfi
715         nop.m 0
716      fmerge.s f9 = f0,f0 
717 .save   ar.pfs,GR_SAVE_PFS
718         mov  GR_SAVE_PFS=ar.pfs
719 }
720 ;;
721
722 { .mfi
723         mov GR_SAVE_GP=gp
724         nop.f 0
725 .save   b0, GR_SAVE_B0
726         mov GR_SAVE_B0=b0
727 }
728
729 .body
730 { .mfb
731       nop.m 999
732       nop.f 999
733        br.call.sptk.many  b0=__libm_tan# ;;
734 }
735
736
737 { .mfi
738        mov gp        = GR_SAVE_GP
739       fnorm.s     f8 = f8
740        mov b0        = GR_SAVE_B0 
741 }
742 ;;
743
744
745 { .mib
746          nop.m 999
747       mov ar.pfs    = GR_SAVE_PFS
748       br.ret.sptk     b0
749 ;;
750 }
751
752
753 .endp  __libm_callout
754 ASM_SIZE_DIRECTIVE(__libm_callout)
755
756 .type __libm_tan#,@function
757 .global __libm_tan#