Mon Jun 24 19:57:01 1996 Roland McGrath <roland@delasyd.gnu.ai.mit.edu>
[kopensolaris-gnu/glibc.git] / sysdeps / sparc / addmul_1.S
1 ! SPARC __mpn_addmul_1 -- Multiply a limb vector with a limb and add
2 ! the result to a second limb vector.
3
4 ! Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
5
6 ! This file is part of the GNU MP Library.
7
8 ! The GNU MP Library is free software; you can redistribute it and/or modify
9 ! it under the terms of the GNU Library General Public License as published by
10 ! the Free Software Foundation; either version 2 of the License, or (at your
11 ! option) any later version.
12
13 ! The GNU MP Library is distributed in the hope that it will be useful, but
14 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
16 ! License for more details.
17
18 ! You should have received a copy of the GNU Library General Public License
19 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
21 ! MA 02111-1307, USA.
22
23
24 ! INPUT PARAMETERS
25 ! res_ptr       o0
26 ! s1_ptr        o1
27 ! size          o2
28 ! s2_limb       o3
29
30 #include "sysdep.h"
31
32 .text
33         .align 4
34         .global C_SYMBOL_NAME(__mpn_addmul_1)
35 C_SYMBOL_NAME(__mpn_addmul_1):
36         ! Make S1_PTR and RES_PTR point at the end of their blocks
37         ! and put (- 4 x SIZE) in index/loop counter.
38         sll     %o2,2,%o2
39         add     %o0,%o2,%o4     ! RES_PTR in o4 since o0 is retval
40         add     %o1,%o2,%o1
41         sub     %g0,%o2,%o2
42
43         cmp     %o3,0xfff
44         bgu     Large
45         nop
46
47         ld      [%o1+%o2],%o5
48         mov     0,%o0
49         b       L0
50          add    %o4,-4,%o4
51 Loop0:
52         addcc   %o5,%g1,%g1
53         ld      [%o1+%o2],%o5
54         addx    %o0,%g0,%o0
55         st      %g1,[%o4+%o2]
56 L0:     wr      %g0,%o3,%y
57         sra     %o5,31,%g2
58         and     %o3,%g2,%g2
59         andcc   %g1,0,%g1
60         mulscc  %g1,%o5,%g1
61         mulscc  %g1,%o5,%g1
62         mulscc  %g1,%o5,%g1
63         mulscc  %g1,%o5,%g1
64         mulscc  %g1,%o5,%g1
65         mulscc  %g1,%o5,%g1
66         mulscc  %g1,%o5,%g1
67         mulscc  %g1,%o5,%g1
68         mulscc  %g1,%o5,%g1
69         mulscc  %g1,%o5,%g1
70         mulscc  %g1,%o5,%g1
71         mulscc  %g1,%o5,%g1
72         mulscc  %g1,0,%g1
73         sra     %g1,20,%g4
74         sll     %g1,12,%g1
75         rd      %y,%g3
76         srl     %g3,20,%g3
77         or      %g1,%g3,%g1
78
79         addcc   %g1,%o0,%g1
80         addx    %g2,%g4,%o0     ! add sign-compensation and cy to hi limb
81         addcc   %o2,4,%o2       ! loop counter
82         bne     Loop0
83          ld     [%o4+%o2],%o5
84
85         addcc   %o5,%g1,%g1
86         addx    %o0,%g0,%o0
87         retl
88         st      %g1,[%o4+%o2]
89
90
91 Large:  ld      [%o1+%o2],%o5
92         mov     0,%o0
93         sra     %o3,31,%g4      ! g4 = mask of ones iff S2_LIMB < 0
94         b       L1
95          add    %o4,-4,%o4
96 Loop:
97         addcc   %o5,%g3,%g3
98         ld      [%o1+%o2],%o5
99         addx    %o0,%g0,%o0
100         st      %g3,[%o4+%o2]
101 L1:     wr      %g0,%o5,%y
102         and     %o5,%g4,%g2
103         andcc   %g0,%g0,%g1
104         mulscc  %g1,%o3,%g1
105         mulscc  %g1,%o3,%g1
106         mulscc  %g1,%o3,%g1
107         mulscc  %g1,%o3,%g1
108         mulscc  %g1,%o3,%g1
109         mulscc  %g1,%o3,%g1
110         mulscc  %g1,%o3,%g1
111         mulscc  %g1,%o3,%g1
112         mulscc  %g1,%o3,%g1
113         mulscc  %g1,%o3,%g1
114         mulscc  %g1,%o3,%g1
115         mulscc  %g1,%o3,%g1
116         mulscc  %g1,%o3,%g1
117         mulscc  %g1,%o3,%g1
118         mulscc  %g1,%o3,%g1
119         mulscc  %g1,%o3,%g1
120         mulscc  %g1,%o3,%g1
121         mulscc  %g1,%o3,%g1
122         mulscc  %g1,%o3,%g1
123         mulscc  %g1,%o3,%g1
124         mulscc  %g1,%o3,%g1
125         mulscc  %g1,%o3,%g1
126         mulscc  %g1,%o3,%g1
127         mulscc  %g1,%o3,%g1
128         mulscc  %g1,%o3,%g1
129         mulscc  %g1,%o3,%g1
130         mulscc  %g1,%o3,%g1
131         mulscc  %g1,%o3,%g1
132         mulscc  %g1,%o3,%g1
133         mulscc  %g1,%o3,%g1
134         mulscc  %g1,%o3,%g1
135         mulscc  %g1,%o3,%g1
136         mulscc  %g1,%g0,%g1
137         rd      %y,%g3
138         addcc   %g3,%o0,%g3
139         addx    %g2,%g1,%o0
140         addcc   %o2,4,%o2
141         bne     Loop
142          ld     [%o4+%o2],%o5
143
144         addcc   %o5,%g3,%g3
145         addx    %o0,%g0,%o0
146         retl
147         st      %g3,[%o4+%o2]