makecontext implementation for Linux/PPC64.
[kopensolaris-gnu/glibc.git] / sysdeps / unix / sysv / linux / powerpc / powerpc64 / makecontext.S
1 /* Create new context.
2    Copyright (C) 2002 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21
22 #define __ASSEMBLY__
23 #include <asm/ptrace.h>
24 #include "ucontext_i.h"
25
26 ENTRY(__makecontext)
27   /* Save parameters into the parameter save area of callers frame.  */
28   std  r3,FRAME_PARM1_SAVE(r1) /* ucontext_t *ucp  */
29   std  r4,FRAME_PARM2_SAVE(r1) /* void (*func)(void)  */
30   std  r5,FRAME_PARM3_SAVE(r1) /* int argc  */
31   std  r6,FRAME_PARM4_SAVE(r1) /* ... */
32   std  r7,FRAME_PARM5_SAVE(r1)
33   std  r8,FRAME_PARM6_SAVE(r1)
34   std  r9,FRAME_PARM7_SAVE(r1)
35   std  r10,FRAME_PARM8_SAVE(r1)
36   mflr  r0
37   /* Get the address of the target functions first parameter.  */
38   addi  r6,r1,FRAME_PARM4_SAVE
39   std   r0,FRAME_LR_SAVE(r1)
40   stdu  r1,-128(r1)
41   
42   /* Get the ucontexts stack pointer and size.  Compute the top of stack
43      and round down to a quadword boundary.  Then stack a dummy frame 
44      with a null back chain.  We store the context pointer in the frames
45      "compiler double word" field so we can recover if is the function 
46      returns.  Finally save the callers link register and TOC pointer 
47      into this frame so the debugger can display a backtrace.
48   */
49   ld    r7,UCONTEXT_STACK_SP(r3)
50   ld    r0,UCONTEXT_STACK_SIZE(r3)
51   add   r7,r7,r0
52   clrrdi  r7,r7,4
53   li    r0,0
54   stdu  r0,-48(r7)
55   std   r3,24(r7)
56   mflr  r0
57   std   r2,FRAME_TOC_SAVE(r7)  /* Store the TOC pointer for later.  */
58   std   r0,FRAME_LR_SAVE(r7)
59   
60   /* Now we need to stack another frame to hold the parameter save area
61      for the function.  We need to allocate a frame with the minimum 48 
62      byte header and 8 parameter register.  However if there are more 
63      than 8 parameters addition space is need to hold all the parameters.
64      The total size it rounded up to a quadword multiple then a frame is 
65      stacked.  This address is stored in the ucontext as GPR 1.  */
66      
67   cmpdi cr1,r5,8  
68   sldi  r8,r5,3
69   bgt   cr1,L(gt8)
70   li    r8,64
71 L(gt8):
72   addi  r8,r8,FRAME_PARM_SAVE+8 /* Add header plus rounding factor.  */
73   clrrdi  r8,r8,4  /* Round down to quadword.  */
74   
75   subf  r8,r8,r7
76   std   r7,0(r8)   /* Stack the frame.  */
77   std   r8,(SIGCONTEXT_GP_REGS+(PT_R1*8))(r3)
78   
79   /* Now we need to copy the target functions parameters.  The functions 
80      parameters are saved in the parameter save area.  We skip over the
81      first three parameters and copy up to 8 double word into the 
82      SIGCONTEXT_GP_REGS starting with R3.  If there are more than 8 
83      parameters then doublewords 8-N are copied into the parameter
84      save area of the context frame.  */ 
85   cmpdi r5,0
86   beq   L(noparms)
87   mr    r0,r5
88   ble   cr1,L(le8)
89   li    r0,8
90 L(le8):    
91   mtctr r0
92   addi  r7,r6,-8
93   addi  r9,r3,(SIGCONTEXT_GP_REGS+(PT_R3*8)-8)
94 L(parmloop2):
95   ldu   r0,8(r7)
96   stdu  r0,8(r9)
97   bdnz  L(parmloop2)
98   
99   addi  r0,r5,-8 
100   ble   cr1,L(noparms) 
101   mtctr r0
102   addi  r9,r8,FRAME_PARM9_SAVE-8
103 L(parmloop):
104   ldu   r0,8(r7)
105   stdu  r0,8(r9)
106   bdnz  L(parmloop)
107   
108 L(noparms):
109   
110   /* Load the function address and TOC from the function descriptor
111      and store them in the ucontext as NIP and r2.  Store the 3rd 
112      field of the function descriptor into the ucontext as r11 in case
113      the calling language needs the "environment pointer".  */
114   ld    r0,0(r4)
115   ld    r10,8(r4);
116   ld    r9,16(r4); 
117   std   r0,(SIGCONTEXT_GP_REGS+(PT_NIP*8))(r3)  
118   std   r10,(SIGCONTEXT_GP_REGS+(PT_R2*8))(r3) 
119   std   r9,(SIGCONTEXT_GP_REGS+(PT_R11*8))(r3)
120   
121   /* If the target function returns we need to do some cleanup.  We use a
122      code trick to get the address of our cleanup function into the link
123      register.  Do not add any code between here and L(exitcode).  */
124   bl  L(gotexitcodeaddr);
125
126         /* This is the helper code which gets called if a function which
127            is registered with 'makecontext' returns.  In this case we
128            have to install the context listed in the uc_link element of
129            the context 'makecontext' manipulated at the time of the
130            'makecontext' call.  If the pointer is NULL the process must
131            terminate.  */
132 L(exitcode):
133    /* Recover the ucontext and TOC from the dummy frame.  */
134   ld    r1,FRAME_BACKCHAIN(r1)  /* Unstack the parameter save area frame.  */
135   ld    r3,FRAME_COMPILER_DW(r1)
136   ld    r2,FRAME_TOC_SAVE(r1)
137   ld    r3,UCONTEXT_LINK(r3)  /* Load the resume context.  */
138   cmpdi r3,0
139   beq   L(BADSTATUS)
140         bl    JUMPTARGET(__setcontext)
141         nop
142
143 L(BADSTATUS):
144 /* If setcontext returns (which can happen if the syscall fails) we will
145    exit the program with error status (-1).  */
146   li    r3,-1
147   b     JUMPTARGET(exit);
148   
149   /* The address of the exit code is in the link register.  Store the lr
150      in the ucontext as LNK so the target function will return to our 
151      exit code.  */
152 L(gotexitcodeaddr):
153   mflr  r0
154   std   r0,(SIGCONTEXT_GP_REGS+(PT_LNK*8))(r3)
155   ld    r0,128+FRAME_LR_SAVE(r1)  
156   addi  r1,r1,128
157   mtlr  r0
158   blr
159 END(__makecontext)
160
161 weak_alias(__makecontext, makecontext)