2003-03-13 Alexandre Oliva <aoliva@redhat.com>
[kopensolaris-gnu/glibc.git] / sysdeps / mips / memcpy.S
1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Hartvig Ekner <hartvige@mips.com>, 2002.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21 #include <endian.h>
22
23
24 /* void *memcpy(void *s1, const void *s2, size_t n);
25
26    This routine could be optimized further for MIPS64, but this is left
27    as an exercise for the future. When it is done, the file should be kept
28    as a sisterfile to this one, and placed in the sysdeps/mips/mips64 
29    directory.  */
30
31 #if __BYTE_ORDER == __BIG_ENDIAN
32 #  define LWHI  lwl             /* high part is left in big-endian      */
33 #  define SWHI  swl             /* high part is left in big-endian      */
34 #  define LWLO  lwr             /* low part is right in big-endian      */
35 #  define SWLO  swr             /* low part is right in big-endian      */
36 #else
37 #  define LWHI  lwr             /* high part is right in little-endian  */
38 #  define SWHI  swr             /* high part is right in little-endian  */
39 #  define LWLO  lwl             /* low part is left in little-endian    */
40 #  define SWLO  swl             /* low part is left in little-endian    */
41 #endif
42
43 ENTRY (memcpy)
44         .set    noreorder
45
46         slti    t0, a2, 8               # Less than 8?
47         bne     t0, zero, L(last8)
48         move    v0, a0                  # Setup exit value before too late
49
50         xor     t0, a1, a0              # Find a0/a1 displacement
51         andi    t0, 0x3
52         bne     t0, zero, L(shift)      # Go handle the unaligned case
53         subu    t1, zero, a1
54         andi    t1, 0x3                 # a0/a1 are aligned, but are we
55         beq     t1, zero, L(chk8w)      #  starting in the middle of a word?
56         subu    a2, t1
57         LWHI    t0, 0(a1)               # Yes we are... take care of that
58         addu    a1, t1
59         SWHI    t0, 0(a0)
60         addu    a0, t1
61
62 L(chk8w):       andi    t0, a2, 0x1f            # 32 or more bytes left?
63         beq     t0, a2, L(chk1w)
64         subu    a3, a2, t0              # Yes
65         addu    a3, a1                  # a3 = end address of loop
66         move    a2, t0                  # a2 = what will be left after loop
67 L(lop8w):       lw      t0,  0(a1)              # Loop taking 8 words at a time
68         lw      t1,  4(a1)
69         lw      t2,  8(a1)
70         lw      t3, 12(a1)
71         lw      t4, 16(a1)
72         lw      t5, 20(a1)
73         lw      t6, 24(a1)
74         lw      t7, 28(a1)
75         addiu   a0, 32
76         addiu   a1, 32
77         sw      t0, -32(a0)
78         sw      t1, -28(a0)
79         sw      t2, -24(a0)
80         sw      t3, -20(a0)
81         sw      t4, -16(a0)
82         sw      t5, -12(a0)
83         sw      t6,  -8(a0)
84         bne     a1, a3, L(lop8w)
85         sw      t7,  -4(a0)
86
87 L(chk1w):       andi    t0, a2, 0x3             # 4 or more bytes left?
88         beq     t0, a2, L(last8)
89         subu    a3, a2, t0              # Yes, handle them one word at a time
90         addu    a3, a1                  # a3 again end address
91         move    a2, t0
92 L(lop1w):       lw      t0, 0(a1)
93         addiu   a0, 4
94         addiu   a1, 4
95         bne     a1, a3, L(lop1w)
96         sw      t0, -4(a0)
97
98 L(last8):       blez    a2, L(lst8e)            # Handle last 8 bytes, one at a time
99         addu    a3, a2, a1
100 L(lst8l):       lb      t0, 0(a1)
101         addiu   a0, 1
102         addiu   a1, 1
103         bne     a1, a3, L(lst8l)
104         sb      t0, -1(a0)
105 L(lst8e):       jr      ra                      # Bye, bye
106         nop
107
108 L(shift):       subu    a3, zero, a0            # Src and Dest unaligned 
109         andi    a3, 0x3                 #  (unoptimized case...)
110         beq     a3, zero, L(shft1)
111         subu    a2, a3                  # a2 = bytes left
112         LWHI    t0, 0(a1)               # Take care of first odd part
113         LWLO    t0, 3(a1)
114         addu    a1, a3
115         SWHI    t0, 0(a0)
116         addu    a0, a3
117 L(shft1):       andi    t0, a2, 0x3
118         subu    a3, a2, t0
119         addu    a3, a1
120 L(shfth):       LWHI    t1, 0(a1)               # Limp through, word by word
121         LWLO    t1, 3(a1)
122         addiu   a0, 4
123         addiu   a1, 4
124         bne     a1, a3, L(shfth)
125         sw      t1, -4(a0)
126         b       L(last8)                        # Handle anything which may be left
127         move    a2, t0
128
129         .set    reorder
130 END (memcpy)