Fixed incorrect use of mvcle introduced by 2001-07-12 change.
[kopensolaris-gnu/glibc.git] / sysdeps / powerpc / dl-start.S
1 /* Machine-dependent ELF startup code.  PowerPC version.
2    Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21
22 /* Initial entry point code for the dynamic linker.
23    The C function `_dl_start' is the real entry point;
24    its return value is the user program's entry point.  */
25 ENTRY(_start)
26 /* We start with the following on the stack, from top:
27    argc (4 bytes);
28    arguments for program (terminated by NULL);
29    environment variables (terminated by NULL);
30    arguments for the program loader. */
31
32 /* Call _dl_start with one parameter pointing at argc */
33         mr      r3,r1
34 /* (we have to frob the stack pointer a bit to allow room for
35    _dl_start to save the link register).  */
36         li      r4,0
37         addi    r1,r1,-16
38         stw     r4,0(r1)
39         bl      _dl_start@local
40
41         /* FALLTHRU */
42 ENTRY(_dl_start_user)
43 /* Now, we do our main work of calling initialisation procedures.
44    The ELF ABI doesn't say anything about parameters for these,
45    so we just pass argc, argv, and the environment.
46    Changing these is strongly discouraged (not least because argc is
47    passed by value!).  */
48
49 /*  Put our GOT pointer in r31, */
50         bl      _GLOBAL_OFFSET_TABLE_-4@local
51         mflr    r31
52 /*  the address of _start in r30, */
53         mr      r30,r3
54 /*  &_dl_argc in 29, &_dl_argv in 27, and _dl_loaded in 28.  */
55         lwz     r28,_dl_loaded@got(r31)
56         lwz     r29,_dl_argc@got(r31)
57         lwz     r27,_dl_argv@got(r31)
58
59 /* Call _dl_init (_dl_loaded, _dl_argc, _dl_argv, _dl_argv+_dl_argc+1). */
60         lwz     r3,0(r28)
61         lwz     r4,0(r29)
62         lwz     r5,0(r27)
63         slwi    r6,r4,2
64         add     r6,r5,r6
65         addi    r6,r6,4
66         bl      _dl_init@local
67
68 /* Now, to conform to the ELF ABI, we have to: */
69 /* Pass argc (actually _dl_argc) in r3; */
70         lwz     r3,0(r29)
71 /* pass argv (actually _dl_argv) in r4; */
72         lwz     r4,0(r27)
73 /* pass envp (actually _dl_argv+_dl_argc+1) in r5; */
74         slwi    r5,r3,2
75         add     r6,r4,r5
76         addi    r5,r6,4
77 /* pass the auxilary vector in r6. This is passed to us just after _envp.  */
78 2:      lwzu    r0,4(r6)
79         cmpwi   r0,0
80         bne     2b
81         addi    r6,r6,4
82 /* Pass a termination function pointer (in this case _dl_fini) in r7.  */
83         lwz     r7,_dl_fini@got(r31)
84 /* Now, call the start function in r30... */
85         mtctr   r30
86         lwz     r26,_dl_starting_up@got(r31)
87 /* Pass the stack pointer in r1 (so far so good), pointing to a NULL value.
88    (This lets our startup code distinguish between a program linked statically,
89    which linux will call with argc on top of the stack which will hopefully
90    never be zero, and a dynamically linked program which will always have
91    a NULL on the top of the stack).
92    Take the opportunity to clear LR, so anyone who accidentally returns
93    from _start gets SEGV.  Also clear the next few words of the stack.  */
94
95         li      r31,0
96         stw     r31,0(r1)
97         mtlr    r31
98         stw     r31,4(r1)
99         stw     r31,8(r1)
100         stw     r31,12(r1)
101 /* Clear _dl_starting_up.  */
102         stw     r31,0(r26)
103 /* Go do it!  */
104         bctr
105 END(_start)