2002-09-30 Jakub Jelinek <jakub@redhat.com>
[kopensolaris-gnu/glibc.git] / sysdeps / ia64 / strncpy.S
1 /* Optimized version of the standard strncpy() function.
2    This file is part of the GNU C Library.
3    Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc.
4    Contributed by Dan Pop <Dan.Pop@cern.ch>
5               and Jakub Jelinek <jakub@redhat.com>.
6
7    The GNU C Library is free software; you can redistribute it and/or
8    modify it under the terms of the GNU Lesser General Public
9    License as published by the Free Software Foundation; either
10    version 2.1 of the License, or (at your option) any later version.
11
12    The GNU C Library is distributed in the hope that it will be useful,
13    but WITHOUT ANY WARRANTY; without even the implied warranty of
14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15    Lesser General Public License for more details.
16
17    You should have received a copy of the GNU Lesser General Public
18    License along with the GNU C Library; if not, write to the Free
19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
20    02111-1307 USA.  */
21
22 /* Return: dest
23
24    Inputs:
25         in0:    dest
26         in1:    src
27         in2:    len
28
29    In this form, it assumes little endian mode.
30  */
31
32 #include <sysdep.h>
33 #undef ret
34
35 #define saved_lc        r15
36 #define saved_pr        r16
37 #define thresh          r17
38 #define dest            r18
39 #define dest2           r19
40 #define src             r20
41 #define len             r21
42 #define asrc            r22
43 #define tmp             r23
44 #define pos             r24
45 #define w0              r25
46 #define w1              r26
47 #define c               r27
48 #define sh2             r28
49 #define sh1             r29
50 #define loopcnt         r30
51 #define value           r31
52
53 ENTRY(strncpy)
54         .prologue
55         alloc   r2 = ar.pfs, 3, 0, 29, 32
56
57 #define MEMLAT 2
58         .rotr   r[MEMLAT + 2]
59         .rotp   p[MEMLAT + 1]
60
61         mov     ret0 = in0              // return value = dest
62         .save pr, saved_pr
63         mov     saved_pr = pr           // save the predicate registers
64         .save ar.lc, saved_lc
65         mov     saved_lc = ar.lc        // save the loop counter
66         .body
67         cmp.geu p6, p5 = 24, in2
68 (p6)    br.cond.spnt .short_len
69         sub     tmp = r0, in0 ;;        // tmp = -dest
70         mov     len = in2               // len
71         mov     dest = in0              // dest
72         mov     src = in1               // src
73         and     tmp = 7, tmp ;;         // loopcnt = -dest % 8
74         cmp.eq  p6, p7 = tmp, r0
75         adds    loopcnt = -1, tmp       // --loopcnt
76 (p6)    br.cond.sptk .dest_aligned ;;
77         sub     len = len, tmp          // len -= -dest % 8
78         mov     ar.lc = loopcnt
79 .l1:                                    // copy -dest % 8 bytes
80 (p5)    ld1     c = [src], 1            // c = *src++
81         ;;
82         st1     [dest] = c, 1           // *dest++ = c
83         cmp.ne  p5, p7 = c, r0
84         br.cloop.dptk .l1 ;;
85 (p7)    br.cond.dpnt    .found0_align
86
87 .dest_aligned:                          // p7 should be cleared here
88         shr.u   c = len, 3              // c = len / 8
89         and     sh1 = 7, src            // sh1 = src % 8
90         and     asrc = -8, src ;;       // asrc = src & -OPSIZ  -- align src
91         adds    c = (MEMLAT-1), c       // c = (len / 8) + MEMLAT - 1
92         sub     thresh = 8, sh1
93         mov     pr.rot = 1 << 16        // set rotating predicates
94         shl     sh1 = sh1, 3 ;;         // sh1 = 8 * (src % 8)
95         mov     ar.lc = c               // "infinite" loop
96         sub     sh2 = 64, sh1           // sh2 = 64 - sh1
97         cmp.eq  p6, p0 = sh1, r0        // is the src aligned?
98 (p6)    br.cond.sptk .src_aligned
99         adds    c = -(MEMLAT-1), c ;;   // c = (len / 8)
100         ld8     r[1] = [asrc],8
101         mov     ar.lc = c ;;
102
103         .align  32
104 .l2:
105 (p6)    st8     [dest] = value, 8       // store val to dest
106         ld8.s   r[0] = [asrc], 8
107         shr.u   value = r[1], sh1 ;;    // value = w0 >> sh1
108         czx1.r  pos = value ;;          // do we have an "early" zero
109         cmp.lt  p7, p0 = pos, thresh    // in w0 >> sh1?
110         adds    len = -8, len           // len -= 8
111 (p7)    br.cond.dpnt .nonalign_found0
112         chk.s   r[0], .recovery2        // it is safe to do that only
113 .back2:                                 // after the previous test
114         shl     tmp = r[0], sh2         // tmp = w1 << sh2
115         ;;
116         or      value = value, tmp ;;   // value |= tmp
117         czx1.r  pos = value ;;
118         cmp.ne  p7, p6 = 8, pos
119 (p7)    br.cond.dpnt .nonalign_found0
120         br.ctop.dptk    .l2 ;;
121         adds    len = 8, len
122         br.cond.sptk    .not_found0 ;;
123 .nonalign_found0:
124         cmp.gtu p6, p0 = -8, len
125 (p6)    br.cond.dptk .found0
126         adds    len = 8, len
127         br.cond.sptk    .not_found0 ;;
128
129         .align  32
130 .src_aligned:
131 .l3:
132 (p[0])          ld8.s   r[0] = [src], 8
133 (p[MEMLAT])     chk.s   r[MEMLAT], .recovery3
134 .back3:
135 (p[MEMLAT])     mov     value = r[MEMLAT]
136 (p[MEMLAT])     czx1.r  pos = r[MEMLAT] ;;
137 (p[MEMLAT])     cmp.ne  p7, p0 = 8, pos
138 (p[MEMLAT])     adds    len = -8, len   // len -= 8
139 (p7)            br.cond.dpnt .found0
140 (p[MEMLAT])     st8     [dest] = r[MEMLAT], 8
141                 br.ctop.dptk .l3 ;;
142
143         chk.s   r[MEMLAT-1], .recovery4
144 .back4:
145         mov     value = r[MEMLAT-1]
146
147 .not_found0:
148         cmp.eq  p5, p6 = len, r0
149         adds    len = -1, len
150 (p5)    br.cond.dptk    .restore_and_exit ;;
151         mov     ar.lc = len
152 .l4:
153 (p6)    extr.u  c = value, 0, 8         // c = value & 0xff
154 (p6)    shr.u   value = value, 8 ;;
155         st1     [dest] = c, 1
156         cmp.ne  p6, p0 = c, r0
157         br.cloop.dptk   .l4
158         br.cond.sptk    .restore_and_exit
159
160 .found0_align:
161         mov     pos = 0
162         adds    len = -8, len
163         mov     value = 0 ;;
164 .found0:
165         shl     tmp = pos, 3
166         shr.u   loopcnt = len, 4        // loopcnt = len / 16
167         mov     c = -1 ;;
168         cmp.eq  p6, p0 = loopcnt, r0
169         adds    loopcnt = -1, loopcnt
170         shl     c = c, tmp ;;
171         and     len = 0xf, len
172         andcm   value = value, c
173         mov     ar.lc = loopcnt ;;
174         cmp.le  p7, p0 = 8, len
175         adds    dest2 = 16, dest
176         st8     [dest] = value, 8
177         and     len = 0x7, len
178 (p6)    br.cond.dpnt    .l6 ;;
179 .l5:
180         st8     [dest] = r0, 16
181         st8     [dest2] = r0, 16
182         br.cloop.dptk   .l5 ;;
183 .l6:
184 (p7)    st8     [dest] = r0, 8
185         cmp.eq  p5, p0 = len, r0
186         adds    len = -1, len
187 (p5)    br.cond.dptk .restore_and_exit ;;
188         mov     ar.lc = len ;;
189 .l7:
190         st1     [dest] = r0, 1
191         br.cloop.dptk   .l7 ;;
192 .restore_and_exit:
193         mov     ar.lc = saved_lc        // restore the loop counter
194         mov     pr = saved_pr, -1       // restore the predicate registers
195         br.ret.sptk.many b0
196
197 .short_len:
198         cmp.eq  p5, p0 = in2, r0
199         adds    loopcnt = -1, in2
200 (p5)    br.cond.spnt .restore_and_exit ;;
201         mov     ar.lc = loopcnt         // p6 should be set when we get here
202 .l8:
203 (p6)    ld1     c = [in1], 1            // c = *src++
204         ;;
205         st1     [in0] = c, 1            // *dest++ = c
206 (p6)    cmp.ne  p6, p0 = c, r0
207         br.cloop.dptk .l8
208         ;;
209         mov     ar.lc = saved_lc        // restore the loop counter
210         mov     pr = saved_pr, -1       // restore the predicate registers
211         br.ret.sptk.many b0
212 .recovery2:
213         add     c = 8, len
214         add     tmp = -8, asrc ;;
215         cmp.gtu p8, p5 = c, thresh ;;
216 (p8)    ld8     r[0] = [tmp]
217 (p5)    mov     r[0] = r0
218         br.cond.sptk .back2
219 .recovery3:
220         add     tmp = -MEMLAT * 8, src ;;
221         ld8     r[MEMLAT] = [tmp]
222         br.cond.sptk .back3
223 .recovery4:
224         add     tmp = -(MEMLAT - 1) * 8, src ;;
225         ld8     r[MEMLAT - 1] = [tmp]
226         br.cond.sptk .back4
227 END(strncpy)