When not using PIC don't use jecxz since the label might be far away.
[kopensolaris-gnu/glibc.git] / sysdeps / unix / sysv / linux / i386 / clone.S
1 /* Copyright (C) 1996, 1997, 1998, 1999 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Richard Henderson (rth@tamu.edu)
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 /* clone() is even more special than fork() as it mucks with stacks
21    and invokes a function in the right context after its all over.  */
22
23 #include <sysdep.h>
24 #define _ERRNO_H        1
25 #include <bits/errno.h>
26 #include <asm-syntax.h>
27
28 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg); */
29
30         .text
31 ENTRY(__clone)
32         /* Sanity check arguments.  */
33         movl    $-EINVAL,%eax
34         movl    4(%esp),%ecx            /* no NULL function pointers */
35 #ifdef PIC
36         jecxz   SYSCALL_ERROR_LABEL
37 #else
38         testl   %ecx,%ecx
39         jz      SYSCALL_ERROR_LABEL
40 #endif
41         movl    8(%esp),%ecx            /* no NULL stack pointers */
42 #ifdef PIC
43         jecxz   SYSCALL_ERROR_LABEL
44 #else
45         testl   %ecx,%ecx
46         jz      SYSCALL_ERROR_LABEL
47 #endif
48
49         /* Insert the argument onto the new stack.  */
50         subl    $8,%ecx
51         movl    16(%esp),%eax           /* no negative argument counts */
52         movl    %eax,4(%ecx)
53
54         /* Save the function pointer as the zeroth argument.
55            It will be popped off in the child in the ebx frobbing below.  */
56         movl    4(%esp),%eax
57         movl    %eax,0(%ecx)
58
59         /* Do the system call */
60         pushl   %ebx
61         movl    16(%esp),%ebx
62         movl    $SYS_ify(clone),%eax
63         int     $0x80
64         popl    %ebx
65
66         test    %eax,%eax
67         jl      SYSCALL_ERROR_LABEL
68         jz      thread_start
69
70 L(pseudo_end):
71         ret
72
73 thread_start:
74         subl    %ebp,%ebp       /* terminate the stack frame */
75         call    *%ebx
76 #ifdef PIC
77         call    L(here)
78 L(here):
79         popl    %ebx
80         addl    $_GLOBAL_OFFSET_TABLE_+[.-L(here)], %ebx
81 #endif
82         pushl   %eax
83         call    JUMPTARGET (_exit)
84
85 PSEUDO_END (__clone)
86
87 weak_alias (__clone, clone)