Various cleanups.
[kopensolaris-gnu/glibc.git] / sysdeps / ia64 / memcmp.S
1 /* Optimized version of the standard memcmp() function.
2    This file is part of the GNU C Library.
3    Copyright (C) 2000 Free Software Foundation, Inc.
4    Contributed by Dan Pop <Dan.Pop@cern.ch>.
5
6    The GNU C Library is free software; you can redistribute it and/or
7    modify it under the terms of the GNU Library General Public License as
8    published by the Free Software Foundation; either version 2 of the
9    License, or (at your option) any later version.
10
11    The GNU C Library is distributed in the hope that it will be useful,
12    but WITHOUT ANY WARRANTY; without even the implied warranty of
13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14    Library General Public License for more details.
15
16    You should have received a copy of the GNU Library General Public
17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
19    Boston, MA 02111-1307, USA.  */
20
21 /* Return: the result of the comparison
22
23    Inputs:
24         in0:    dest (aka s1)
25         in1:    src  (aka s2)
26         in2:    byte count
27
28    In this form, it assumes little endian mode.  For big endian mode, the
29    the two shifts in .l2 must be inverted:
30
31         shl     tmp1[0] = r[1 + MEMLAT], sh1   // tmp1 = w0 << sh1
32         shr.u   tmp2[0] = r[0 + MEMLAT], sh2   // tmp2 = w1 >> sh2
33
34    and all the mux1 instructions should be replaced by plain mov's.  */
35
36 #include <sysdep.h>
37 #undef ret
38
39 #define OP_T_THRES      16
40 #define OPSIZ           8
41 #define MEMLAT          2
42
43 #define saved_pfs       r14
44 #define start           r15
45 #define saved_pr        r17
46 #define saved_lc        r18
47 #define dest            r19
48 #define src             r20
49 #define len             r21
50 #define asrc            r22
51 #define tmp             r23
52 #define value1          r24
53 #define value2          r25
54 #define sh2             r28
55 #define sh1             r29
56 #define loopcnt         r30
57
58 ENTRY(memcmp)
59         alloc   saved_pfs = ar.pfs, 3, 37, 0, 40
60
61         .rotr   r[MEMLAT + 2], q[MEMLAT + 5], tmp1[4], tmp2[4], val[2]
62         .rotp   p[MEMLAT + 4 + 1]
63
64         mov     ret0 = r0               // by default return value = 0
65         mov     saved_pr = pr           // save the predicate registers
66         mov     saved_lc = ar.lc        // save the loop counter
67         mov     dest = in0              // dest
68         mov     src = in1               // src
69         mov     len = in2               // len
70         sub     tmp = r0, in0           // tmp = -dest
71         ;;
72         and     loopcnt = 7, tmp                // loopcnt = -dest % 8
73         cmp.ge  p6, p0 = OP_T_THRES, len        // is len <= OP_T_THRES
74 (p6)    br.cond.spnt    .cmpfew                 // compare byte by byte
75         ;;
76         cmp.eq  p6, p0 = loopcnt, r0
77 (p6)    br.cond.sptk .dest_aligned
78         sub     len = len, loopcnt      // len -= -dest % 8
79         adds    loopcnt = -1, loopcnt   // --loopcnt
80         ;;
81         mov     ar.lc = loopcnt
82 .l1:                                    // copy -dest % 8 bytes
83         ld1     value1 = [src], 1       // value = *src++
84         ld1     value2 = [dest], 1
85         ;;
86         cmp.ne  p6, p0 = value1, value2
87 (p6)    br.cond.spnt .done
88         br.cloop.dptk .l1       
89 .dest_aligned:
90         and     sh1 = 7, src            // sh1 = src % 8
91         and     tmp = -8, len           // tmp = len & -OPSIZ
92         and     asrc = -8, src          // asrc = src & -OPSIZ  -- align src
93         shr.u   loopcnt = len, 3        // loopcnt = len / 8
94         and     len = 7, len ;;         // len = len % 8
95         shl     sh1 = sh1, 3            // sh1 = 8 * (src % 8)
96         adds    loopcnt = -1, loopcnt   // --loopcnt
97         mov     pr.rot = 1 << 16 ;;     // set rotating predicates
98         sub     sh2 = 64, sh1           // sh2 = 64 - sh1
99         mov     ar.lc = loopcnt         // set LC
100         cmp.eq  p6, p0 = sh1, r0        // is the src aligned?
101 (p6)    br.cond.sptk .src_aligned
102         add     src = src, tmp          // src += len & -OPSIZ
103         mov     ar.ec = MEMLAT + 4 + 1  // four more passes needed
104         ld8     r[1] = [asrc], 8 ;;     // r[1] = w0
105         .align  32
106
107 // We enter this loop with p6 cleared by the above comparison
108
109 .l2:                                    
110 (p[0])          ld8     r[0] = [asrc], 8                // r[0] = w1
111 (p[0])          ld8     q[0] = [dest], 8
112 (p[MEMLAT])     shr.u   tmp1[0] = r[1 + MEMLAT], sh1    // tmp1 = w0 >> sh1
113 (p[MEMLAT])     shl     tmp2[0] = r[0 + MEMLAT], sh2    // tmp2 = w1 << sh2
114 (p[MEMLAT+4])   cmp.ne  p6, p0 = q[MEMLAT + 4], val[1]
115 (p[MEMLAT+3])   or      val[0] = tmp1[3], tmp2[3]       // val = tmp1 | tmp2
116 (p6)            br.cond.spnt .l2exit
117                 br.ctop.sptk    .l2
118                 br.cond.sptk .cmpfew
119 .l3exit:
120         mux1    value1 = r[MEMLAT], @rev
121         mux1    value2 = q[MEMLAT], @rev
122         cmp.ne  p6, p0 = r0, r0 ;;      // clear p6
123 .l2exit:
124 (p6)    mux1    value1 = val[1], @rev
125 (p6)    mux1    value2 = q[MEMLAT + 4], @rev ;;
126         cmp.ltu p6, p7 = value2, value1 ;;
127 (p6)    mov     ret0 = -1
128 (p7)    mov     ret0 = 1
129         mov     ar.pfs = saved_pfs      // restore the PFS
130         mov     pr = saved_pr, -1       // restore the predicate registers
131         mov     ar.lc = saved_lc        // restore the loop counter
132         br.ret.sptk.many b0
133 .src_aligned:
134         cmp.ne  p6, p0 = r0, r0         // clear p6
135         mov     ar.ec = MEMLAT + 1 ;;   // set EC
136 .l3:
137 (p[0])          ld8     r[0] = [src], 8
138 (p[0])          ld8     q[0] = [dest], 8
139 (p[MEMLAT])     cmp.ne  p6, p0 = r[MEMLAT], q[MEMLAT]
140 (p6)            br.cond.spnt .l3exit
141                 br.ctop.dptk .l3 ;;
142 .cmpfew:
143         cmp.eq  p6, p0 = len, r0        // is len == 0 ?
144         adds    len = -1, len           // --len;
145 (p6)    br.cond.spnt    .restore_and_exit ;;
146         mov     ar.lc = len
147 .l4:
148         ld1     value1 = [src], 1
149         ld1     value2 = [dest], 1
150         ;;
151         cmp.ne  p6, p0 = value1, value2
152 (p6)    br.cond.spnt    .done
153         br.cloop.dptk   .l4 ;;
154 .done:
155 (p6)    sub     ret0 = value2, value1   // don't execute it if falling thru
156 .restore_and_exit:
157         mov     ar.pfs = saved_pfs      // restore the PFS
158         mov     pr = saved_pr, -1       // restore the predicate registers
159         mov     ar.lc = saved_lc        // restore the loop counter
160         br.ret.sptk.many b0
161 END(memcmp)
162
163 weak_alias (memcmp, bcmp)