Updated to fedora-glibc-20041217T0906
[kopensolaris-gnu/glibc.git] / sysdeps / unix / sysv / linux / sparc / sparc64 / socket.S
1 /* Copyright (C) 1997, 1998, 2002, 2004 Free Software Foundation, Inc.
2    This file is part of the GNU C Library.
3    Contributed by Miguel de Icaza <miguel@gnu.ai.mit.edu>, 1997.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Lesser General Public License for more details.
14
15    You should have received a copy of the GNU Lesser General Public
16    License along with the GNU C Library; if not, write to the Free
17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18    02111-1307 USA.  */
19
20 #include <sysdep-cancel.h>
21 #include <socketcall.h>
22
23 #define P(a, b) P2(a, b)
24 #define P2(a, b) a##b
25
26 #ifndef NARGS
27 #ifdef socket
28 #error NARGS not defined
29 #endif
30 #define NARGS 3
31 #endif
32
33         .text
34 /* The socket-oriented system calls are handled unusually in Linux.
35    They are all gated through the single `socketcall' system call number.
36    `socketcall' takes two arguments: the first is the subcode, specifying
37    which socket function is being called; and the second is a pointer to
38    the arguments to the specific function.
39
40    The .S files for the other calls just #define socket and #include this.  */
41
42 #ifndef __socket
43 #define __socket P(__,socket)
44 #endif
45
46 .globl __socket
47 ENTRY (__socket)
48
49         /* Drop up to 6 arguments (recvfrom) into the memory allocated by
50            the caller for varargs, since that's really what we have.  */
51         stx     %o0, [%sp + STACK_BIAS + 128 + 0]
52         stx     %o1, [%sp + STACK_BIAS + 128 + 8]
53 #if NARGS > 2
54         stx     %o2, [%sp + STACK_BIAS + 128 + 16]
55 #if NARGS > 3
56         stx     %o3, [%sp + STACK_BIAS + 128 + 24]
57 #if NARGS > 4
58         stx     %o4, [%sp + STACK_BIAS + 128 + 32]
59 #if NARGS > 5
60         stx     %o5, [%sp + STACK_BIAS + 128 + 40]
61 #endif
62 #endif
63 #endif
64 #endif
65
66 #if defined NEED_CANCELLATION && defined CENABLE
67         SINGLE_THREAD_P
68         cmp     %g1, 0
69         bne     .Lsocket_cancel
70 #endif
71          mov    P(SOCKOP_,socket), %o0          /* arg 1: socket subfunction */
72         add     %sp, STACK_BIAS + 128, %o1      /* arg 2: parameter block */
73         LOADSYSCALL(socketcall)
74         ta      0x6d
75
76         bcs,pn  %xcc, __syscall_error_handler
77          nop
78         retl
79          nop
80
81 #if defined NEED_CANCELLATION && defined CENABLE
82 .Lsocket_cancel:
83         cfi_startproc
84         save    %sp, -160, %sp
85         cfi_def_cfa_register (%fp)
86         cfi_window_save
87         cfi_register (%o7, %i7)
88         CENABLE
89          nop
90         mov     %o0, %l0
91         add     %sp, 160 + STACK_BIAS + 128, %o1
92         mov     P(SOCKOP_,socket), %o0
93         LOADSYSCALL(socketcall)
94         ta      0x6d
95
96         bcs,pn  %xcc, __syscall_error_handler2
97          mov    %o0, %l1
98         CDISABLE
99          mov    %l0, %o0
100         jmpl    %i7 + 8, %g0
101          restore %g0, %l1, %o0
102         cfi_endproc
103         SYSCALL_ERROR_HANDLER2
104 #endif
105
106         SYSCALL_ERROR_HANDLER
107
108 END (__socket)
109
110 weak_alias (__socket, socket)