Optimize for speed.
[kopensolaris-gnu/glibc.git] / sysdeps / s390 / s390-32 / memcpy.S
1 /* memcpy - copy a block from source to destination.  S/390 version.
2    Copyright (C) 2000, 2001 Free Software Foundation, Inc.
3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 /* INPUT PARAMETERS
21      %r2 = address of destination memory area
22      %r3 = address of source memory area
23      %r4 = number of bytes to copy.  */
24
25 #include "sysdep.h"
26 #include "asm-syntax.h"
27
28         .text
29 ENTRY(memcpy)
30         ltr     %r4,%r4
31         jz      .L3
32         ahi     %r4,-1              # length - 1
33         lr      %r1,%r2             # copy destination address
34         lr      %r5,%r4
35         sra     %r5,8
36         jz      .L1
37 .L0:    mvc     0(256,%r1),0(%r3)   # move in 256 byte chunks
38         la      %r1,256(%r1)
39         la      %r3,256(%r3)
40         brct    %r5,.L0
41 .L1:    bras    %r5,.L2             # setup base pointer for execute
42         mvc     0(1,%r1),0(%r3)     # instruction for execute
43 .L2:    ex      %r4,0(%r5)          # execute mvc with length ((%r4)&255)+1
44 .L3:    br      %r14
45 END(memcpy)
46