(__sigsetjmp): Skip FPU fields.
[kopensolaris-gnu/glibc.git] / sysdeps / sh / sh3 / setjmp.S
1 /* setjmp for SH3.
2    Copyright (C) 1999, 2000 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21 #define _SETJMP_H
22 #define _ASM
23 #include <bits/setjmp.h>
24
25         /* Binary compatibility entry point.  */
26 ENTRY (__setjmp)
27         mov     #0, r5
28 ENTRY (__sigsetjmp)
29         /* Save registers */
30         add     #(JB_SIZE - 4 * 5), r4
31         stc.l   gbr, @-r4
32         sts.l   pr, @-r4
33         mov.l   r15, @-r4
34         mov.l   r14, @-r4
35         mov.l   r13, @-r4
36         mov.l   r12, @-r4
37         mov.l   r11, @-r4
38         mov.l   r10, @-r4
39         mov.l   r9, @-r4
40         mov.l   r8, @-r4
41
42         /* Make a tail call to __sigjmp_save; it takes the same args.  */
43 #ifdef SHARED
44         mov.l   1f, r1
45         mova    1f, r0
46         bra     2f
47          add    r1, r0
48         .align  2
49 1:
50         .long   _GLOBAL_OFFSET_TABLE_
51 2:
52         mov.l   .L1, r1
53         mov.l   @(r0,r1), r1
54         jmp     @r1
55          nop
56         .align  2
57 .L1:
58         .long   C_SYMBOL_NAME(__sigjmp_save@GOT)
59 #else
60         mov.l   .L1, r1
61         jmp     @r1
62          nop
63         .align  2
64 .L1:
65         .long   C_SYMBOL_NAME(__sigjmp_save)
66 #endif
67 END (__setjmp)