(_dl_string_hwcap): Always inline.
[kopensolaris-gnu/glibc.git] / sysdeps / unix / sysv / linux / i386 / socket.S
1 /* Copyright (C) 1995, 1996, 1997, 1998, 2002 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3
4    The GNU C Library is free software; you can redistribute it and/or
5    modify it under the terms of the GNU Lesser General Public
6    License as published by the Free Software Foundation; either
7    version 2.1 of the License, or (at your option) any later version.
8
9    The GNU C Library is distributed in the hope that it will be useful,
10    but WITHOUT ANY WARRANTY; without even the implied warranty of
11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12    Lesser General Public License for more details.
13
14    You should have received a copy of the GNU Lesser General Public
15    License along with the GNU C Library; if not, write to the Free
16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
17    02111-1307 USA.  */
18
19 #include <sysdep-cancel.h>
20 #include <socketcall.h>
21 #include <tls.h>
22
23 #define P(a, b) P2(a, b)
24 #define P2(a, b) a##b
25
26         .text
27 /* The socket-oriented system calls are handled unusally in Linux.
28    They are all gated through the single `socketcall' system call number.
29    `socketcall' takes two arguments: the first is the subcode, specifying
30    which socket function is being called; and the second is a pointer to
31    the arguments to the specific function.
32
33    The .S files for the other calls just #define socket and #include this.  */
34
35 #ifndef __socket
36 # ifndef NO_WEAK_ALIAS
37 #  define __socket P(__,socket)
38 # else
39 #  define __socket socket
40 # endif
41 #endif
42
43 .globl __socket
44 ENTRY (__socket)
45 #if defined NEED_CANCELLATION && defined CENABLE
46         SINGLE_THREAD_P
47         jne 1f
48 #endif
49
50         /* Save registers.  */
51         movl %ebx, %edx
52
53         movl $SYS_ify(socketcall), %eax /* System call number in %eax.  */
54
55         /* Use ## so `socket' is a separate token that might be #define'd.  */
56         movl $P(SOCKOP_,socket), %ebx   /* Subcode is first arg to syscall.  */
57         lea 4(%esp), %ecx               /* Address of args is 2nd arg.  */
58
59         /* Do the system call trap.  */
60         ENTER_KERNEL
61
62         /* Restore registers.  */
63         movl %edx, %ebx
64
65         /* %eax is < 0 if there was an error.  */
66         cmpl $-125, %eax
67         jae SYSCALL_ERROR_LABEL
68
69         /* Successful; return the syscall's value.  */
70 L(pseudo_end):
71         ret
72
73
74 #if defined NEED_CANCELLATION && defined CENABLE
75         /* We need one more register.  */
76 1:      pushl %esi
77
78         /* Enable asynchronous cancellation.  */
79         CENABLE
80         movl %eax, %esi
81
82         /* Save registers.  */
83         movl %ebx, %edx
84
85         movl $SYS_ify(socketcall), %eax /* System call number in %eax.  */
86
87         /* Use ## so `socket' is a separate token that might be #define'd.  */
88         movl $P(SOCKOP_,socket), %ebx   /* Subcode is first arg to syscall.  */
89         lea 8(%esp), %ecx               /* Address of args is 2nd arg.  */
90
91         /* Do the system call trap.  */
92         ENTER_KERNEL
93
94         /* Restore registers.  */
95         movl %edx, %ebx
96
97         /* Restore the cancellation.  */
98         xchgl %esi, %eax
99         CDISABLE
100
101         /* Restore registers.  */
102         movl %esi, %eax
103         popl %esi
104
105         /* %eax is < 0 if there was an error.  */
106         cmpl $-125, %eax
107         jae SYSCALL_ERROR_LABEL
108
109         /* Successful; return the syscall's value.  */
110         ret
111 #endif
112 PSEUDO_END (__socket)
113
114 #ifndef NO_WEAK_ALIAS
115 weak_alias (__socket, socket)
116 #endif