2007-07-21 Samuel Thibault <samuel.thibault@ens-lyon.org>
[kopensolaris-gnu/glibc.git] / sysdeps / s390 / s390-32 / add_n.S
1 /* Add two limb vectors of the same length > 0 and store sum in a third
2    limb vector.
3    Copyright (C) 2000, 2001 Free Software Foundation, Inc.
4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
5    This file is part of the GNU MP Library.
6
7    The GNU MP Library is free software; you can redistribute it and/or modify
8    it under the terms of the GNU Lesser General Public License as published by
9    the Free Software Foundation; either version 2.1 of the License, or (at your
10    option) any later version.
11
12    The GNU MP Library is distributed in the hope that it will be useful, but
13    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
15    License for more details.
16
17    You should have received a copy of the GNU Lesser General Public License
18    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
19    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
20    MA 02111-1307, USA. */
21
22 /*
23   INPUT PARAMETERS
24   res_ptr       %r2
25   s1_ptr        %r3
26   s2_ptr        %r4
27   size          %r5
28 */
29
30 #include "sysdep.h"
31 #include "asm-syntax.h"
32
33         .text
34 ENTRY(__mpn_add_n)
35         st     %r6,24(%r15)   # save register 6
36         cfi_offset (%r6, -72)
37         sr     %r1,%r1
38         lhi    %r0,1          # cannot use ahi to add carry, use alr
39 .L0:    l      %r6,0(%r1,%r3) # .L0 -> no carry from last add
40         al     %r6,0(%r1,%r4)
41         st     %r6,0(%r1,%r2)
42         la     %r1,4(0,%r1)
43         brc    3,.L3
44 .L1:    brct   %r5,.L0
45         slr    %r2,%r2        # no last carry to return
46         j      .Lexit
47 .L2:    l      %r6,0(%r1,%r3) # .L2 -> carry from last add
48         al     %r6,0(%r1,%r4)
49         brc    3,.L4
50         alr    %r6,%r0        # no carry yet, add carry from last add
51         st     %r6,0(%r1,%r2)
52         la     %r1,4(0,%r1)
53         brc    12,.L1          # new carry ?
54 .L3:    brct   %r5,.L2
55         lr     %r2,%r0        # return last carry
56         j      .Lexit
57 .L4:    alr    %r6,%r0        # already a carry, add carry from last add
58         st     %r6,0(%r1,%r2)
59         la     %r1,4(0,%r1)
60         brct   %r5,.L2
61         lr     %r2,%r0        # return last carry
62 .Lexit: l      %r6,24(%r15)   # restore register 6
63         br     %r14
64 END(__mpn_add_n)