* sysdeps/mips/mips64/memcpy.S, sysdeps/mips/mips64/memset.S: New.
[kopensolaris-gnu/glibc.git] / sysdeps / mips / mips64 / memset.S
1 /* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Hartvig Ekner <hartvige@mips.com>, 2002.
4    Ported to mips3 n32/n64 by Alexandre Oliva <aoliva@redhat.com>
5
6    The GNU C Library is free software; you can redistribute it and/or
7    modify it under the terms of the GNU Lesser General Public
8    License as published by the Free Software Foundation; either
9    version 2.1 of the License, or (at your option) any later version.
10
11    The GNU C Library is distributed in the hope that it will be useful,
12    but WITHOUT ANY WARRANTY; without even the implied warranty of
13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14    Lesser General Public License for more details.
15
16    You should have received a copy of the GNU Lesser General Public
17    License along with the GNU C Library; if not, write to the Free
18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
19    02111-1307 USA.  */
20
21 #include <sysdep.h>
22 #include <endian.h>
23 #include <sys/asm.h>
24
25
26 /* void *memset(void *s, int c, size_t n);
27         
28    This could probably be optimized further.  */
29
30 #if __BYTE_ORDER == __BIG_ENDIAN
31 # define SDHI   sdl             /* high part is left in big-endian      */
32 #else
33 # define SDHI   sdr             /* high part is right in little-endian  */
34 #endif
35
36 ENTRY (memset)
37         .set    noreorder
38
39         slti    t5, a2, 8               # Less than 8?
40         bne     t5, zero, L(last8)
41         move    v0, a0                  # Setup exit value before too late
42
43         beq     a1, zero, L(ueven)      # If zero pattern, no need to extend
44         andi    a1, 0xff                # Avoid problems with bogus arguments
45         dsll    t4, a1, 8
46         or      a1, t4
47         dsll    t4, a1, 16
48         or      a1, t4                  # a1 is now pattern in full word
49         dsll    t4, a1, 32
50         or      a1, t4                  # a1 is now pattern in double word
51
52 L(ueven):
53         PTR_SUBU t4, zero, a0           # Unaligned address?
54         andi    t4, 0x7
55         beq     t4, zero, L(chkw)
56         PTR_SUBU a2, t4
57         SDHI    a1, 0(a0)               # Yes, handle first unaligned part
58         PTR_ADDU a0, t4                 # Now both a0 and a2 are updated
59
60 L(chkw):
61         andi    t4, a2, 0xf             # Enough left for one loop iteration?
62         beq     t4, a2, L(chkl)
63         PTR_SUBU a3, a2, t4
64         PTR_ADDU a3, a0                 # a3 is last loop address +1
65         move    a2, t4                  # a2 is now # of bytes left after loop
66 L(loopw):
67         PTR_ADDIU a0, 16                # Handle 2 words pr. iteration
68         sd      a1, -16(a0)
69         bne     a0, a3, L(loopw)
70         sd      a1,  -8(a0)
71
72 L(chkl):
73         andi    t4, a2, 0x8             # Check if there is at least a double
74         beq     t4, zero, L(last8)      #  word remaining after the loop
75         PTR_SUBU a2, t4
76         sd      a1, 0(a0)               # Yes...
77         PTR_ADDIU a0, 8
78
79 L(last8):
80         blez    a2, L(exit)             # Handle last 8 bytes (if cnt>0)
81         PTR_ADDU a3, a2, a0             # a3 is last address +1
82 L(lst8l):
83         PTR_ADDIU a0, 1
84         bne     a0, a3, L(lst8l)
85         sb      a1, -1(a0)
86 L(exit):
87         j       ra                      # Bye, bye
88         nop
89
90         .set    reorder
91 END (memset)