Mon Jun 24 19:57:01 1996 Roland McGrath <roland@delasyd.gnu.ai.mit.edu>
[kopensolaris-gnu/glibc.git] / sysdeps / sparc / lshift.S
1 ! sparc __mpn_lshift --
2
3 ! Copyright (C) 1995, 1996 Free Software Foundation, Inc.
4
5 ! This file is part of the GNU MP Library.
6
7 ! The GNU MP Library is free software; you can redistribute it and/or modify
8 ! it under the terms of the GNU Library General Public License as published by
9 ! the Free Software Foundation; either version 2 of the License, or (at your
10 ! option) any later version.
11
12 ! The GNU MP Library is distributed in the hope that it will be useful, but
13 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
15 ! License for more details.
16
17 ! You should have received a copy of the GNU Library General Public License
18 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
19 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
20 ! MA 02111-1307, USA.
21
22
23 ! INPUT PARAMETERS
24 ! res_ptr       %o0
25 ! src_ptr       %o1
26 ! size          %o2
27 ! cnt           %o3
28
29 #include "sysdep.h"
30
31         .text
32         .align  4
33         .global C_SYMBOL_NAME(__mpn_lshift)
34 C_SYMBOL_NAME(__mpn_lshift):
35         sll     %o2,2,%g1
36         add     %o1,%g1,%o1     ! make %o1 point at end of src
37         ld      [%o1-4],%g2     ! load first limb
38         sub     %g0,%o3,%o5     ! negate shift count
39         add     %o0,%g1,%o0     ! make %o0 point at end of res
40         add     %o2,-1,%o2
41         andcc   %o2,4-1,%g4     ! number of limbs in first loop
42         srl     %g2,%o5,%g1     ! compute function result
43         be      L0              ! if multiple of 4 limbs, skip first loop
44         st      %g1,[%sp+80]
45
46         sub     %o2,%g4,%o2     ! adjust count for main loop
47
48 Loop0:  ld      [%o1-8],%g3
49         add     %o0,-4,%o0
50         add     %o1,-4,%o1
51         addcc   %g4,-1,%g4
52         sll     %g2,%o3,%o4
53         srl     %g3,%o5,%g1
54         mov     %g3,%g2
55         or      %o4,%g1,%o4
56         bne     Loop0
57          st     %o4,[%o0+0]
58
59 L0:     tst     %o2
60         be      Lend
61          nop
62
63 Loop:   ld      [%o1-8],%g3
64         add     %o0,-16,%o0
65         addcc   %o2,-4,%o2
66         sll     %g2,%o3,%o4
67         srl     %g3,%o5,%g1
68
69         ld      [%o1-12],%g2
70         sll     %g3,%o3,%g4
71         or      %o4,%g1,%o4
72         st      %o4,[%o0+12]
73         srl     %g2,%o5,%g1
74
75         ld      [%o1-16],%g3
76         sll     %g2,%o3,%o4
77         or      %g4,%g1,%g4
78         st      %g4,[%o0+8]
79         srl     %g3,%o5,%g1
80
81         ld      [%o1-20],%g2
82         sll     %g3,%o3,%g4
83         or      %o4,%g1,%o4
84         st      %o4,[%o0+4]
85         srl     %g2,%o5,%g1
86
87         add     %o1,-16,%o1
88         or      %g4,%g1,%g4
89         bne     Loop
90          st     %g4,[%o0+0]
91
92 Lend:   sll     %g2,%o3,%g2
93         st      %g2,[%o0-4]
94         retl
95         ld      [%sp+80],%o0