Updated from ../=mpn/gmp-1.906.7
[kopensolaris-gnu/glibc.git] / sysdeps / mips / mips3 / lshift.s
1  # MIPS3 __mpn_lshift --
2
3  # Copyright (C) 1995 Free Software Foundation, Inc.
4
5  # This file is part of the GNU MP Library.
6
7  # The GNU MP Library is free software; you can redistribute it and/or modify
8  # it under the terms of the GNU Library General Public License as published by
9  # the Free Software Foundation; either version 2 of the License, or (at your
10  # option) any later version.
11
12  # The GNU MP Library is distributed in the hope that it will be useful, but
13  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
15  # License for more details.
16
17  # You should have received a copy of the GNU Library General Public License
18  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
19  # the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20
21
22  # INPUT PARAMETERS
23  # res_ptr      $4
24  # src_ptr      $5
25  # size         $6
26  # cnt          $7
27
28         .text
29         .align  2
30         .globl  __mpn_lshift
31         .ent    __mpn_lshift
32 __mpn_lshift:
33         .set    noreorder
34         .set    nomacro
35
36         dsll    $2,$6,3
37         daddu   $5,$5,$2        # make r5 point at end of src
38         ld      $10,-8($5)      # load first limb
39         dsubu   $13,$0,$7
40         daddu   $4,$4,$2        # make r4 point at end of res
41         daddiu  $6,$6,-1
42         and     $9,$6,4-1       # number of limbs in first loop
43         beq     $9,$0,.L0       # if multiple of 4 limbs, skip first loop
44          dsrl   $2,$10,$13      # compute function result
45
46         dsubu   $6,$6,$9
47
48 .Loop0: ld      $3,-16($5)
49         daddiu  $4,$4,-8
50         daddiu  $5,$5,-8
51         daddiu  $9,$9,-1
52         dsll    $11,$10,$7
53         dsrl    $12,$3,$13
54         move    $10,$3
55         or      $8,$11,$12
56         bne     $9,$0,.Loop0
57          sd     $8,0($4)
58
59 .L0:    beq     $6,$0,.Lend
60          nop
61
62 .Loop:  ld      $3,-16($5)
63         daddiu  $4,$4,-32
64         daddiu  $6,$6,-4
65         dsll    $11,$10,$7
66         dsrl    $12,$3,$13
67
68         ld      $10,-24($5)
69         dsll    $14,$3,$7
70         or      $8,$11,$12
71         sd      $8,24($4)
72         dsrl    $9,$10,$13
73
74         ld      $3,-32($5)
75         dsll    $11,$10,$7
76         or      $8,$14,$9
77         sd      $8,16($4)
78         dsrl    $12,$3,$13
79
80         ld      $10,-40($5)
81         dsll    $14,$3,$7
82         or      $8,$11,$12
83         sd      $8,8($4)
84         dsrl    $9,$10,$13
85
86         daddiu  $5,$5,-32
87         or      $8,$14,$9
88         bgtz    $6,.Loop
89          sd     $8,0($4)
90
91 .Lend:  dsll    $8,$10,$7
92         j       $31
93         sd      $8,-8($4)
94         .end    __mpn_lshift