IA64 memcmp implementation.
[kopensolaris-gnu/glibc.git] / sysdeps / ia64 / memcmp.S
1 /*
2  *
3  * Optimized version of the standard memcmp() function
4  *
5  * Contributed by Dan Pop <Dan.Pop@cern.ch>
6  *
7  * Return: the result of the comparison
8  *
9  * Inputs:
10  *      in0:    dest (aka s1)
11  *      in1:    src  (aka s2)
12  *      in2:    byte count
13  *
14  * In this form, it assumes little endian mode.  For big endian mode, the
15  * the two shifts in .l2 must be inverted:
16  *
17  *      shl     tmp1[0] = r[1 + MEMLAT], sh1   // tmp1 = w0 << sh1
18  *      shr.u   tmp2[0] = r[0 + MEMLAT], sh2   // tmp2 = w1 >> sh2
19  *
20  * and all the mux1 instructions should be replaced by plain mov's.
21  *
22  */
23
24 #include <sysdep.h>
25 #undef ret
26
27 #define OP_T_THRES      16
28 #define OPSIZ           8
29 #define MEMLAT          2
30
31 #define saved_pfs       r14
32 #define start           r15
33 #define saved_pr        r17
34 #define saved_lc        r18
35 #define dest            r19
36 #define src             r20
37 #define len             r21
38 #define asrc            r22
39 #define tmp             r23
40 #define value1          r24
41 #define value2          r25
42 #define sh2             r28
43 #define sh1             r29
44 #define loopcnt         r30
45
46 ENTRY(memcmp)
47         alloc   saved_pfs = ar.pfs, 3, 37, 0, 40
48
49         .rotr   r[MEMLAT + 2], q[MEMLAT + 5], tmp1[4], tmp2[4], val[2]
50         .rotp   p[MEMLAT + 4 + 1]
51
52         mov     ret0 = r0               // by default return value = 0
53         mov     saved_pr = pr           // save the predicate registers
54         mov     saved_lc = ar.lc        // save the loop counter
55         mov     dest = in0              // dest
56         mov     src = in1               // src
57         mov     len = in2               // len
58         sub     tmp = r0, in0           // tmp = -dest
59         ;;
60         and     loopcnt = 7, tmp                // loopcnt = -dest % 8
61         cmp.ge  p6, p0 = OP_T_THRES, len        // is len <= OP_T_THRES
62 (p6)    br.cond.spnt    .cmpfew                 // compare byte by byte
63         ;;
64         cmp.eq  p6, p0 = loopcnt, r0
65 (p6)    br.cond.sptk .dest_aligned
66         sub     len = len, loopcnt      // len -= -dest % 8
67         adds    loopcnt = -1, loopcnt   // --loopcnt
68         ;;
69         mov     ar.lc = loopcnt
70 .l1:                                    // copy -dest % 8 bytes
71         ld1     value1 = [src], 1       // value = *src++
72         ld1     value2 = [dest], 1
73         ;;
74         cmp.ne  p6, p0 = value1, value2
75 (p6)    br.cond.spnt .done
76         br.cloop.dptk .l1       
77 .dest_aligned:
78         and     sh1 = 7, src            // sh1 = src % 8
79         and     tmp = -8, len           // tmp = len & -OPSIZ
80         and     asrc = -8, src          // asrc = src & -OPSIZ  -- align src
81         shr.u   loopcnt = len, 3        // loopcnt = len / 8
82         and     len = 7, len ;;         // len = len % 8
83         shl     sh1 = sh1, 3            // sh1 = 8 * (src % 8)
84         adds    loopcnt = -1, loopcnt   // --loopcnt
85         mov     pr.rot = 1 << 16 ;;     // set rotating predicates
86         sub     sh2 = 64, sh1           // sh2 = 64 - sh1
87         mov     ar.lc = loopcnt         // set LC
88         cmp.eq  p6, p0 = sh1, r0        // is the src aligned?
89 (p6)    br.cond.sptk .src_aligned
90         add     src = src, tmp          // src += len & -OPSIZ
91         mov     ar.ec = MEMLAT + 4 + 1  // four more passes needed
92         ld8     r[1] = [asrc], 8 ;;     // r[1] = w0
93         .align  32
94
95 // We enter this loop with p6 cleared by the above comparison
96
97 .l2:                                    
98 (p[0])          ld8     r[0] = [asrc], 8                // r[0] = w1
99 (p[0])          ld8     q[0] = [dest], 8
100 (p[MEMLAT])     shr.u   tmp1[0] = r[1 + MEMLAT], sh1    // tmp1 = w0 >> sh1
101 (p[MEMLAT])     shl     tmp2[0] = r[0 + MEMLAT], sh2    // tmp2 = w1 << sh2
102 (p[MEMLAT+4])   cmp.ne  p6, p0 = q[MEMLAT + 4], val[1]
103 (p[MEMLAT+3])   or      val[0] = tmp1[3], tmp2[3]       // val = tmp1 | tmp2
104 (p6)            br.cond.spnt .l2exit
105                 br.ctop.sptk    .l2
106                 br.cond.sptk .cmpfew
107 .l3exit:
108         mux1    value1 = r[MEMLAT], @rev
109         mux1    value2 = q[MEMLAT], @rev
110         cmp.ne  p6, p0 = r0, r0 ;;      // clear p6
111 .l2exit:
112 (p6)    mux1    value1 = val[1], @rev
113 (p6)    mux1    value2 = q[MEMLAT + 4], @rev ;;
114         cmp.ltu p6, p7 = value2, value1 ;;
115 (p6)    mov     ret0 = -1
116 (p7)    mov     ret0 = 1
117         mov     ar.pfs = saved_pfs      // restore the PFS
118         mov     pr = saved_pr, -1       // restore the predicate registers
119         mov     ar.lc = saved_lc        // restore the loop counter
120         br.ret.sptk.many b0
121 .src_aligned:
122         cmp.ne  p6, p0 = r0, r0         // clear p6
123         mov     ar.ec = MEMLAT + 1 ;;   // set EC
124 .l3:
125 (p[0])          ld8     r[0] = [src], 8
126 (p[0])          ld8     q[0] = [dest], 8
127 (p[MEMLAT])     cmp.ne  p6, p0 = r[MEMLAT], q[MEMLAT]
128 (p6)            br.cond.spnt .l3exit
129                 br.ctop.dptk .l3 ;;
130 .cmpfew:
131         cmp.eq  p6, p0 = len, r0        // is len == 0 ?
132         adds    len = -1, len           // --len;
133 (p6)    br.cond.spnt    .restore_and_exit ;;
134         mov     ar.lc = len
135 .l4:
136         ld1     value1 = [src], 1
137         ld1     value2 = [dest], 1
138         ;;
139         cmp.ne  p6, p0 = value1, value2
140 (p6)    br.cond.spnt    .done
141         br.cloop.dptk   .l4 ;;
142 .done:
143 (p6)    sub     ret0 = value2, value1   // don't execute it if falling thru
144 .restore_and_exit:
145         mov     ar.pfs = saved_pfs      // restore the PFS
146         mov     pr = saved_pr, -1       // restore the predicate registers
147         mov     ar.lc = saved_lc        // restore the loop counter
148         br.ret.sptk.many b0
149 END(memcmp)
150
151 weak_alias (memcmp, bcmp)