rint implementation for ppc64.
[kopensolaris-gnu/glibc.git] / sysdeps / powerpc / powerpc64 / fpu / s_rint.S
1 /* Round to int floating-point values.  PowerPC64 version.
2    Copyright (C) 2004 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 /* This has been coded in assembler because GCC makes such a mess of it
21    when it's coded in C.  */
22
23 #include <sysdep.h>
24
25         .section        ".toc","aw"
26 .LC0:   /* 2**52 */
27         .tc FD_43300000_0[TC],0x4330000000000000
28         .section        ".text"
29
30 ENTRY (__rint)
31         lfd     fp13,.LC0@toc(2)
32         fabs    fp0,fp1
33         fsub    fp12,fp13,fp13  /* generate 0.0  */
34         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
35         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
36         bnllr-  cr7
37         bng-    cr6,.L4
38         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
39         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
40         blr
41 .L4:
42         bnllr-  cr6             /* if (x < 0.0)  */
43         fsub    fp1,fp13,fp1    /* x = TWO52 - x;  */
44         fsub    fp0,fp1,fp13    /* x = - (x - TWO52);  */
45         fneg    fp1,fp0
46         blr
47         END (__rint)
48
49 weak_alias (__rint, rint)
50
51 #ifdef NO_LONG_DOUBLE
52 weak_alias (__rint, rintl)
53 strong_alias (__rint, __rintl)
54 #endif