Various cleanups.
[kopensolaris-gnu/glibc.git] / sysdeps / ia64 / strchr.S
1 /* Optimized version of the standard strchr() function.
2    This file is part of the GNU C Library.
3    Copyright (C) 2000 Free Software Foundation, Inc.
4    Contributed by Dan Pop <Dan.Pop@cern.ch>.
5
6    The GNU C Library is free software; you can redistribute it and/or
7    modify it under the terms of the GNU Library General Public License as
8    published by the Free Software Foundation; either version 2 of the
9    License, or (at your option) any later version.
10
11    The GNU C Library is distributed in the hope that it will be useful,
12    but WITHOUT ANY WARRANTY; without even the implied warranty of
13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14    Library General Public License for more details.
15
16    You should have received a copy of the GNU Library General Public
17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
19    Boston, MA 02111-1307, USA.  */
20
21 /* Return: the address of the first occurence of chr in str or NULL
22
23    Inputs:
24         in0:    str
25         in1:    chr
26
27    A modified version of memchr.S, the search ends when the character is
28    found or the terminating null character is encountered.
29
30    This implementation assumes little endian mode.  For big endian mode,
31    the instruction czx1.r should be replaced by czx1.l.  */
32
33 #include <sysdep.h>
34 #undef ret
35
36 #define saved_pfs       r14
37 #define saved_lc        r18
38 #define poschr          r19
39 #define pos0            r20
40 #define val1            r21
41 #define val2            r22
42 #define tmp             r24
43 #define chrx8           r25
44 #define loopcnt         r30
45
46 #define str             in0
47 #define chr             in1
48
49 ENTRY(strchr)
50         alloc saved_pfs = ar.pfs, 2, 0, 0, 0
51         mov     saved_lc = ar.lc        // save the loop counter
52         mov     ret0 = str      
53         and     tmp = 7, str            // tmp = str % 8
54         mux1    chrx8 = chr, @brcst
55         extr.u  chr = chr, 0, 8         // retain only the last byte
56         cmp.ne  p8, p0 = r0, r0         // clear p8
57         ;;
58         sub     loopcnt = 8, tmp        // loopcnt = 8 - tmp
59         cmp.eq  p6, p0 = tmp, r0
60 (p6)    br.cond.sptk    .str_aligned;;
61         adds    loopcnt = -1, loopcnt;;
62         mov     ar.lc = loopcnt
63 .l1:
64         ld1     val2 = [ret0], 1
65         ;;
66         cmp.eq  p6, p0 = val2, chr
67         cmp.eq  p7, p0 = val2, r0
68 (p6)    br.cond.spnt    .restore_and_exit
69 (p7)    br.cond.spnt    .notfound
70         br.cloop.sptk   .l1
71 .str_aligned:
72         ld8     val1 = [ret0], 8;;
73         nop.b   0
74         nop.b   0
75 .l2:    
76         ld8.s   val2 = [ret0], 8        // don't bomb out here
77         czx1.r  pos0 = val1     
78         xor     tmp = val1, chrx8       // if val1 contains chr, tmp will
79         ;;                              // contain a zero in its position
80         czx1.r  poschr = tmp
81         cmp.ne  p6, p0 = 8, pos0
82         ;;
83         cmp.ne  p7, p0 = 8, poschr
84 (p7)    br.cond.spnt .foundit
85 (p6)    br.cond.spnt .notfound
86         chk.s   val2, .recovery
87 .back:
88         mov     val1 = val2     
89         br.cond.dptk .l2
90 .foundit:
91 (p6)    cmp.lt  p8, p0 = pos0, poschr   // we found chr and null in the word
92 (p8)    br.cond.spnt .notfound          // null was found before chr
93         add     ret0 = ret0, poschr ;;
94         adds    ret0 = -15, ret0 ;;     // should be -16, but we decrement
95 .restore_and_exit:                      // ret0 in the next instruction
96         adds    ret0 = -1, ret0         // ret0 was pointing 1 char too far
97         mov     ar.pfs = saved_pfs      // restore the PFS
98         mov     ar.lc = saved_lc        // restore the loop counter
99         br.ret.sptk.many b0
100 .notfound:
101         mov     ret0 = r0               // return NULL if null was found
102         mov     ar.pfs = saved_pfs      // first
103         mov     ar.lc = saved_lc
104         br.ret.sptk.many b0
105 .recovery:
106         adds    ret0 = -8, ret0;;
107         ld8     val2 = [ret0], 8        // bomb out here
108         br.cond.sptk    .back
109 END(strchr)
110
111 weak_alias(strchr, index)