PPC optimized string functions.
[kopensolaris-gnu/glibc.git] / sysdeps / powerpc / stpcpy.S
1 /* Optimized stpcpy implementation for PowerPC.
2    Copyright (C) 1997 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21
22 /* See strlen.s for comments on how the end-of-string testing works.  */
23
24 EALIGN(__stpcpy,4,0)
25 /* char * [r3] stpcpy (char *dest [r3], const char *src [r4])  */
26
27 /* General register assignments:
28    r0:  temporary
29    r3:  pointer to previous word in dest
30    r4:  pointer to previous word in src
31    r6:  current word from src
32    r7:  0xfefefeff
33    r8:  0x7f7f7f7f
34    r9:  ~(word in src | 0x7f7f7f7f)
35    r10: alternate word from src.  */
36
37         or    %r0,%r4,%r3
38         clrlwi. %r0,%r0,30
39         addi  %r3,%r3,-4
40         bne   L(unaligned)
41
42         lis   %r7,0xfeff
43         lis   %r8,0x7f7f
44         lwz   %r6,0(%r4)
45         addi  %r7,%r7,-0x101
46         addi  %r8,%r8,0x7f7f
47         b     2f
48
49 0:      lwzu  %r10,4(%r4)
50         stwu  %r6,4(%r3)
51         add   %r0,%r7,%r10
52         nor   %r9,%r8,%r10
53         and.  %r0,%r0,%r9
54         bne-  1f
55         lwzu  %r6,4(%r4)
56         stwu  %r10,4(%r3)
57 2:      add   %r0,%r7,%r6
58         nor   %r9,%r8,%r6
59         and.  %r0,%r0,%r9
60         beq+  0b
61
62         mr    %r10,%r6
63 /* We've hit the end of the string.  Do the rest byte-by-byte.  */
64 1:      rlwinm. %r0,%r10,8,24,31
65         stbu  %r0,4(%r3)
66         beqlr-
67         rlwinm. %r0,%r10,16,24,31
68         stbu  %r0,1(%r3)
69         beqlr-
70         rlwinm. %r0,%r10,24,24,31
71         stbu  %r0,1(%r3)
72         beqlr-
73         stbu  %r10,1(%r3)
74         blr
75
76 /* Oh well.  In this case, we just do a byte-by-byte copy.  */
77         .align 4
78         nop
79 L(unaligned):
80         lbz   %r6,0(%r4)
81         addi  %r3,%r3,3
82         cmpwi %r6,0
83         beq-  2f
84
85 0:      lbzu  %r10,1(%r4)
86         stbu  %r6,1(%r3)
87         cmpwi %r10,0
88         beq-  1f
89         nop             /* Let 601 load start of loop.  */
90         lbzu  %r6,1(%r4)
91         stbu  %r10,1(%r3)
92         cmpwi %r6,0
93         bne+  0b
94 2:      stbu  %r6,1(%r3)
95         blr
96 1:      stbu  %r10,1(%r3)
97         blr
98 END(__stpcpy)
99
100 weak_alias (__stpcpy, stpcpy)