7ad360a3a089b7a8e7a23fff4b09e74ed5bc9414
[kopensolaris-gnu/glibc.git] / sysdeps / unix / sysv / linux / s390 / s390-32 / setcontext.S
1 /* Copyright (C) 2001 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep.h>
21 #include <features.h>
22
23 #include "ucontext_i.h"
24
25 /*  __setcontext (const ucontext_t *ucp)
26
27   Restores the machine context in UCP and thereby resumes execution
28   in that context.
29
30   This implementation is intended to be used for *synchronous* context
31   switches only.  Therefore, it does not have to restore anything
32   other than the PRESERVED state.  */
33
34 ENTRY(__setcontext)
35         lr      %r5,%r2
36
37         /* sigprocmask (SIG_SETMASK, &sc->sc_mask, NULL).  */
38         la      %r2,SIG_BLOCK
39         la      %r3,SC_MASK(%r5)
40         slr     %r4,%r4
41         svc     SYS_ify(rt_sigprocmask)
42
43         /* Load fpu context.  */
44         lfpc    SC_FPC(%r5)
45         ld      %f0,SC_FPRS(%r5)
46         ld      %f1,SC_FPRS+8(%r5)
47         ld      %f2,SC_FPRS+16(%r5)
48         ld      %f3,SC_FPRS+24(%r5)
49         ld      %f4,SC_FPRS+32(%r5)
50         ld      %f5,SC_FPRS+40(%r5)
51         ld      %f6,SC_FPRS+48(%r5)
52         ld      %f7,SC_FPRS+56(%r5)
53         ld      %f8,SC_FPRS+64(%r5)
54         ld      %f9,SC_FPRS+72(%r5)
55         ld      %f10,SC_FPRS+80(%r5)
56         ld      %f11,SC_FPRS+88(%r5)
57         ld      %f12,SC_FPRS+96(%r5)
58         ld      %f13,SC_FPRS+104(%r5)
59         ld      %f14,SC_FPRS+112(%r5)
60         ld      %f15,SC_FPRS+120(%r5)
61  
62         /* Don't touch %a0, used for thread purposes.  */
63         lam     %a1,%a15,SC_ACRS+4(%r5)
64
65         /* Load general purpose registers.  */
66         lm      %r0,%r15,SC_GPRS(%r5)
67
68         /* Return.  */
69         br      %r14
70 END(__setcontext)
71
72 weak_alias(__setcontext, setcontext)