Updated from ../=mpn/gmp-1.906.7
[kopensolaris-gnu/glibc.git] / sysdeps / mips / rshift.s
1  # MIPS2 __mpn_rshift --
2
3  # Copyright (C) 1995 Free Software Foundation, Inc.
4
5  # This file is part of the GNU MP Library.
6
7  # The GNU MP Library is free software; you can redistribute it and/or modify
8  # it under the terms of the GNU Library General Public License as published by
9  # the Free Software Foundation; either version 2 of the License, or (at your
10  # option) any later version.
11
12  # The GNU MP Library is distributed in the hope that it will be useful, but
13  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
15  # License for more details.
16
17  # You should have received a copy of the GNU Library General Public License
18  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
19  # the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
20
21
22  # INPUT PARAMETERS
23  # res_ptr      $4
24  # src_ptr      $5
25  # size         $6
26  # cnt          $7
27
28         .text
29         .align  2
30         .globl  __mpn_rshift
31         .ent    __mpn_rshift
32 __mpn_rshift:
33         .set    noreorder
34         .set    nomacro
35
36         lw      $10,0($5)       # load first limb
37         subu    $13,$0,$7
38         addiu   $6,$6,-1
39         and     $9,$6,4-1       # number of limbs in first loop
40         beq     $9,$0,.L0       # if multiple of 4 limbs, skip first loop
41          sll    $2,$10,$13      # compute function result
42
43         subu    $6,$6,$9
44
45 .Loop0: lw      $3,4($5)
46         addiu   $4,$4,4
47         addiu   $5,$5,4
48         addiu   $9,$9,-1
49         srl     $11,$10,$7
50         sll     $12,$3,$13
51         move    $10,$3
52         or      $8,$11,$12
53         bne     $9,$0,.Loop0
54          sw     $8,-4($4)
55
56 .L0:    beq     $6,$0,.Lend
57          nop
58
59 .Loop:  lw      $3,4($5)
60         addiu   $4,$4,16
61         addiu   $6,$6,-4
62         srl     $11,$10,$7
63         sll     $12,$3,$13
64
65         lw      $10,8($5)
66         srl     $14,$3,$7
67         or      $8,$11,$12
68         sw      $8,-16($4)
69         sll     $9,$10,$13
70
71         lw      $3,12($5)
72         srl     $11,$10,$7
73         or      $8,$14,$9
74         sw      $8,-12($4)
75         sll     $12,$3,$13
76
77         lw      $10,16($5)
78         srl     $14,$3,$7
79         or      $8,$11,$12
80         sw      $8,-8($4)
81         sll     $9,$10,$13
82
83         addiu   $5,$5,16
84         or      $8,$14,$9
85         bgtz    $6,.Loop
86          sw     $8,-4($4)
87
88 .Lend:  srl     $8,$10,$7
89         j       $31
90         sw      $8,0($4)
91         .end    __mpn_rshift