2685d6e7701ddebdf1432d1ac0ec925ae93f0819
[kopensolaris-gnu/glibc.git] / sysdeps / libm-i387 / s_expm1.S
1 /* ix87 specific implementation of exp(x)-1.
2    Copyright (C) 1996 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
5    Based on code by John C. Bowman <bowman@ipp-garching.mpg.de>.
6
7    The GNU C Library is free software; you can redistribute it and/or
8    modify it under the terms of the GNU Library General Public License as
9    published by the Free Software Foundation; either version 2 of the
10    License, or (at your option) any later version.
11
12    The GNU C Library is distributed in the hope that it will be useful,
13    but WITHOUT ANY WARRANTY; without even the implied warranty of
14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15    Library General Public License for more details.
16
17    You should have received a copy of the GNU Library General Public
18    License along with the GNU C Library; see the file COPYING.LIB.  If not,
19    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
20    Boston, MA 02111-1307, USA.  */
21
22         /* Using: e^x - 1 = 2^(x * log2(e)) - 1 */
23
24 #include <machine/asm.h>
25
26 #ifdef __ELF__
27         .section .rodata
28 #else
29         .text
30 #endif
31         .align ALIGNARG(4)
32         ASM_TYPE_DIRECTIVE(zero,@object)
33 zero:   .double 0.0
34         ASM_SIZE_DIRECTIVE(zero)
35         ASM_TYPE_DIRECTIVE(one,@object)
36 one:    .double 1.0
37         ASM_SIZE_DIRECTIVE(one)
38         ASM_TYPE_DIRECTIVE(l2e,@object)
39 l2e:    .tfloat 1.442695040888963407359924681002
40         ASM_SIZE_DIRECTIVE(l2e)
41
42 #ifdef PIC
43 #define MO(op) op##@GOTOFF(%edx)
44 #else
45 #define MO(op) op
46 #endif
47
48         .text
49 ENTRY(__expm1)
50         fldl    4(%esp)         // x
51         fxam                    // Is NaN or +-Inf?
52         fstsw   %ax
53 #ifdef  PIC
54         call    1f
55 1:      popl    %edx
56         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
57 #endif
58         movb    $0x45, %ch
59         andb    %ah, %ch
60         cmpb    $0x05, %ch
61         je      2f              // Is +-Inf, jump.
62
63         fldt    MO(l2e)         // log2(e) : x
64         fmulp                   // log2(e)*x
65         fld     %st             // log2(e)*x : log2(e)*x
66         frndint                 // int(log2(e)*x) : log2(e)*x
67         fsub    %st, %st(1)     // int(log2(e)*x) : fract(log2(e)*x)
68         fxch                    // fract(log2(e)*x) : int(log2(e)*x)
69         f2xm1                   // 2^fract(log2(e)*x)-1 : int(log2(e)*x)
70         fscale                  // 2^(log2(e)*x)-2^int(log2(e)*x) : int(log2(e)*x)
71         fxch                    // int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
72         fldl    MO(one)         // 1 : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
73         fscale                  // 2^int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
74         faddp                   // 2^(log2(e)*x)
75         fsubl   MO(one)
76         ret
77
78 2:      testl   $0x200, %eax    // Test sign.
79         jz      3f              // If positive, jump.
80         fldl    MO(zero)        // Set result to 0.
81 3:      ret
82 END(__expm1)
83 weak_alias (__expm1, expm1)