Fixed incorrect use of mvcle introduced by 2001-07-12 change.
[kopensolaris-gnu/glibc.git] / sysdeps / vax / strchr.s
1 /*
2  * Copyright (c) 1988 Regents of the University of California.
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms, with or without
6  * modification, are permitted provided that the following conditions
7  * are met:
8  * 1. Redistributions of source code must retain the above copyright
9  *    notice, this list of conditions and the following disclaimer.
10  * 2. Redistributions in binary form must reproduce the above copyright
11  *    notice, this list of conditions and the following disclaimer in the
12  *    documentation and/or other materials provided with the distribution.
13  * 4. Neither the name of the University nor the names of its contributors
14  *    may be used to endorse or promote products derived from this software
15  *    without specific prior written permission.
16  *
17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
27  * SUCH DAMAGE.
28  */
29
30 #if defined(LIBC_SCCS) && !defined(lint)
31         .asciz "@(#)strchr.s    5.4 (Berkeley) 6/1/90"
32 #endif /* LIBC_SCCS and not lint */
33
34 /*
35  * Find the first occurrence of c in the string cp.
36  * Return pointer to match or null pointer.
37  *
38  * char *
39  * strchr(cp, c)
40  *      char *cp, c;
41  */
42 #include "DEFS.h"
43
44         .lcomm  tbl,256
45
46 ENTRY(strchr, 0)
47         movzwl  $65535,r4       /* handy constant */
48         movq    4(ap),r1        /* r1 = cp; r2 = c */
49         movzbl  r2,r2
50         beql    Lzero           /* special case for c == '\0' */
51
52 /*
53  * Fancy scanc version.  Alas, it is not reentrant.
54  */
55         movab   tbl,r3          /* r3 = base of table */
56         bbss    $0,(r3),Lreent  /* ensure not reentering */
57         movab   (r3)[r2],r5
58         incb    (r5)            /* mark both '\0' and c */
59 0:
60         scanc   r4,(r1),(r3),$1 /* look for c or '\0' */
61         beql    0b              /* still looking */
62         movl    r1,r0           /* return whatever we found */
63         tstb    (r0)
64         bneq    1f              #       unless it was '\0':
65         clrl    r0              #       then return NULL
66 1:
67         clrb    (r5)            /* clean up table */
68         clrb    (r3)
69         ret
70
71 /*
72  * Special case for \0.
73  */
74 Lzero:
75         locc    r2,r4,(r1)      /* just find end of string */
76         beql    Lzero           /* still looking */
77         movl    r1,r0           /* found it */
78         ret
79
80 /*
81  * Slower reentrant version is two two-step searches.  The first
82  * phase runs until we know where the string ends; it locates the
83  * first occurrence of c within a 65535-byte block.  If we find
84  * the end of the string first, we switch to the second phase,
85  * were we look only up to the known end of string.
86  */
87 Lreent:
88 0:      /* first phase */
89         movl    r1,r3
90         locc    $0,r4,(r3)      /* look for '\0' */
91         bneq    1f
92         locc    r2,r4,(r3)      /* look for c */
93         beql    0b              /* not found: reset pointer and loop */
94         movl    r1,r0           /* found: return it */
95         ret
96 1:      /* second phase */
97         subl3   r3,r1,r0        /* length of short block */
98         locc    r2,r0,(r3)      /* look for c */
99         beql    2f              /* not found: return NULL */
100         movl    r1,r0
101 2:      ret
102
103 weak_alias (strchr, index)