2000-01-05 Roland McGrath <roland@baalperazim.frob.com>
[kopensolaris-gnu/glibc.git] / sysdeps / mach / hurd / errnos.awk
1 # Copyright (C) 1991,92,93,94,95,96,97,2000 Free Software Foundation, Inc.
2 # This file is part of the GNU C Library.
3
4 # The GNU C Library is free software; you can redistribute it and/or
5 # modify it under the terms of the GNU Library General Public License
6 # as published by the Free Software Foundation; either version 2 of
7 # the License, or (at your option) any later version.
8
9 # The GNU C Library is distributed in the hope that it will be useful,
10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12 # Library General Public License for more details.
13
14 # You should have received a copy of the GNU Library General Public
15 # License along with the GNU C Library; see the file COPYING.LIB.  If not,
16 # write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
17 # Boston, MA 02111-1307, USA.
18
19 # errno.texinfo contains lines like:
20 # @comment errno.h
21 # @comment POSIX.1: Function not implemented
22 # @deftypevr Macro int ENOSYS
23 # @comment errno 123
24
25 BEGIN {
26     print "/* This file generated by errnos.awk.  */";
27     print "";
28     print "/* The Hurd uses Mach error system 0x10, currently only subsystem 0. */";
29     print "#ifndef _HURD_ERRNO";
30     print "#define _HURD_ERRNO(n)\t((0x10 << 26) | ((n) & 0x3fff))";
31     print "#endif";
32     print "";
33     print "#ifdef _ERRNO_H\n";
34     print "enum __error_t_codes\n{";
35     errnoh = 0;
36     maxerrno = 0;
37     in_mach_errors = "";
38     in_math = 0;
39     edom = erange = "";
40     print "#undef EDOM\n#undef ERANGE";
41     lno = 0;
42   }
43
44 $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
45 $1 == "@comment" && errnoh == 1 \
46   {
47     ++errnoh;
48     etext = "";
49     for (i = 3; i <= NF; ++i)
50       etext = etext " " $i;
51     next;
52   }
53
54 errnoh == 2 && $1 == "@deftypevr"  && $2 == "Macro" && $3 == "int" \
55   { ++errnoh; e = $4; next; }
56
57 errnoh == 3 && $1 == "@comment" && $2 == "errno" {
58     if (e == "EWOULDBLOCK")
59       {
60         lines[lno++]="#define EWOULDBLOCK EAGAIN /* Operation would block */";
61         next;
62       }
63     errno = $3 + 0;
64     if (errno == 0)
65       next;
66     if (errno > maxerrno) maxerrno = errno;
67     x = sprintf ("%-40s/*%s */", sprintf ("%-24s%s", "#define\t" e,
68                                           "_HURD_ERRNO (" errno ")"),
69                  etext);
70     if (e == "EDOM")
71       edom = x;
72     else if (e == "ERANGE")
73       erange = x;
74     comma[lno] = 1;
75     lines[lno++] = sprintf("\t%-16s= _HURD_ERRNO (%d)", e, errno);
76     lines[lno++] = x;
77     next;
78   }
79 { errnoh=0 }
80
81 NF == 3 && $1 == "#define" && $2 == "MACH_SEND_IN_PROGRESS" \
82   {
83     in_mach_errors = FILENAME;
84     lines[lno++] = "\n\t/* Errors from <mach/message.h>.  */";
85   }
86 NF == 3 && $1 == "#define" && $2 == "KERN_SUCCESS" \
87   {
88     in_mach_errors = FILENAME;
89     lines[lno++] = "\n\t/* Errors from <mach/kern_return.h>.  */";
90     next;
91   }
92
93 in_mach_errors != "" && $2 == "MACH_IPC_COMPAT" \
94   {
95     in_mach_errors = "";
96   }
97
98 in_mach_errors == FILENAME && NF == 3 && $1 == "#define" \
99   {
100     comma[lno] = 1;
101     lines[lno++] = sprintf("\t%-32s= %s", "E" $2, $3);
102   }
103
104 $1 == "#define" && $2 == "_MACH_MIG_ERRORS_H_" \
105   {
106     in_mig_errors = 1;
107     lines[lno++] = "\n\t/* Errors from <mach/mig_errors.h>.  */";
108     next;
109   }
110 in_mig_errors && $1 == "#endif" && $3 == "_MACH_MIG_ERRORS_H_" \
111   {
112     in_mig_errors = 0;
113   }
114
115 (in_mig_errors && $1 == "#define" && $3 <= -300) || \
116 (in_device_errors && $1 == "#define") \
117   {
118     comment = "";
119     for (i = 4; i <= NF; ++i)
120       comment = comment " " $i;
121     comma[lno] = 1;
122     lines[lno++] = sprintf("%-32s", sprintf ("\t%-24s= %s", "E" $2, $3)) comment;
123   }
124
125 $1 == "#define" && $2 == "D_SUCCESS" \
126   {
127     in_device_errors = 1;
128     lines[lno++] = "\n\t/* Errors from <device/device_types.h>.  */";
129     next;
130   }
131 in_device_errors && $1 == "#endif" \
132   {
133     in_device_errors = 0;
134   }
135
136
137 END \
138   {
139     for (i = 0; i < lno - 1; ++i)
140       printf "%s%s\n", lines[i], (comma[i] ? "," : "");
141     print lines[i];
142     print "";
143     print "};";
144     print "";
145     printf "#define\t_HURD_ERRNOS\t%d\n", maxerrno+1;
146     print "";
147     print "\
148 /* User-visible type of error codes.  It is ok to use `int' or\n\
149    `kern_return_t' for these, but with `error_t' the debugger prints\n\
150    symbolic values.  */";
151     print "#ifdef __USE_GNU";
152     print "typedef enum __error_t_codes error_t;"
153     print "#define __error_t_defined\t1"
154     print "#endif";
155     print "";
156     print "/* errno is a per-thread variable.  */";
157     print "#include <hurd/threadvar.h>";
158     print "#define errno        (*__hurd_errno_location ())";
159     print "#define __set_errno(val) errno = (val)";
160     print "";
161     print "#endif /* <errno.h> included.  */";
162     print "";
163     print "#if !defined (_ERRNO_H) && defined (__need_Emath)";
164     print edom; print erange;
165     print "#endif /* <errno.h> not included and need math error codes.  */";
166   }