* sysdeps/powerpc/stpcpy.S: Define & use symbolic register names.
[kopensolaris-gnu/glibc.git] / sysdeps / powerpc / stpcpy.S
1 /* Optimized stpcpy implementation for PowerPC.
2    Copyright (C) 1997, 1999, 2000 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21
22 /* See strlen.s for comments on how the end-of-string testing works.  */
23
24 /* char * [r3] stpcpy (char *dest [r3], const char *src [r4])  */
25
26 EALIGN (__stpcpy, 4, 0)
27
28 #define rTMP    r0
29 #define rDEST   r3              /* pointer to previous word in dest */
30 #define rSRC    r4              /* pointer to previous word in src */
31 #define rWORD   r6              /* current word from src */
32 #define rFEFE   r7              /* 0xfefefeff */
33 #define r7F7F   r8              /* 0x7f7f7f7f */
34 #define rNEG    r9              /* ~(word in src | 0x7f7f7f7f) */
35 #define rALT    r10             /* alternate word from src */
36
37         or      rTMP, rSRC, rDEST
38         clrlwi. rTMP, rTMP, 30
39         addi    rDEST, rDEST, -4
40         bne     L(unaligned)
41
42         lis     rFEFE, -0x101
43         lis     r7F7F, 0x7f7f
44         lwz     rWORD, 0(rSRC)
45         addi    rFEFE, rFEFE, -0x101
46         addi    r7F7F, r7F7F, 0x7f7f
47         b       L(g2)
48
49 L(g0):  lwzu    rALT, 4(rSRC)
50         stwu    rWORD, 4(rDEST)
51         add     rTMP, rFEFE, rALT
52         nor     rNEG, r7F7F, rALT
53         and.    rTMP, rTMP, rNEG
54         bne-    L(g1)
55         lwzu    rWORD, 4(rSRC)
56         stwu    rALT, 4(rDEST)
57 L(g2):  add     rTMP, rFEFE, rWORD
58         nor     rNEG, r7F7F, rWORD
59         and.    rTMP, rTMP, rNEG
60         beq+    L(g0)
61
62         mr      rALT, rWORD
63 /* We've hit the end of the string.  Do the rest byte-by-byte.  */
64 L(g1):  rlwinm. rTMP, rALT, 8, 24, 31
65         stbu    rTMP, 4(rDEST)
66         beqlr-
67         rlwinm. rTMP, rALT, 16, 24, 31
68         stbu    rTMP, 1(rDEST)
69         beqlr-
70         rlwinm. rTMP, rALT, 24, 24, 31
71         stbu    rTMP, 1(rDEST)
72         beqlr-
73         stbu    rALT, 1(rDEST)
74         blr
75
76 /* Oh well.  In this case, we just do a byte-by-byte copy.  */
77         .align 4
78         nop
79 L(unaligned):
80         lbz     rWORD, 0(rSRC)
81         addi    rDEST, rDEST, 3
82         cmpwi   rWORD, 0
83         beq-    L(u2)
84
85 L(u0):  lbzu    rALT, 1(rSRC)
86         stbu    rWORD, 1(rDEST)
87         cmpwi   rALT, 0
88         beq-    L(u1)
89         nop             /* Let 601 load start of loop.  */
90         lbzu    rWORD, 1(rSRC)
91         stbu    rALT, 1(rDEST)
92         cmpwi   rWORD, 0
93         bne+    L(u0)
94 L(u2):  stbu    rWORD, 1(rDEST)
95         blr
96 L(u1):  stbu    rALT, 1(rDEST)
97         blr
98 END (__stpcpy)
99
100 weak_alias (__stpcpy, stpcpy)