sysdeps/sparc/divrem.m4

   1 /*
   2  * Division and remainder, from Appendix E of the Sparc Version 8
   3  * Architecture Manual, with fixes from Gordon Irlam.
   4  */
   5
   6 /*
   7  * Input: dividend and divisor in %o0 and %o1 respectively.
   8  *
   9  * m4 parameters:
  10  *  NAME        name of function to generate
  11  *  OP          OP=div => %o0 / %o1; OP=rem => %o0 % %o1
  12  *  S           S=true => signed; S=false => unsigned
  13  *
  14  * Algorithm parameters:
  15  *  N           how many bits per iteration we try to get (4)
  16  *  WORDSIZE    total number of bits (32)
  17  *
  18  * Derived constants:
  19  *  TOPBITS     number of bits in the top `decade' of a number
  20  *
  21  * Important variables:
  22  *  Q           the partial quotient under development (initially 0)
  23  *  R           the remainder so far, initially the dividend
  24  *  ITER        number of main division loop iterations required;
  25  *              equal to ceil(log2(quotient) / N).  Note that this
  26  *              is the log base (2^N) of the quotient.
  27  *  V           the current comparand, initially divisor*2^(ITER*N-1)
  28  *
  29  * Cost:
  30  *  Current estimate for non-large dividend is
  31  *      ceil(log2(quotient) / N) * (10 + 7N/2) + C
  32  *  A large dividend is one greater than 2^(31-TOPBITS) and takes a
  33  *  different path, as the upper bits of the quotient must be developed
  34  *  one bit at a time.
  35  */
  36
  37 define(N, `4')
  38 define(WORDSIZE, `32')
  39 define(TOPBITS, eval(WORDSIZE - N*((WORDSIZE-1)/N)))
  40
  41 define(dividend, `%o0')
  42 define(divisor, `%o1')
  43 define(Q, `%o2')
  44 define(R, `%o3')
  45 define(ITER, `%o4')
  46 define(V, `%o5')
  47
  48 /* m4 reminder: ifelse(a,b,c,d) => if a is b, then c, else d */
  49 define(T, `%g1')
  50 define(SC, `%g7')
  51 ifelse(S, `true', `define(SIGN, `%g6')')
  52
  53 /*
  54  * This is the recursive definition for developing quotient digits.
  55  *
  56  * Parameters:
  57  *  $1  the current depth, 1 <= $1 <= N
  58  *  $2  the current accumulation of quotient bits
  59  *  N   max depth
  60  *
  61  * We add a new bit to $2 and either recurse or insert the bits in
  62  * the quotient.  R, Q, and V are inputs and outputs as defined above;
  63  * the condition codes are expected to reflect the input R, and are
  64  * modified to reflect the output R.
  65  */
  66 define(DEVELOP_QUOTIENT_BITS,
  67 `       ! depth $1, accumulated bits $2
  68         bl      L.$1.eval(2^N+$2)
  69         srl     V,1,V
  70         ! remainder is positive
  71         subcc   R,V,R
  72         ifelse($1, N,
  73         `       b       9f
  74                 add     Q, ($2*2+1), Q
  75         ', `    DEVELOP_QUOTIENT_BITS(incr($1), `eval(2*$2+1)')')
  76 L.$1.eval(2^N+$2):
  77         ! remainder is negative
  78         addcc   R,V,R
  79         ifelse($1, N,
  80         `       b       9f
  81                 add     Q, ($2*2-1), Q
  82         ', `    DEVELOP_QUOTIENT_BITS(incr($1), `eval(2*$2-1)')')
  83         ifelse($1, 1, `9:')')
  84
  85 #include "DEFS.h"
  86 #include <machine/trap.h>
  87
  88 FUNC(NAME)
  89 ifelse(S, `true',
  90 `       ! compute sign of result; if neither is negative, no problem
  91         orcc    divisor, dividend, %g0  ! either negative?
  92         bge     2f                      ! no, go do the divide
  93         xor     divisor, dividend, SIGN ! compute sign in any case
  94         tst     divisor
  95         bge     1f
  96         tst     dividend
  97         ! divisor is definitely negative; dividend might also be negative
  98         bge     2f                      ! if dividend not negative...
  99         sub     %g0, divisor, divisor   ! in any case, make divisor nonneg
 100 1:      ! dividend is negative, divisor is nonnegative
 101         sub     %g0, dividend, dividend ! make dividend nonnegative
 102 2:
 103 ')
 104         ! Ready to divide.  Compute size of quotient; scale comparand.
 105         orcc    divisor, %g0, V
 106         bne     1f
 107         mov     dividend, R
 108
 109                 ! Divide by zero trap.  If it returns, return 0 (about as
 110                 ! wrong as possible, but that is what SunOS does...).
 111                 ta      ST_DIV0
 112                 retl
 113                 clr     %o0
 114
 115 1:
 116         cmp     R, V                    ! if divisor exceeds dividend, done
 117         blu     Lgot_result             ! (and algorithm fails otherwise)
 118         clr     Q
 119         sethi   %hi(1 << (WORDSIZE - TOPBITS - 1)), T
 120         cmp     R, T
 121         blu     Lnot_really_big
 122         clr     ITER
 123
 124         ! `Here the dividend is >= 2^(31-N) or so.  We must be careful here,
 125         ! as our usual N-at-a-shot divide step will cause overflow and havoc.
 126         ! The number of bits in the result here is N*ITER+SC, where SC <= N.
 127         ! Compute ITER in an unorthodox manner: know we need to shift V into
 128         ! the top decade: so do not even bother to compare to R.'
 129         1:
 130                 cmp     V, T
 131                 bgeu    3f
 132                 mov     1, SC
 133                 sll     V, N, V
 134                 b       1b
 135                 add     ITER, 1, ITER
 136
 137         ! Now compute SC.
 138         2:      addcc   V, V, V
 139                 bcc     Lnot_too_big
 140                 add     SC, 1, SC
 141
 142                 ! We get here if the divisor overflowed while shifting.
 143                 ! This means that R has the high-order bit set.
 144                 ! Restore V and subtract from R.
 145                 sll     T, TOPBITS, T   ! high order bit
 146                 srl     V, 1, V         ! rest of V
 147                 add     V, T, V
 148                 b       Ldo_single_div
 149                 sub     SC, 1, SC
 150
 151         Lnot_too_big:
 152         3:      cmp     V, R
 153                 blu     2b
 154                 nop
 155                 be      Ldo_single_div
 156                 nop
 157         /* NB: these are commented out in the V8-Sparc manual as well */
 158         /* (I do not understand this) */
 159         ! V > R: went too far: back up 1 step
 160         !       srl     V, 1, V
 161         !       dec     SC
 162         ! do single-bit divide steps
 163         !
 164         ! We have to be careful here.  We know that R >= V, so we can do the
 165         ! first divide step without thinking.  BUT, the others are conditional,
 166         ! and are only done if R >= 0.  Because both R and V may have the high-
 167         ! order bit set in the first step, just falling into the regular
 168         ! division loop will mess up the first time around.
 169         ! So we unroll slightly...
 170         Ldo_single_div:
 171                 subcc   SC, 1, SC
 172                 bl      Lend_regular_divide
 173                 nop
 174                 sub     R, V, R
 175                 mov     1, Q
 176                 b       Lend_single_divloop
 177                 nop
 178         Lsingle_divloop:
 179                 sll     Q, 1, Q
 180                 bl      1f
 181                 srl     V, 1, V
 182                 ! R >= 0
 183                 sub     R, V, R
 184                 b       2f
 185                 add     Q, 1, Q
 186         1:      ! R < 0
 187                 add     R, V, R
 188                 sub     Q, 1, Q
 189         2:
 190         Lend_single_divloop:
 191                 subcc   SC, 1, SC
 192                 bge     Lsingle_divloop
 193                 tst     R
 194                 b,a     Lend_regular_divide
 195
 196 Lnot_really_big:
 197 1:
 198         sll     V, N, V
 199         cmp     V, R
 200         bleu    1b
 201         addcc   ITER, 1, ITER
 202         be      Lgot_result
 203         sub     ITER, 1, ITER
 204
 205         tst     R       ! set up for initial iteration
 206 Ldivloop:
 207         sll     Q, N, Q
 208         DEVELOP_QUOTIENT_BITS(1, 0)
 209 Lend_regular_divide:
 210         subcc   ITER, 1, ITER
 211         bge     Ldivloop
 212         tst     R
 213         bl,a    Lgot_result
 214         ! non-restoring fixup here (one instruction only!)
 215 ifelse(OP, `div',
 216 `       sub     Q, 1, Q
 217 ', `    add     R, divisor, R
 218 ')
 219
 220 Lgot_result:
 221 ifelse(S, `true',
 222 `       ! check to see if answer should be < 0
 223         tst     SIGN
 224         bl,a    1f
 225         ifelse(OP, `div', `sub %g0, Q, Q', `sub %g0, R, R')
 226 1:')
 227         retl
 228         ifelse(OP, `div', `mov Q, %o0', `mov R, %o0')