Updated from ../=mpn/gmp-1.906.7
[kopensolaris-gnu/glibc.git] / sysdeps / mips / mips3 / addmul_1.s
1  # MIPS3 __mpn_addmul_1 -- Multiply a limb vector with a single limb and
2  # add the product to a second limb vector.
3
4  # Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
5
6  # This file is part of the GNU MP Library.
7
8  # The GNU MP Library is free software; you can redistribute it and/or modify
9  # it under the terms of the GNU Library General Public License as published by
10  # the Free Software Foundation; either version 2 of the License, or (at your
11  # option) any later version.
12
13  # The GNU MP Library is distributed in the hope that it will be useful, but
14  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
16  # License for more details.
17
18  # You should have received a copy of the GNU Library General Public License
19  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20  # the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21
22
23  # INPUT PARAMETERS
24  # res_ptr      $4
25  # s1_ptr       $5
26  # size         $6
27  # s2_limb      $7
28
29         .text
30         .align  4
31         .globl  __mpn_addmul_1
32         .ent    __mpn_addmul_1
33 __mpn_addmul_1:
34         .set    noreorder
35         .set    nomacro
36
37  # warm up phase 0
38         ld      $8,0($5)
39
40  # warm up phase 1
41         daddiu  $5,$5,8
42         dmultu  $8,$7
43
44         daddiu  $6,$6,-1
45         beq     $6,$0,$LC0
46          move   $2,$0           # zero cy2
47
48         daddiu  $6,$6,-1
49         beq     $6,$0,$LC1
50         ld      $8,0($5)        # load new s1 limb as early as possible
51
52 Loop:   ld      $10,0($4)
53         mflo    $3
54         mfhi    $9
55         daddiu  $5,$5,8
56         daddu   $3,$3,$2        # add old carry limb to low product limb
57         dmultu  $8,$7
58         ld      $8,0($5)        # load new s1 limb as early as possible
59         daddiu  $6,$6,-1        # decrement loop counter
60         sltu    $2,$3,$2        # carry from previous addition -> $2
61         daddu   $3,$10,$3
62         sltu    $10,$3,$10
63         daddu   $2,$2,$10
64         sd      $3,0($4)
65         daddiu  $4,$4,8
66         bne     $6,$0,Loop      # should be "bnel"
67          daddu  $2,$9,$2        # add high product limb and carry from addition
68
69  # cool down phase 1
70 $LC1:   ld      $10,0($4)
71         mflo    $3
72         mfhi    $9
73         daddu   $3,$3,$2
74         sltu    $2,$3,$2
75         dmultu  $8,$7
76         daddu   $3,$10,$3
77         sltu    $10,$3,$10
78         daddu   $2,$2,$10
79         sd      $3,0($4)
80         daddiu  $4,$4,8
81         daddu   $2,$9,$2        # add high product limb and carry from addition
82
83  # cool down phase 0
84 $LC0:   ld      $10,0($4)
85         mflo    $3
86         mfhi    $9
87         daddu   $3,$3,$2
88         sltu    $2,$3,$2
89         daddu   $3,$10,$3
90         sltu    $10,$3,$10
91         daddu   $2,$2,$10
92         sd      $3,0($4)
93         j       $31
94         daddu   $2,$9,$2        # add high product limb and carry from addition
95
96         .end    __mpn_addmul_1