fdwalk should return 0 on an empty directory
[kopensolaris-gnu/glibc.git] / sysdeps / s390 / s390-32 / setjmp.S
1 /*
2    Copyright (C) 2000, 2001, 2005 Free Software Foundation, Inc.
3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
4    This file is part of the GNU C Library.
5
6    The GNU C Library is free software; you can redistribute it and/or
7    modify it under the terms of the GNU Lesser General Public
8    License as published by the Free Software Foundation; either
9    version 2.1 of the License, or (at your option) any later version.
10
11    The GNU C Library is distributed in the hope that it will be useful,
12    but WITHOUT ANY WARRANTY; without even the implied warranty of
13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14    Lesser General Public License for more details.
15
16    You should have received a copy of the GNU Lesser General Public
17    License along with the GNU C Library; if not, write to the Free
18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
19    02111-1307 USA.  */
20
21 #ifndef _ASM
22 #define _ASM
23 #endif
24
25 #include <sysdep.h>
26 #include <bits/setjmp.h>
27
28 /* Save the current program position in ENV and return 0.  */
29 /* R2 = pointer to jmp_buf, R3 = savemask */
30
31 ENTRY(__sigsetjmp)
32 #ifdef PTR_MANGLE
33         stm    %r6,%r13,0(%r2)      /* store registers in jmp_buf */
34         lr     %r4,%r14
35         lr     %r5,%r15
36         PTR_MANGLE (%r4, %r1)
37         PTR_MANGLE2 (%r5, %r1)
38         stm    %r4,%r5,32(%r2)
39 #else
40         stm    %r6,%r15,0(%r2)      /* store registers in jmp_buf */
41 #endif
42         std    %f4,40(%r2)
43         std    %f6,48(%r2)
44 #if defined NOT_IN_libc && defined IS_IN_rtld
45         /* In ld.so we never save the signal mask.  */
46         lhi    %r2,0
47         br     %r14
48 #elif defined PIC
49         /* We cannot use the PLT, because it requires that %r12 be set, but
50            we can't save and restore our caller's value.  Instead, we do an
51            indirect jump through the GOT. */
52         basr   %r1,0
53 .L0:    al     %r1,.L1 - .L0(0,%r1) /* get address of global offset table */
54                                     /* get address of __sigjmp_save from got */
55         l      %r1,__sigjmp_save@GOT12(0,%r1)
56         br     %r1
57 .L1:    .long  _GLOBAL_OFFSET_TABLE_ - .L0
58 #else
59         basr   %r1,0
60 .L0:    l      %r1,.L1-.L0(0,%r1)   /* load address of __sigjmp_save */
61         br     %r1                  /* tail-call __sigjmp_save */
62 .L1:    .long  __sigjmp_save
63 #endif
64 END (__sigsetjmp)