68541d5d80c69713e577d16595c20844c3e5150e
[kopensolaris-gnu/glibc.git] / sysdeps / unix / sysv / linux / i386 / getcontext.S
1 /* Save current context.
2    Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4    Contributed by Ulrich Drepper <drepper@redhat.com>, 2001.
5
6    The GNU C Library is free software; you can redistribute it and/or
7    modify it under the terms of the GNU Lesser General Public
8    License as published by the Free Software Foundation; either
9    version 2.1 of the License, or (at your option) any later version.
10
11    The GNU C Library is distributed in the hope that it will be useful,
12    but WITHOUT ANY WARRANTY; without even the implied warranty of
13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14    Lesser General Public License for more details.
15
16    You should have received a copy of the GNU Lesser General Public
17    License along with the GNU C Library; if not, write to the Free
18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
19    02111-1307 USA.  */
20
21 #include <sysdep.h>
22
23 #include "ucontext_i.h"
24
25
26 ENTRY(__getcontext)
27         /* Load address of the context data structure.  */
28         movl    4(%esp), %eax
29
30         /* Return value of getcontext.  EAX is the only register whose
31            value is not preserved.  */
32         movl    $0, oEAX(%eax)
33
34         /* Save the 32-bit register values and the return address.  */
35         movl    %ecx, oECX(%eax)
36         movl    %edx, oEDX(%eax)
37         movl    %edi, oEDI(%eax)
38         movl    %esi, oESI(%eax)
39         movl    %ebp, oEBP(%eax)
40         movl    (%esp), %ecx
41         movl    %ecx, oEIP(%eax)
42         leal    4(%esp), %ecx           /* Exclude the return address.  */
43         movl    %ecx, oESP(%eax)
44         movl    %ebx, oEBX(%eax)
45
46         /* Save the FS segment register.  We don't touch the GS register
47            since it is used for threads.  */
48         xorl    %edx, %edx
49         movw    %fs, %dx
50         movl    %edx, oFS(%eax)
51
52         /* We have separate floating-point register content memory on the
53            stack.  We use the __fpregs_mem block in the context.  Set the
54            links up correctly.  */
55         leal    oFPREGSMEM(%eax), %ecx
56         movl    %ecx, oFPREGS(%eax)
57         /* Save the floating-point context.  */
58         fnstenv (%ecx)
59         /* And load it right back since the processor changes the mask.
60            Intel thought this opcode to be used in interrupt handlers which
61            would block all exceptions.  */
62         fldenv  (%ecx)
63
64         /* Save the current signal mask.  */
65         pushl   %ebx
66         leal    oSIGMASK(%eax), %edx
67         xorl    %ecx, %ecx
68         movl    $SIG_BLOCK, %ebx
69         movl    $__NR_sigprocmask, %eax
70         ENTER_KERNEL
71         popl    %ebx
72         cmpl    $-4095, %eax            /* Check %eax for error.  */
73         jae     SYSCALL_ERROR_LABEL     /* Jump to error handler if error.  */
74
75         /* All done, return 0 for success.  */
76         xorl    %eax, %eax
77 L(pseudo_end):
78         ret
79 PSEUDO_END(__getcontext)
80
81 weak_alias(__getcontext, getcontext)