(libc_cv_gcc_unwind_find_fde): Set for m68k, too.
[kopensolaris-gnu/glibc.git] / sysdeps / unix / sysv / linux / configure.in
1 sinclude(./aclocal.m4)dnl Autoconf lossage
2 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
3 # Local configure fragment for sysdeps/unix/sysv/linux.
4
5 # On Linux, the default is to use libio instead of stdio.
6 test $stdio = default && stdio=libio
7
8 # Don't bother trying to generate any glue code to be compatible with the
9 # existing system library, because we are the only system library.
10 inhibit_glue=yes
11
12 define([LIBC_LINUX_VERSION],[2.0.10])dnl
13 if test -n "$sysheaders"; then
14   OLD_CPPFLAGS=$CPPFLAGS
15   CPPFLAGS="$CPPFLAGS $SYSINCLUDES"
16 fi
17 define([libc_cv_linuxVER], [libc_cv_linux]patsubst(LIBC_LINUX_VERSION,[\.]))dnl
18 AC_CACHE_CHECK(installed Linux kernel header files, libc_cv_linuxVER, [dnl
19 AC_EGREP_CPP([eat flaming death], [#include <linux/version.h>
20 #if !defined LINUX_VERSION_CODE || LINUX_VERSION_CODE < ]dnl
21 patsubst(LIBC_LINUX_VERSION,[^\([^.]*\)\.\([^.]*\)\.\([^.]*\)$],dnl
22 [ (\1 *65536+ \2 *256+ \3) /* \1.\2.\3 */])[
23 eat flaming death
24 #endif],
25              libc_cv_linuxVER='TOO OLD!',
26              libc_cv_linuxVER='LIBC_LINUX_VERSION or later')])
27 if test "$libc_cv_linuxVER" != 'LIBC_LINUX_VERSION or later'; then
28   AC_MSG_ERROR([GNU libc requires kernel header files from
29 Linux LIBC_LINUX_VERSION or later to be installed before configuring.
30 The kernel header files are found usually in /usr/include/asm and
31 /usr/include/linux; make sure these directories use files from
32 Linux LIBC_LINUX_VERSION or later.  This check uses <linux/version.h>, so
33 make sure that file was built correctly when installing the kernel header
34 files.  To use kernel headers not from /usr/include/linux, use the
35 configure option --with-headers.])
36 fi
37
38 # If the user gave a minimal version number test whether the available
39 # kernel headers are young enough.  Additionally we have minimal
40 # kernel versions for some architectures.
41 case "$machine" in
42   alpha*)
43     arch_minimum_kernel=2.1.100
44     libc_cv_gcc_unwind_find_fde=yes
45     ;;
46   i386*)
47     libc_cv_gcc_unwind_find_fde=yes
48     arch_minimum_kernel=2.0.10
49     ;;
50   ia64*)
51     arch_minimum_kernel=2.4.0
52     ;;
53   hppa*)
54     arch_minimum_kernel=2.3.99
55     ;;
56   m68k*)
57     arch_minimum_kernel=2.0.10
58     libc_cv_gcc_unwind_find_fde=yes
59     ;;
60   mips*)
61     arch_minimum_kernel=2.2.15
62     libc_cv_gcc_unwind_find_fde=yes
63     ;;
64   powerpc*)
65     libc_cv_gcc_unwind_find_fde=yes
66     arch_minimum_kernel=2.0.10
67     ;;
68   s390/s390-32)
69     libc_cv_gcc_unwind_find_fde=yes
70     arch_minimum_kernel=2.2.10
71     ;;
72   s390/s390-64)
73     libc_cv_gcc_unwind_find_fde=yes
74     arch_minimum_kernel=2.4.0
75     ;;
76   sh*)
77     arch_minimum_kernel=2.3.99
78     libc_cv_gcc_unwind_find_fde=yes
79     ;;
80   sparc*)
81     libc_cv_gcc_unwind_find_fde=yes
82     arch_minimum_kernel=2.0.10
83     ;;
84   x86_64*)
85     arch_minimum_kernel=2.4.0
86     ;;
87   *)
88     arch_minimum_kernel=2.0.10
89     ;;
90 esac
91 if test -n "$minimum_kernel"; then
92   changequote(,)
93   user_version=$((`echo "$minimum_kernel.0.0.0" | sed 's/\([0-9]*\)\.\([0-9]*\)\.\([0-9]*\).*/\1 \* 65536 + \2 \* 256 + \3/'`))
94   arch_version=$((`echo "$arch_minimum_kernel.0.0.0" | sed 's/\([0-9]*\)\.\([0-9]*\)\.\([0-9]*\).*/\1 \* 65536 + \2 \* 256 + \3/'`))
95   changequote([,])
96   if test $user_version -lt $arch_version; then
97     AC_MSG_WARN([minimum kernel version reset to $arch_minimum_kernel])
98     minimum_kernel=$arch_minimum_kernel
99   fi
100 else
101   if test $arch_minimum_kernel != '2.0.10'; then
102     minimum_kernel=$arch_minimum_kernel
103   fi
104 fi
105
106 if test -n "$minimum_kernel"; then
107   AC_MSG_CHECKING(for kernel header at least $minimum_kernel)
108 changequote(,)dnl
109   decnum=`echo "$minimum_kernel.0.0.0" | sed 's/\([0-9]*\)\.\([0-9]*\)\.\([0-9]*\).*/(\1 * 65536 + \2 * 256 + \3)/'`;
110   abinum=`echo "$minimum_kernel.0.0.0" | sed 's/\([0-9]*\)\.\([0-9]*\)\.\([0-9]*\).*/\1,\2,\3/'`;
111 changequote([,])dnl
112   AC_EGREP_CPP([eat flaming death], [#include <linux/version.h>
113 #if LINUX_VERSION_CODE < $decnum
114 eat flaming death
115 #endif], libc_minimum_kernel='too old!', libc_minimum_kernel=ok)
116   AC_MSG_RESULT($libc_minimum_kernel)
117   if test "$libc_minimum_kernel" = ok; then
118     AC_DEFINE_UNQUOTED(__LINUX_KERNEL_VERSION, $decnum)
119     AC_DEFINE_UNQUOTED(__ABI_TAG_VERSION, $abinum)
120   else
121     AC_MSG_ERROR([*** The available kernel headers are older than the requested
122 *** compatible kernel version])
123   fi
124 fi
125
126 # The result of the above test for the use of the FDE code is invalid if
127 # the user overrides the decision about the minimum ABI.
128 if test "$oldest_abi" != default && test "2.2.4" \< "$oldest_abi"; then
129   libc_cv_gcc_unwind_find_fde=no
130 fi
131
132 if test -n "$sysheaders"; then
133   CPPFLAGS=$OLD_CPPFLAGS
134 fi
135 # The Linux filesystem standard prescribes where to place "essential"
136 # files.  I.e., when the installation prefix is "/usr" we have to place
137 # shared library objects and the configuration files on the root partition
138 # in /lib and /etc.
139 if test "$prefix" = "/usr" -o "$prefix" = "/usr/"; then
140   # 64bit libraries on sparc go to /lib64 and not /lib
141   if test "$machine" = "sparc/sparc64" -o "$machine" = "x86_64"; then
142     libc_cv_slibdir="/lib64"
143     if test "$libdir" = '${exec_prefix}/lib'; then
144       libdir='${exec_prefix}/lib64';
145       # Locale data can be shared between 32bit and 64bit libraries
146       libc_cv_localedir='${exec_prefix}/lib/locale'
147     fi
148   else
149     libc_cv_slibdir="/lib"
150   fi
151   # Allow the user to override the path with --sysconfdir
152   if test $sysconfdir = '${prefix}/etc'; then
153     libc_cv_sysconfdir=/etc
154   else
155     libc_cv_sysconfdir=$sysconfdir
156    fi
157   libc_cv_rootsbindir="/sbin"
158 fi
159
160 # Under Linux the LinuxThreads add-on should be available.
161 case $add_ons in
162   # It is available.  Good.
163   *linuxthreads*)
164     linuxthreads_missing=
165     ;;
166   *)
167     linuxthreads_missing=yes
168     ;;
169 esac
170
171 if test "$linuxthreads_missing"; then
172   if test $enable_sanity = yes; then
173     echo "\
174 *** On GNU/Linux systems it is normal to compile GNU libc with the
175 *** \`linuxthreads' add-on.  Without that, the library will be
176 *** incompatible with normal GNU/Linux systems.
177 *** If you really mean to not use this add-on, run configure again
178 *** using the extra parameter \`--disable-sanity-checks'."
179     exit 1
180   else
181     echo "\
182 *** WARNING: Are you sure you do not want to use the \`linuxthreads'
183 *** add-on?"
184   fi
185 fi
186
187 # One Linux we use ldconfig.
188 use_ldconfig=yes
189
190 # We need some extensions to the `ldd' script.
191 changequote(,)
192 case "$machine" in
193   i[3456]86* | m68*)
194     ldd_rewrite_script=../sysdeps/unix/sysv/linux/ldd-rewrite.sed
195     ;;
196   ia64*)
197     ldd_rewrite_script=../sysdeps/unix/sysv/linux/ia64/ldd-rewrite.sed
198     ;;
199   s390*)
200     ldd_rewrite_script=../sysdeps/unix/sysv/linux/s390/ldd-rewrite.sed
201     ;;
202   sparc*)
203     ldd_rewrite_script=../sysdeps/unix/sysv/linux/sparc/ldd-rewrite.sed
204     ;;
205   x86_64*)
206     ldd_rewrite_script=../sysdeps/unix/sysv/linux/x86_64/ldd-rewrite.sed
207     ;;
208   *)
209     ;;
210 esac
211 changequote([,])
212
213 if test $host = $build; then
214   # If $prefix/include/{net,scsi} are symlinks, make install will
215   # clobber what they're linked to (probably a kernel tree).
216   # test -L ought to work on all Linux boxes.
217   if test "x$prefix" != xNONE; then
218     ac_prefix=$prefix
219   else
220     ac_prefix=$ac_default_prefix
221   fi
222   AC_MSG_CHECKING([for symlinks in ${ac_prefix}/include])
223   ac_message=
224   if test -L ${ac_prefix}/include/net; then
225     ac_message="$ac_message
226    ${ac_prefix}/include/net is a symlink"
227   fi
228   if test -L ${ac_prefix}/include/scsi; then
229     ac_message="$ac_message
230    ${ac_prefix}/include/scsi is a symlink"
231   fi
232   if test -n "$ac_message"; then
233     AC_MSG_ERROR([$ac_message
234 \`make install' will destroy the target of the link(s).
235 Delete the links and re-run configure, or better still, move the entire
236 ${ac_prefix}/include directory out of the way.])
237   else
238     AC_MSG_RESULT(ok)
239   fi
240 fi