Update.
[kopensolaris-gnu/glibc.git] / sysdeps / mips / rtld-ldscript.in
1 OUTPUT_FORMAT("@@rtld-oformat@@")
2 OUTPUT_ARCH(@@rtld-arch@@)
3 ENTRY(@@rtld-entry@@)
4 SECTIONS
5 {
6   /* Read-only sections, merged into text segment: */
7   . = @@rtld-base@@;
8   .reginfo       : { *(.reginfo) }
9   .dynamic       : { *(.dynamic) }
10   .dynstr        : { *(.dynstr)         }
11   .dynsym        : { *(.dynsym)         }
12   .hash          : { *(.hash)           }
13   .rel.text      : { *(.rel.text)               }
14   .rela.text     : { *(.rela.text)      }
15   .rel.data      : { *(.rel.data)               }
16   .rela.data     : { *(.rela.data)      }
17   .rel.rodata    : { *(.rel.rodata)     }
18   .rela.rodata   : { *(.rela.rodata)    }
19   .rel.got       : { *(.rel.got)                }
20   .rela.got      : { *(.rela.got)               }
21   .rel.ctors     : { *(.rel.ctors)      }
22   .rela.ctors    : { *(.rela.ctors)     }
23   .rel.dtors     : { *(.rel.dtors)      }
24   .rela.dtors    : { *(.rela.dtors)     }
25   .rel.init      : { *(.rel.init)       }
26   .rela.init     : { *(.rela.init)      }
27   .rel.fini      : { *(.rel.fini)       }
28   .rela.fini     : { *(.rela.fini)      }
29   .rel.bss       : { *(.rel.bss)                }
30   .rela.bss      : { *(.rela.bss)               }
31   .rel.plt       : { *(.rel.plt)                }
32   .rela.plt      : { *(.rela.plt)               }
33   .rodata    : { *(.rodata)  }
34   .rodata1   : { *(.rodata1) }
35   .init          : { *(.init)   } =0
36   .text      :
37   {
38     *(.text)
39     *(.stub)
40     /* .gnu.warning sections are handled specially by elf32.em.  */
41     *(.gnu.warning)
42   } =0
43   .fini      : { *(.fini)    } =0
44   /* Adjust the address for the data segment.  We want to adjust up to
45      the same address within the page on the next page up.  It would
46      be more correct to do this:
47        . = 0x10000000;
48      The current expression does not correctly handle the case of a
49      text segment ending precisely at the end of a page; it causes the
50      data segment to skip a page.  The above expression does not have
51      this problem, but it will currently (2/95) cause BFD to allocate
52      a single segment, combining both text and data, for this case.
53      This will prevent the text segment from being shared among
54      multiple executions of the program; I think that is more
55      important than losing a page of the virtual address space (note
56      that no actual memory is lost; the page which is skipped can not
57      be referenced).  */
58   . += 0x10000;
59   .data    :
60   {
61     *(.data)
62     CONSTRUCTORS
63   }
64   .data1   : { *(.data1) }
65   .ctors         : { *(.ctors)   }
66   .dtors         : { *(.dtors)   }
67   _gp = ALIGN(16) + 0x7ff0;
68   .got           :
69   {
70     *(.got.plt) *(.got)
71    }
72   /* We want the small data sections together, so single-instruction offsets
73      can access them all, and initialized data all before uninitialized, so
74      we can shorten the on-disk segment size.  */
75   .sdata     : { *(.sdata) }
76   .lit8 : { *(.lit8) }
77   .lit4 : { *(.lit4) }
78   .sbss      : { *(.sbss) *(.scommon) }
79   .bss       :
80   {
81    *(.dynbss)
82    *(.bss)
83    *(COMMON)
84   }
85   /* The normal linker scripts created by the binutils doesn't have the
86      symbols end and _end which breaks ld.so's dl-minimal.c.  */
87   _end = . ;
88   PROVIDE (end = .);
89   /* These are needed for ELF backends which have not yet been
90      converted to the new style linker.  */
91   .stab 0 : { *(.stab) }
92   .stabstr 0 : { *(.stabstr) }
93   /* DWARF debug sections.
94      Symbols in the .debug DWARF section are relative to the beginning of the
95      section so we begin .debug at 0.  It's not clear yet what needs to happen
96      for the others.   */
97   .debug          0 : { *(.debug) }
98   .debug_srcinfo  0 : { *(.debug_srcinfo) }
99   .debug_aranges  0 : { *(.debug_aranges) }
100   .debug_pubnames 0 : { *(.debug_pubnames) }
101   .debug_sfnames  0 : { *(.debug_sfnames) }
102   .line           0 : { *(.line) }
103   /* These must appear regardless of  .  */
104   .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
105   .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
106 }