Mon Jun 24 19:57:01 1996 Roland McGrath <roland@delasyd.gnu.ai.mit.edu>
[kopensolaris-gnu/glibc.git] / sysdeps / vax / rindex.s
1 /*
2  * Copyright (c) 1983 Regents of the University of California.
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms, with or without
6  * modification, are permitted provided that the following conditions
7  * are met:
8  * 1. Redistributions of source code must retain the above copyright
9  *    notice, this list of conditions and the following disclaimer.
10  * 2. Redistributions in binary form must reproduce the above copyright
11  *    notice, this list of conditions and the following disclaimer in the
12  *    documentation and/or other materials provided with the distribution.
13  * 3. All advertising materials mentioning features or use of this software
14  *    must display the following acknowledgement:
15  *      This product includes software developed by the University of
16  *      California, Berkeley and its contributors.
17  * 4. Neither the name of the University nor the names of its contributors
18  *    may be used to endorse or promote products derived from this software
19  *    without specific prior written permission.
20  *
21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
31  * SUCH DAMAGE.
32  */
33
34 #if defined(LIBC_SCCS) && !defined(lint)
35         .asciz "@(#)rindex.s    5.6 (Berkeley) 6/1/90"
36 #endif /* LIBC_SCCS and not lint */
37
38 /*
39  * Find the last occurence of c in the string cp.
40  * Return pointer to match or null pointer.
41  *
42  * char *
43  * rindex(cp, c)
44  *      char *cp, c;
45  */
46 #include "DEFS.h"
47
48 ENTRY(rindex, 0)
49         movq    4(ap),r1        # r1 = cp; r2 = c
50         tstl    r2              # check for special case c == '\0'
51         bneq    2f
52 1:
53         locc    $0,$65535,(r1)  # just find end of string
54         beql    1b              # still looking
55         movl    r1,r0           # found it
56         ret
57 2:
58         moval   tbl,r3          # r3 = address of table
59         bbss    $0,(r3),5f      # insure not reentering
60         movab   (r3)[r2],r5     # table entry for c
61         incb    (r5)
62         clrl    r4              # last found
63 3:
64         scanc   $65535,(r1),(r3),$1     # look for c or '\0'
65         beql    3b              # keep looking
66         tstb    (r1)            # if have found '\0'
67         beql    4f              #    we are done
68         movl    r1,r4           # save most recently found
69         incl    r1              # skip over character
70         jbr     3b              # keep looking
71 4:
72         movl    r4,r0           # return last found (if any)
73         clrb    (r5)            # clean up table
74         clrb    (r3)
75         ret
76
77         .data
78 tbl:    .space  256
79         .text
80
81 /*
82  * Reentrant, but slower version of rindex
83  */
84 5:
85         movl    r1,r3
86         clrl    r4              # r4 = pointer to last match
87 6:
88         locc    $0,$65535,(r3)  # look for '\0'
89         bneq    8f
90         decw    r0              # r0 = 65535
91 1:
92         locc    r2,r0,(r3)      # look for c
93         bneq    7f
94         movl    r1,r3           # reset pointer and ...
95         jbr     6b              # ... try again
96 7:
97         movl    r1,r4           # stash pointer ...
98         addl3   $1,r1,r3        # ... skip over match and ...
99         decl    r0              # ... decrement count
100         jbr     6b              # ... try again
101 8:
102         subl3   r3,r1,r0        # length of short block
103         incl    r0              # +1 for '\0'
104 9:
105         locc    r2,r0,(r3)      # look for c
106         beql    0f
107         movl    r1,r4           # stash pointer ...
108         addl3   $1,r1,r3        # ... skip over match ...
109         decl    r0              # ... adjust count and ...
110         jbr     9b              # ... try again
111 0:
112         movl    r4,r0           # return stashed pointer
113         ret