(elf_machine_rela): Don't define refsym if in dl-conflict.c.
[kopensolaris-gnu/glibc.git] / sysdeps / s390 / s390-32 / memcpy.S
1 /* memcpy - copy a block from source to destination.  S/390 version.
2    Copyright (C) 2000, 2001, 2003 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
5
6    The GNU C Library is free software; you can redistribute it and/or
7    modify it under the terms of the GNU Lesser General Public
8    License as published by the Free Software Foundation; either
9    version 2.1 of the License, or (at your option) any later version.
10
11    The GNU C Library is distributed in the hope that it will be useful,
12    but WITHOUT ANY WARRANTY; without even the implied warranty of
13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14    Lesser General Public License for more details.
15
16    You should have received a copy of the GNU Lesser General Public
17    License along with the GNU C Library; if not, write to the Free
18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
19    02111-1307 USA.  */
20
21 /* INPUT PARAMETERS
22      %r2 = address of destination memory area
23      %r3 = address of source memory area
24      %r4 = number of bytes to copy.  */
25
26 #include "sysdep.h"
27 #include "asm-syntax.h"
28
29         .text
30 ENTRY(memcpy)
31         ltr     %r4,%r4
32         jz      .L3
33         ahi     %r4,-1              # length - 1
34         lr      %r1,%r2             # copy destination address
35         lr      %r5,%r4
36         srl     %r5,8
37         ltr     %r5,%r5             # < 256 bytes to move ?
38         jz      .L1
39         chi     %r5,255             # > 1MB to move ?
40         jh      .L4
41 .L0:    mvc     0(256,%r1),0(%r3)   # move in 256 byte chunks
42         la      %r1,256(%r1)
43         la      %r3,256(%r3)
44         brct    %r5,.L0
45 .L1:    bras    %r5,.L2             # setup base pointer for execute
46         mvc     0(1,%r1),0(%r3)     # instruction for execute
47 .L2:    ex      %r4,0(%r5)          # execute mvc with length ((%r4)&255)+1
48 .L3:    br      %r14
49         # data copies > 1MB are faster with mvcle.
50 .L4:    ahi     %r4,1               # length + 1
51         lr      %r5,%r4             # source length
52         lr      %r4,%r3             # source address
53         lr      %r3,%r5             # destination length = source length
54 .L5:    mvcle   %r2,%r4,0           # thats it, MVCLE is your friend
55         jo      .L5
56         lr      %r2,%r1             # return destination address
57         br      %r14
58 END(memcpy)
59 libc_hidden_builtin_def (memcpy)