c9b11b941a31b4ca4ec4207957a93ee32b5e2954
[kopensolaris-gnu/glibc.git] / sysdeps / unix / sysv / linux / sh / socket.S
1 /* Copyright (C) 1999, 2000 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3
4    The GNU C Library is free software; you can redistribute it and/or
5    modify it under the terms of the GNU Library General Public License as
6    published by the Free Software Foundation; either version 2 of the
7    License, or (at your option) any later version.
8
9    The GNU C Library is distributed in the hope that it will be useful,
10    but WITHOUT ANY WARRANTY; without even the implied warranty of
11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12    Library General Public License for more details.
13
14    You should have received a copy of the GNU Library General Public
15    License along with the GNU C Library; see the file COPYING.LIB.  If not,
16    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
17    Boston, MA 02111-1307, USA.  */
18
19 #include <sysdep.h>
20 #include <socketcall.h>
21
22 #define P(a, b) P2(a, b)
23 #define P2(a, b) a##b
24
25         .text
26 /* The socket-oriented system calls are handled unusally in Linux.
27    They are all gated through the single `socketcall' system call number.
28    `socketcall' takes two arguments: the first is the subcode, specifying
29    which socket function is being called; and the second is a pointer to
30    the arguments to the specific function.
31
32    The .S files for the other calls just #define socket and #include this.  */
33
34 #ifndef __socket
35 #define __socket P(__,socket)
36 #endif
37
38 #define PUSHARGS_1      mov.l r4,@-r15
39 #define PUSHARGS_2      mov.l r5,@-r15; PUSHARGS_1
40 #define PUSHARGS_3      mov.l r6,@-r15; PUSHARGS_2
41 #define PUSHARGS_4      mov.l r7,@-r15; PUSHARGS_3
42 #define PUSHARGS_5      PUSHARGS_4      /* Caller has already pushed arg 5 */
43 #define PUSHARGS_6      PUSHARGS_4      /* Caller has already pushed arg 5,6 */
44
45 #define POPARGS_1       add #4,r15
46 #define POPARGS_2       add #8,r15
47 #define POPARGS_3       add #12,r15
48 #define POPARGS_4       add #16,r15
49 #define POPARGS_5       add #16,r15
50 #define POPARGS_6       add #16,r15 
51
52 #ifndef NARGS
53 #define NARGS 3                 /* If we were called with no wrapper, this is really socket() */
54 #endif
55
56 .globl __socket
57 ENTRY (__socket)
58         /* This will not work in the case of a socket call being interrupted
59            by a signal.  If the signal handler uses any stack the arguments
60            to socket will be trashed.  The results of a restart of any
61            socket call are then unpredictable. */
62
63         /* Push args onto the stack.  */
64         P(PUSHARGS_,NARGS)
65
66         /* Do the system call trap.  */
67         mov #+P(SOCKOP_,socket), r4
68         mov r15, r5
69         mov.l .L1,r3
70         trapa #0x12
71
72         /* Pop args off the stack */
73         P(POPARGS_,NARGS)
74
75         mov     r0, r1
76         mov     #-12, r2
77         shad    r2, r1
78         not     r1, r1                  // r1=0 means r0 = -1 to -4095
79         tst     r1, r1                  // i.e. error in linux
80         bf      1f
81
82         mov.l .L2, r1
83 #ifdef SHARED
84         mov     r0, r2
85         mov.l   r12, @-r15
86         sts.l   pr, @-r15
87         mov.l   0f, r12
88         mova    0f, r0
89         add     r0, r12
90         mova    .L2, r0
91         add     r0, r1
92         jsr @r1
93          mov    r2, r0
94         lds.l   @r15+, pr
95         rts
96          mov.l  @r15+, r12
97         .align 2
98 0:
99         .long   _GLOBAL_OFFSET_TABLE_
100 #else
101         jmp @r1
102          nop
103 #endif
104 1:
105         /* Successful; return the syscall's value.  */
106         rts
107          nop
108         .align 2
109 .L1:
110         .long   SYS_ify(socketcall)
111 .L2:
112         .long   PLTJMP(C_SYMBOL_NAME(__syscall_error))
113
114 PSEUDO_END (__socket)
115
116 weak_alias (__socket, socket)